(* Copyright (C) 2004-2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

open Printf
open MatitaTypes

let debug = true
let debug_print = if  debug then prerr_endline else ignore

  (** raised when one of the script margins (top or bottom) is reached *)
exception Margin

let safe_substring s i j =
  try String.sub s i j with Invalid_argument _ -> assert false

let heading_nl_RE = Pcre.regexp "^\\s*\n\\s*"
let only_dust_RE = Pcre.regexp "^(\\s|\n|%%[^\n]*\n)*$"
let multiline_RE = Pcre.regexp "^\n[^\n]+$"
let newline_RE = Pcre.regexp "\n"
 
let comment str =
  if Pcre.pmatch ~rex:multiline_RE str then
    "\n(** " ^ (Pcre.replace ~rex:newline_RE str) ^ " **)"
  else
    "\n(**\n" ^ str ^ "\n**)"
                     
let first_line s =
  let s = Pcre.replace ~rex:heading_nl_RE s in
  try
    let nl_pos = String.index s '\n' in
    String.sub s 0 nl_pos
  with Not_found -> s

let prepend_text header base =
  if Pcre.pmatch ~rex:heading_nl_RE base then
    sprintf "\n%s%s" header base
  else
    sprintf "%s\n%s" header base

  (** creates a statement AST for the Goal tactic, e.g. "goal 7" *)
let goal_ast n =
  let module A = TacticAst in
  let loc = CicAst.dummy_floc in
  A.Executable (loc, A.Tactical (loc, A.Tactic (loc, A.Goal (loc, n))))

type guistuff = {
  mathviewer:MatitaTypes.mathViewer;
  urichooser: UriManager.uri list -> UriManager.uri list;
  ask_confirmation: title:string -> message:string -> [`YES | `NO | `CANCEL];
  develcreator: containing:string option -> unit;
  mutable filenamedata: string option * MatitamakeLib.development option
}

let eval_with_engine guistuff status user_goal parsed_text st =
  let module TA = TacticAst in
  let module TAPp = TacticAstPp in
  let include_ = 
    match guistuff.filenamedata with
    | _,None -> []
    | None,Some devel -> [MatitamakeLib.root_for_development devel ]
    | Some f,_ -> 
        match MatitamakeLib.development_for_dir (Filename.dirname f) with
        | None -> []
        | Some devel -> [MatitamakeLib.root_for_development devel ]
  in
  let parsed_text_length = String.length parsed_text in
  let loc, ex = 
    match st with TA.Executable (loc,ex) -> loc, ex | _ -> assert false 
  in
  let goal_changed = ref false in
  let status =
    match status.proof_status with
      | Incomplete_proof (_, goal) when goal <> user_goal ->
          goal_changed := true;
          MatitaEngine.eval_ast ~include_paths:include_
            ~do_heavy_checks:true status (goal_ast user_goal)
      | _ -> status
  in
  let new_status = 
    MatitaEngine.eval_ast 
      ~include_paths:include_ ~do_heavy_checks:true status st 
  in
  let new_aliases =
    match ex with
      | TA.Command (_, TA.Alias _)
      | TA.Command (_, TA.Include _) -> DisambiguateTypes.Environment.empty
      | _ -> MatitaSync.alias_diff ~from:status new_status
  in
  (* we remove the defined object since we consider them "automathic aliases" *)
  let new_aliases = 
    let module DTE = DisambiguateTypes.Environment in
    let module UM = UriManager in
    DTE.fold (
      fun k ((v,_) as value) acc -> 
        let b = 
          try
            let v = UM.strip_xpointer (UM.uri_of_string v) in
            List.exists (fun (s,_) -> s = v) new_status.objects 
          with UM.IllFormedUri _ -> false
        in
        if b then 
          acc
        else
          DTE.add k value acc
    ) new_aliases DTE.empty
  in
  let new_text =
    if DisambiguateTypes.Environment.is_empty new_aliases then
      parsed_text
    else
      prepend_text (CicTextualParser2.EnvironmentP3.to_string new_aliases)
        parsed_text
  in
  let new_text =
    if !goal_changed then
      prepend_text
        (TAPp.pp_tactic (TA.Goal (loc, user_goal))(* ^ "\n"*))
        new_text
    else
      new_text
  in
    [ new_status, new_text ], parsed_text_length

let eval_with_engine guistuff status user_goal parsed_text st =
  try
    eval_with_engine guistuff status user_goal parsed_text st
  with
    MatitaEngine.UnableToInclude what as exc ->
      let compile_needed_and_go_on d =
        let root = MatitamakeLib.root_for_development d in
        let target = root ^ "/" ^ what in
        if not(MatitamakeLib.build_development ~target d) then
          raise exc
        else
          eval_with_engine guistuff status user_goal parsed_text st
      in
      let do_nothing () = [], 0 in
      let handle_with_devel d =
        let name = MatitamakeLib.name_for_development d in
        let title = "Unable to include " ^ what in
        let message = 
          what ^ " is handled by development <b>" ^ name ^ "</b>.\n\n" ^
          "<i>Should I compile it and Its dependencies?</i>"
        in
        (match guistuff.ask_confirmation ~title ~message with
        | `YES -> compile_needed_and_go_on d
        | `NO -> raise exc
        | `CANCEL -> do_nothing ())
      in
      let handle_withoud_devel filename =
        let title = "Unable to include " ^ what in
        let message = 
         what ^ " is <b>not</b> handled by a development.\n" ^
         "All dependencies are authomatically solved for a development.\n\n" ^
         "<i>Do you want to set up a development?</i>"
        in
        (match guistuff.ask_confirmation ~title ~message with
        | `YES -> 
            (match filename with
            | Some f -> 
                guistuff.develcreator ~containing:(Some (Filename.dirname f))
            | None -> guistuff.develcreator ~containing:None);
            do_nothing ()
        | `NO -> raise exc
        | `CANCEL -> do_nothing())
      in
      match guistuff.filenamedata with
      | None,None -> handle_withoud_devel None
      | None,Some d -> handle_with_devel d
      | Some f,_ ->
          match MatitamakeLib.development_for_dir (Filename.dirname f) with
          | None -> handle_withoud_devel (Some f)
          | Some d -> handle_with_devel d
;;

let disambiguate term status =
  let module MD = MatitaDisambiguator in
  let dbd = MatitaDb.instance () in
  let metasenv = MatitaMisc.get_proof_metasenv status in
  let context = MatitaMisc.get_proof_context status in
  let aliases = MatitaMisc.get_proof_aliases status in
  let interps = MD.disambiguate_term dbd context metasenv aliases term in
  match interps with 
  | [_,_,x,_] -> x
  | _ -> assert false
 
let eval_macro guistuff status parsed_text script mac
=
  let module TA = TacticAst in
  let module TAPp = TacticAstPp in
  let module MQ = MetadataQuery in
  let module MDB = MatitaDb in
  let module CTC = CicTypeChecker in
  let module CU = CicUniv in
  (* no idea why ocaml wants this *)
  let advance ?statement () = script#advance ?statement () in
  let parsed_text_length = String.length parsed_text in
  let dbd = MatitaDb.instance () in
  match mac with
  (* WHELP's stuff *)
  | TA.WMatch (loc, term) -> 
      let term = disambiguate term status in
      let l =  MQ.match_term ~dbd term in
      let entry = `Whelp (TAPp.pp_macro_cic (TA.WMatch (loc, term)), l) in
      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
      [], parsed_text_length
  | TA.WInstance (loc, term) ->
      let term = disambiguate term status in
      let l = MQ.instance ~dbd term in
      let entry = `Whelp (TAPp.pp_macro_cic (TA.WInstance (loc, term)), l) in
      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
      [], parsed_text_length
  | TA.WLocate (loc, s) -> 
      let l = MQ.locate ~dbd s in
      let entry = `Whelp (TAPp.pp_macro_cic (TA.WLocate (loc, s)), l) in
      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
      [], parsed_text_length
  | TA.WElim (loc, term) ->
      let term = disambiguate term status in
      let uri =
        match term with
        | Cic.MutInd (uri,n,_) -> UriManager.uri_of_uriref uri n None 
        | _ -> failwith "Not a MutInd"
      in
      let l = MQ.elim ~dbd uri in
      let entry = `Whelp (TAPp.pp_macro_cic (TA.WElim (loc, term)), l) in
      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
      [], parsed_text_length
  | TA.WHint (loc, term) ->
      let term = disambiguate term status in
      let s = ((None,[0,[],term], Cic.Meta (0,[]) ,term),0) in
      let l = List.map fst (MQ.experimental_hint ~dbd s) in
      let entry = `Whelp (TAPp.pp_macro_cic (TA.WHint (loc, term)), l) in
      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
      [], parsed_text_length
  (* REAL macro *)
  | TA.Hint loc -> 
      let s = MatitaMisc.get_proof_status status in
      let l = List.map fst (MQ.experimental_hint ~dbd s) in
      let selected = guistuff.urichooser l in
      (match selected with
      | [] -> [], parsed_text_length
      | [uri] -> 
        let ast = 
         TA.Executable (loc,
          (TA.Tactical (loc, 
            TA.Tactic (loc,
             TA.Apply (loc, CicAst.Uri (UriManager.string_of_uri uri,None))))))
        in
        let new_status = MatitaEngine.eval_ast status ast in
        let extra_text = 
          comment parsed_text ^ 
          "\n" ^ TAPp.pp_statement ast
        in
        [ new_status , extra_text ], parsed_text_length
      | _ -> 
          MatitaLog.error 
            "The result of the urichooser should be only 1 uri, not:\n";
          List.iter (
            fun u -> MatitaLog.error (UriManager.string_of_uri u ^ "\n")
          ) selected;
          assert false)
  | TA.Check (_,term) ->
      let metasenv = MatitaMisc.get_proof_metasenv status in
      let context = MatitaMisc.get_proof_context status in
      let aliases = MatitaMisc.get_proof_aliases status in
      let interps = 
        MatitaDisambiguator.disambiguate_term 
          dbd context metasenv aliases term 
      in
      let _, metasenv , term, ugraph =
        match interps with 
        | [x] -> x
        | _ -> assert false
      in
      let ty,_ = CTC.type_of_aux' metasenv context term ugraph in
      let t_and_ty = Cic.Cast (term,ty) in
      guistuff.mathviewer#show_entry (`Cic (t_and_ty,metasenv));
      [], parsed_text_length
(*   | TA.Abort _ -> 
      let rec go_back () =
        let status = script#status.proof_status in
        match status with
        | No_proof -> ()
        | _ -> script#retract ();go_back()
      in
      [], parsed_text_length, Some go_back
  | TA.Redo (_, Some i) ->  [], parsed_text_length, 
      Some (fun () -> for j = 1 to i do advance () done)
  | TA.Redo (_, None) ->   [], parsed_text_length, 
      Some (fun () -> advance ())
  | TA.Undo (_, Some i) ->  [], parsed_text_length, 
      Some (fun () -> for j = 1 to i do script#retract () done)
  | TA.Undo (_, None) -> [], parsed_text_length, 
      Some (fun () -> script#retract ()) *)
  (* TODO *)
  | TA.Quit _ -> failwith "not implemented"
  | TA.Print (_,kind) -> failwith "not implemented"
  | TA.Search_pat (_, search_kind, str) -> failwith "not implemented"
  | TA.Search_term (_, search_kind, term) -> failwith "not implemented"

                                
let eval_executable guistuff status user_goal parsed_text script ex =
  let module TA = TacticAst in
  let module TAPp = TacticAstPp in
  let module MD = MatitaDisambiguator in
  let module ML = MatitacleanLib in
  let parsed_text_length = String.length parsed_text in
  match ex with
  | TA.Command (loc, _) | TA.Tactical (loc, _) ->
      (try 
        (match ML.baseuri_of_baseuri_decl (TA.Executable (loc,ex)) with
        | None -> ()
        | Some u -> 
            if not (MatitacleanLib.is_empty u) then
              match 
                guistuff.ask_confirmation 
                  ~title:"Baseuri redefinition" 
                  ~message:(
                    "Baseuri " ^ u ^ " already exists.\n" ^
                    "Do you want to redefine the corresponding "^
                    "part of the library?")
              with
              | `YES -> MatitacleanLib.clean_baseuris [u]
              | `NO -> ()
              | `CANCEL -> raise MatitaTypes.Cancel);
        eval_with_engine 
          guistuff status user_goal parsed_text (TA.Executable (loc, ex))
      with MatitaTypes.Cancel -> [], 0)
  | TA.Macro (_,mac) ->
      eval_macro guistuff status parsed_text script mac

let rec eval_statement guistuff status user_goal script s =
  if Pcre.pmatch ~rex:only_dust_RE s then raise Margin;
  let st = CicTextualParser2.parse_statement (Stream.of_string s) in
  let text_of_loc loc =
    let parsed_text_length = snd (CicAst.loc_of_floc loc) in
    let parsed_text = safe_substring s 0 parsed_text_length in
    parsed_text, parsed_text_length
  in
  match st with
  | TacticAst.Comment (loc,_)-> 
      let parsed_text, parsed_text_length = text_of_loc loc in
      let remain_len = String.length s - parsed_text_length in
      let s = String.sub s parsed_text_length remain_len in
      let s,len = 
        eval_statement guistuff status user_goal script s 
      in
      (match s with
      | (status, text) :: tl ->
        ((status, parsed_text ^ text)::tl), (parsed_text_length + len)
      | [] -> [], 0)
  | TacticAst.Executable (loc, ex) ->
      let parsed_text, parsed_text_length = text_of_loc loc in
      eval_executable guistuff  status user_goal parsed_text script ex 
  
let fresh_script_id =
  let i = ref 0 in
  fun () -> incr i; !i

class script ~(buffer: GText.buffer) ~(init: MatitaTypes.status) 
              ~(mathviewer: MatitaTypes.mathViewer) 
              ~set_star
              ~ask_confirmation
              ~urichooser 
              ~develcreator 
              () =
object (self)
  val scriptId = fresh_script_id ()
  
  val guistuff = {
    mathviewer = mathviewer;
    urichooser = urichooser;
    ask_confirmation = ask_confirmation;
    develcreator = develcreator;
    filenamedata = (None, None)} 
  
  method private getFilename =
    match guistuff.filenamedata with Some f,_ -> f | _ -> assert false
    
  method private ppFilename =
    match guistuff.filenamedata with 
    | Some f,_ -> f 
    | None,_ -> sprintf ".unnamed%d.ma" scriptId
  
  initializer 
    ignore(GMain.Timeout.add ~ms:300000 
       ~callback:(fun _ -> self#_saveToBackuptFile ();true));
    ignore(buffer#connect#modified_changed 
       (fun _ -> if buffer#modified then 
          set_star self#ppFilename true 
        else 
          set_star self#ppFilename false));
    self#reset ();
    self#template ()

  val mutable statements = [];    (** executed statements *)
  val mutable history = [ init ];
    (** list of states before having executed statements. Head element of this
      * list is the current state, last element is the state at the beginning of
      * the script.
      * Invariant: this list length is 1 + length of statements *)

  (** goal as seen by the user (i.e. metano corresponding to current tab) *)
  val mutable userGoal = ~-1

  (** text mark and tag representing locked part of a script *)
  val locked_mark =
    buffer#create_mark ~name:"locked" ~left_gravity:true buffer#start_iter
  val locked_tag = buffer#create_tag [`BACKGROUND "lightblue"; `EDITABLE false]

    (* history can't be empty, the invariant above grant that it contains at
     * least the init status *)
  method status = match history with hd :: _ -> hd | _ -> assert false

  method private _advance ?statement () =
    let s = match statement with Some s -> s | None -> self#getFuture in
    MatitaLog.debug ("evaluating: " ^ first_line s ^ " ...");
    let (entries, parsed_len) = 
      eval_statement guistuff self#status userGoal self s
    in
    let (new_statuses, new_statements) = List.split entries in
(*
prerr_endline "evalStatement returned";
List.iter (fun s -> prerr_endline ("'" ^ s ^ "'")) new_statements;
*)
    history <- List.rev new_statuses @ history;
    statements <- List.rev new_statements @ statements;
    let start = buffer#get_iter_at_mark (`MARK locked_mark) in
    let new_text = String.concat "" new_statements in
    if new_text <> String.sub s 0 parsed_len then
      begin
(*       prerr_endline ("new:" ^ new_text); *)
(*       prerr_endline ("s:" ^ String.sub s 0 parsed_len); *)
      let stop = start#copy#forward_chars parsed_len in
      buffer#delete ~start ~stop;
      buffer#insert ~iter:start new_text;
(*       prerr_endline "AUTOMATICALLY MODIFIED!!!!!" *)
      end;
    self#moveMark (String.length new_text)

  method private _retract () =
    match statements, history with
    | last_statement :: _, cur_status :: prev_status :: _ ->
        MatitaSync.time_travel ~present:cur_status ~past:prev_status;
        statements <- List.tl statements;
        history <- List.tl history;
        self#moveMark (- (String.length last_statement));
    | _ -> raise Margin

  method advance ?statement () =
    try
      self#_advance ?statement ();
      self#notify
    with 
    | Margin -> self#notify
    | exc -> self#notify; raise exc

  method retract () =
    try
      self#_retract ();
      self#notify
    with 
    | Margin -> self#notify
    | exc -> self#notify; raise exc

  method private getFuture =
    buffer#get_text ~start:(buffer#get_iter_at_mark (`MARK locked_mark))
      ~stop:buffer#end_iter ()

      
  (** @param rel_offset relative offset from current position of locked_mark *)
  method private moveMark rel_offset =
    let mark = `MARK locked_mark in
    let old_insert = buffer#get_iter_at_mark `INSERT in
    buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
    let current_mark_pos = buffer#get_iter_at_mark mark in
    let new_mark_pos =
      match rel_offset with
      | 0 -> current_mark_pos
      | n when n > 0 -> current_mark_pos#forward_chars n
      | n (* when n < 0 *) -> current_mark_pos#backward_chars (abs n)
    in
    buffer#move_mark mark ~where:new_mark_pos;
    buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:new_mark_pos;
    buffer#move_mark `INSERT old_insert;
    begin
     match self#status.proof_status with
        Incomplete_proof (_,goal) -> self#setGoal goal
      | _ -> ()
    end ;
    while Glib.Main.pending () do ignore(Glib.Main.iteration false); done

  method clean_dirty_lock =
    let lock_mark_iter = buffer#get_iter_at_mark (`MARK locked_mark) in
    buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
    buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:lock_mark_iter

  val mutable observers = []

  method addObserver (o: MatitaTypes.status -> unit) =
    observers <- o :: observers

  method private notify =
    let status = self#status in
    List.iter (fun o -> o status) observers

  method loadFromFile () =
    buffer#set_text (MatitaMisc.input_file self#getFilename);
    self#goto_top;
    buffer#set_modified false
    
  method assignFileName file =
    let abspath = MatitaMisc.absolute_path file in
    let devel = MatitamakeLib.development_for_dir (Filename.dirname abspath) in
    guistuff.filenamedata <- Some abspath, devel
    
  method saveToFile () =
    let oc = open_out self#getFilename in
    output_string oc (buffer#get_text ~start:buffer#start_iter
                        ~stop:buffer#end_iter ());
    close_out oc;
    buffer#set_modified false
  
  method private _saveToBackuptFile () =
    if buffer#modified then
      begin
        let f = self#ppFilename ^ "~" in
        let oc = open_out f in
        output_string oc (buffer#get_text ~start:buffer#start_iter
                            ~stop:buffer#end_iter ());
        close_out oc;
        MatitaLog.debug ("backup " ^ f ^ " saved")                    
      end
  
  method private goto_top =
    MatitaSync.time_travel ~present:self#status ~past:init;
    statements <- [];
    history <- [ init ];
    userGoal <- ~-1;
    buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
    buffer#move_mark (`MARK locked_mark) ~where:buffer#start_iter

  method reset () =
    self#goto_top;
    buffer#delete ~start:buffer#start_iter ~stop:buffer#end_iter;
    self#notify;
    buffer#set_modified false

  method template () =
    let template = MatitaMisc.input_file BuildTimeConf.script_template in 
    buffer#insert ~iter:(buffer#get_iter `START) template;
    guistuff.filenamedata <- 
      (None,MatitamakeLib.development_for_dir (Unix.getcwd ()));
    buffer#set_modified false;
    set_star self#ppFilename false

  method goto (pos: [`Top | `Bottom | `Cursor]) () =
    let getpos _ = buffer#get_iter_at_mark (`MARK locked_mark) in 
    match pos with
    | `Top -> self#goto_top; self#notify
    | `Bottom ->
        (try 
          let rec dowhile pos =
            self#_advance ();
            if pos#compare (getpos ()) < 0 then
              dowhile (getpos ())
          in
          dowhile (getpos ());
          self#notify 
        with 
        | Margin -> self#notify
        | exc -> self#notify; raise exc)
    | `Cursor ->
        let locked_iter () = buffer#get_iter_at_mark (`NAME "locked") in
        let cursor_iter () = buffer#get_iter_at_mark `INSERT in
        let forward_until_cursor () = (* go forward until locked > cursor *)
          let rec aux oldpos =
            self#_advance ();
            if (locked_iter ())#compare (cursor_iter ()) < 0 &&
               oldpos#compare (getpos ()) < 0 
            then
              aux (getpos ())
          in
          aux (getpos ())
        in
        let rec back_until_cursor () = (* go backward until locked < cursor *)
          self#_retract ();
          if (locked_iter ())#compare (cursor_iter ()) > 0 then
            back_until_cursor ()
        in
        let cmp = (locked_iter ())#compare (cursor_iter ()) in
        (try
          if cmp < 0 then       (* locked < cursor *)
            (forward_until_cursor (); self#notify)
          else if cmp > 0 then  (* locked > cursor *)
            (back_until_cursor (); self#notify)
          else                  (* cursor = locked *)
              ()
        with 
        | Margin -> self#notify
        | exc -> self#notify; raise exc)
              
  method onGoingProof () =
    match self#status.proof_status with
    | No_proof | Proof _ -> false
    | Incomplete_proof _ -> true
    | Intermediate _ -> assert false

  method proofStatus = MatitaMisc.get_proof_status self#status
  method proofMetasenv = MatitaMisc.get_proof_metasenv self#status
  method proofContext = MatitaMisc.get_proof_context self#status
  method setGoal n = userGoal <- n

  method eos = 
    let s = self#getFuture in
    let rec is_there_and_executable s = 
      if Pcre.pmatch ~rex:only_dust_RE s then raise Margin;
      let st = CicTextualParser2.parse_statement (Stream.of_string s) in
      match st with
      | TacticAst.Comment (loc,_)-> 
          let parsed_text_length = snd (CicAst.loc_of_floc loc) in
          let remain_len = String.length s - parsed_text_length in
          let next = String.sub s parsed_text_length remain_len in
          is_there_and_executable next
      | TacticAst.Executable (loc, ex) -> false
    in
    try
      is_there_and_executable s
    with 
    | CicTextualParser2.Parse_error _ -> false
    | Margin -> true
      
    
    
  (* debug *)
  method dump () =
    MatitaLog.debug "script status:";
    MatitaLog.debug ("history size: " ^ string_of_int (List.length history));
    MatitaLog.debug (sprintf "%d statements:" (List.length statements));
    List.iter MatitaLog.debug statements;
    MatitaLog.debug ("Current file name: " ^
      (match guistuff.filenamedata with 
      |None,_ -> "[ no name ]" 
      | Some f,_ -> f));

end

let _script = ref None

let script ~buffer ~init ~mathviewer ~urichooser ~develcreator ~ask_confirmation ~set_star ()
=
  let s = new script 
    ~buffer ~init ~mathviewer ~ask_confirmation ~urichooser ~develcreator ~set_star () 
  in
  _script := Some s;
  s

let instance () = match !_script with None -> assert false | Some s -> s