(* Copyright (C) 2004-2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

open Printf
open MatitaTypes 

(** Functions "imported" from Http_getter_misc *)

let strip_trailing_slash = Http_getter_misc.strip_trailing_slash
let normalize_dir = Http_getter_misc.normalize_dir
let strip_suffix = Http_getter_misc.strip_suffix

let baseuri_of_baseuri_decl st =
  match st with
  | GrafiteAst.Executable (_, GrafiteAst.Command (_, GrafiteAst.Set (_, "baseuri", buri))) ->
      Some buri
  | _ -> None

let baseuri_of_file file = 
  let uri = ref None in
  let ic = open_in file in
  let istream = Ulexing.from_utf8_channel ic in
  (try
    while true do
      try 
        let stm = GrafiteParser.parse_statement istream in
        match baseuri_of_baseuri_decl stm with
        | Some buri -> 
            let u = strip_trailing_slash buri in
            if String.length u < 5 || String.sub u 0 5 <> "cic:/" then
              MatitaLog.error (file ^ " sets an incorrect baseuri: " ^ buri);
            (try 
              ignore(Http_getter.resolve u)
            with
            | Http_getter_types.Unresolvable_URI _ -> 
                MatitaLog.error (file ^ " sets an unresolvable baseuri: "^buri)
            | Http_getter_types.Key_not_found _ -> ());
            uri := Some u;
            raise End_of_file
        | None -> ()
      with
        CicNotationParser.Parse_error _ as exn ->
          prerr_endline ("Unable to parse: " ^ file);
          prerr_endline (MatitaExcPp.to_string exn);
          ()
    done
  with End_of_file -> close_in ic);
  match !uri with
  | Some uri -> uri
  | None -> failwith ("No baseuri defined in " ^ file)

let is_empty buri =
 List.for_all
  (function
      Http_getter_types.Ls_section _ -> true
    | Http_getter_types.Ls_object _ -> false)
  (Http_getter.ls (Http_getter_misc.strip_trailing_slash buri ^ "/"))

let safe_remove fname = if Sys.file_exists fname then Sys.remove fname

let is_dir_empty d =
  try 
    let od = Unix.opendir d in
    try 
      ignore (Unix.readdir od);
      ignore (Unix.readdir od);
      ignore (Unix.readdir od);
      Unix.closedir od;
      false
    with End_of_file -> 
      Unix.closedir od;
      true
  with Unix.Unix_error _ -> true

let safe_rmdir d = try Unix.rmdir d with Unix.Unix_error _ -> ()

let rec rmdir_descend d = 
  if is_dir_empty d then
    begin
      safe_rmdir d;
      rmdir_descend (Filename.dirname d)
    end

let absolute_path file =
  if file.[0] = '/' then file else Unix.getcwd () ^ "/" ^ file
  
let is_proof_script fname = true  (** TODO Zack *)
let is_proof_object fname = true  (** TODO Zack *)

let append_phrase_sep s =
  if not (Pcre.pmatch ~pat:(sprintf "%s$" BuildTimeConf.phrase_sep) s) then
    s ^ BuildTimeConf.phrase_sep
  else
    s

let empty_mathml = lazy (
  DomMisc.domImpl#createDocument ~namespaceURI:(Some DomMisc.mathml_ns)
    ~qualifiedName:(Gdome.domString "math") ~doctype:None)

let empty_boxml = lazy (
  DomMisc.domImpl#createDocument ~namespaceURI:(Some DomMisc.boxml_ns) 
    ~qualifiedName:(Gdome.domString "box") ~doctype:None)

let closed_goal_mathml = lazy (
  DomMisc.domImpl#createDocumentFromURI ~uri:BuildTimeConf.closed_xml ())

exception History_failure

type 'a memento = 'a array * int * int * int  (* data, hd, tl, cur *)

class type ['a] history =
  object
    method add : 'a -> unit
    method next : 'a
    method previous : 'a
    method load: 'a memento -> unit
    method save: 'a memento
    method is_begin: bool
    method is_end: bool
  end

class basic_history (head, tail, cur) =
  object
    val mutable hd = head  (* insertion point *)
    val mutable tl = tail (* oldest inserted item *)
    val mutable cur = cur  (* current item for the history *)
    
    method is_begin = cur <= tl
    method is_end = cur >= hd
  end
  
  
class shell_history size =
  let size = size + 1 in
  let decr x = let x' = x - 1 in if x' < 0 then size + x' else x' in
  let incr x = (x + 1) mod size in
  object (self)
    val data = Array.create size ""

    inherit basic_history (0, -1 , -1)
    
    method add s =
      data.(hd) <- s;
      if tl = -1 then tl <- hd;
      hd <- incr hd;
      if hd = tl then tl <- incr tl;
      cur <- hd
    method previous =
      if cur = tl then raise History_failure;
      cur <- decr cur;
      data.(cur)
    method next =
      if cur = hd then raise History_failure;
      cur <- incr cur;
      if cur = hd then "" else data.(cur)
    method load (data', hd', tl', cur') =
      assert (Array.length data = Array.length data');
      hd <- hd'; tl <- tl'; cur <- cur';
      Array.blit data' 0 data 0 (Array.length data')
    method save = (Array.copy data, hd, tl, cur)
  end

class ['a] browser_history ?memento size init =
  object (self)
    initializer match memento with Some m -> self#load m | _ -> ()
    val data = Array.create size init

    inherit basic_history (0, 0, 0)
    
    method previous =
      if cur = tl then raise History_failure;
      cur <- cur - 1;
      if cur = ~-1 then cur <- size - 1;
      data.(cur)
    method next =
      if cur = hd then raise History_failure;
      cur <- cur + 1;
      if cur = size then cur <- 0;
      data.(cur)
    method add (e:'a) =
      if e <> data.(cur) then
        begin
          cur <- cur + 1;
          if cur = size then cur <- 0;
          if cur = tl then tl <- tl + 1;
          if tl = size then tl <- 0;
          hd <- cur;
          data.(cur) <- e
        end
    method load (data', hd', tl', cur') =
      assert (Array.length data = Array.length data');
      hd <- hd'; tl <- tl'; cur <- cur';
      Array.blit data' 0 data 0 (Array.length data')
    method save = (Array.copy data, hd, tl, cur)
  end

let singleton f =
  let instance = lazy (f ()) in
  fun () -> Lazy.force instance

let get_current_proof status =
  match status.proof_status with
  | Incomplete_proof { proof = p } -> p
  | _ -> statement_error "no ongoing proof"

let get_proof_metasenv status =
  match status.proof_status with
  | No_proof -> []
  | Proof (_, metasenv, _, _)
  | Incomplete_proof { proof = (_, metasenv, _, _) }
  | Intermediate metasenv ->
      metasenv

let get_proof_context status goal =
  match status.proof_status with
  | Incomplete_proof { proof = (_, metasenv, _, _) } ->
      let (_, context, _) = CicUtil.lookup_meta goal metasenv in
      context
  | _ -> []
 
let get_proof_conclusion status goal =
  match status.proof_status with
  | Incomplete_proof { proof = (_, metasenv, _, _) } ->
      let (_, _, conclusion) = CicUtil.lookup_meta goal metasenv in
      conclusion
  | _ -> statement_error "no ongoing proof"

let get_stack status =
  match status.proof_status with
  | Incomplete_proof p -> p.stack
  | Proof _ -> Continuationals.Stack.empty
  | _ -> assert false

let set_stack stack status =
  match status.proof_status with
  | Incomplete_proof p ->
      { status with proof_status = Incomplete_proof { p with stack = stack } }
  | Proof _ ->
      assert (Continuationals.Stack.is_empty stack);
      status
  | _ -> assert false
 
let qualify status name = get_string_option status "baseuri" ^ "/" ^ name

let image_path n = sprintf "%s/%s" BuildTimeConf.images_dir n

let end_ma_RE = Pcre.regexp "\\.ma$"

let obj_file_of_baseuri baseuri =
 let path =
  Helm_registry.get "matita.basedir" ^ "/xml" ^
   Pcre.replace ~pat:"^cic:" ~templ:"" baseuri
 in
  path ^ ".moo"

let obj_file_of_script f =
 if f = "coq.ma" then BuildTimeConf.coq_notation_script else
  let baseuri = baseuri_of_file f in
   obj_file_of_baseuri baseuri

let list_tl_at ?(equality=(==)) e l =
  let rec aux =
    function
    | [] -> raise Not_found
    | hd :: tl as l when equality hd e -> l
    | hd :: tl -> aux tl
  in
  aux l