(* Copyright (C) 2004-2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

open Printf

open MatitaTypes

(** given a uri and a type list (the contructors types) builds a list of pairs
 *  (name,uri) that is used to generate authomatic aliases **)
let extract_alias types uri = 
  fst(List.fold_left (
    fun (acc,i) (name, _, _, cl) -> 
      ((name, UriManager.string_of_uriref (uri,[i]))
      ::
      (fst(List.fold_left (
        fun (acc,j) (name,_) ->
          (((name,UriManager.string_of_uriref (uri,[i;j])) :: acc) , j+1)
        ) (acc,1) cl))),i+1
  ) ([],0) types)

let env_of_list l env =
 let l' = List.map (fun (name,suri) -> name,suri,CicUtil.term_of_uri (UriManager.uri_of_string suri)) l in
  DisambiguateTypes.env_of_list l' env

let add_aliases_for_inductive_def status types suri = 
  let uri = UriManager.uri_of_string suri in
  let aliases = env_of_list (extract_alias types uri) status.aliases in
  {status with aliases = aliases }

let add_alias_for_constant status suri =
 let uri = UriManager.uri_of_string suri in
 let name = UriManager.name_of_uri uri in
 let new_env = env_of_list [(name,suri)] status.aliases in
 {status with aliases = new_env }

let add_aliases_for_object status suri =
 function
    Cic.InductiveDefinition (types,_,_,_) ->
     add_aliases_for_inductive_def status types suri
  | Cic.Constant _ -> add_alias_for_constant status suri
  | Cic.Variable _
  | Cic.CurrentProof _ -> assert false
  
let paths_and_uris_of_obj uri status =
  let basedir = get_string_option status "basedir" in
  let innertypesuri = UriManager.innertypesuri_of_uri uri in
  let bodyuri = UriManager.bodyuri_of_uri uri in
  let innertypesfilename = Str.replace_first (Str.regexp "^cic:") ""
        (UriManager.string_of_uri innertypesuri) ^ ".xml.gz" in
  let innertypespath = basedir ^ "/" ^ innertypesfilename in
  let xmlfilename = Str.replace_first (Str.regexp "^cic:/") ""
        (UriManager.string_of_uri uri) ^ ".xml.gz" in
  let xmlpath = basedir ^ "/" ^ xmlfilename in
  let xmlbodyfilename = Str.replace_first (Str.regexp "^cic:/") ""
        (UriManager.string_of_uri uri) ^ ".body.xml.gz" in
  let xmlbodypath = basedir ^ "/" ^  xmlbodyfilename in
  xmlpath, xmlbodypath, innertypespath, bodyuri, innertypesuri

let save_object_to_disk status uri obj =
  let ensure_path_exists path =
    let dir = Filename.dirname path in
    MatitaMisc.mkdir dir
  in
  (* generate annobj, ids_to_inner_sorts and ids_to_inner_types *)
  let annobj,_,_,ids_to_inner_sorts,ids_to_inner_types,_,_ =
    Cic2acic.acic_object_of_cic_object ~eta_fix:false obj
  in 
  (* prepare XML *)
  let xml, bodyxml =
   Cic2Xml.print_object uri ~ids_to_inner_sorts ~ask_dtd_to_the_getter:false
    annobj 
  in
  let xmlinnertypes =
   Cic2Xml.print_inner_types uri ~ids_to_inner_sorts ~ids_to_inner_types
    ~ask_dtd_to_the_getter:false
  in
  let xmlpath, xmlbodypath, innertypespath, bodyuri, innertypesuri = 
    paths_and_uris_of_obj uri status 
  in
  let path_scheme_of path = "file://" ^ path in
  List.iter MatitaMisc.mkdir
    (List.map Filename.dirname [innertypespath; xmlpath]);
  (* now write to disk *)
  ensure_path_exists innertypespath;
  Xml.pp ~gzip:true xmlinnertypes (Some innertypespath) ;
  ensure_path_exists xmlpath;
  Xml.pp ~gzip:true xml (Some xmlpath) ;
  (* now register to the getter *)
  Http_getter.register' innertypesuri (path_scheme_of innertypespath); 
  Http_getter.register' uri (path_scheme_of xmlpath);
  (* we return a list of uri,path we registered/created *)
  (uri,xmlpath) :: (innertypesuri,innertypespath) ::
    (* now the optional body, both write and register *)
    (match bodyxml,bodyuri with
       None,None -> []
     | Some bodyxml,Some bodyuri->
         ensure_path_exists xmlbodypath;
         Xml.pp ~gzip:true bodyxml (Some xmlbodypath) ;
         Http_getter.register' bodyuri (path_scheme_of xmlbodypath);
         [bodyuri,xmlbodypath]
     | _-> assert false) 

let remove_object_from_disk uri path =
  Sys.remove path;
  Http_getter.unregister' uri

let add_obj uri obj status =
  let dbd = MatitaDb.instance () in
  let suri = UriManager.string_of_uri uri in
  if CicEnvironment.in_library uri then
    command_error (sprintf "%s already defined" suri)
  else begin
    CicTypeChecker.typecheck_obj uri obj;
    MetadataDb.index_obj ~dbd ~uri; (* must be in the env *)
    let new_stuff = save_object_to_disk status uri obj in  
    MatitaLog.message (sprintf "%s defined" suri);
    let status = add_aliases_for_object status suri obj in
    { status with objects = new_stuff @ status.objects;
                  proof_status = No_proof }
  end
   
module OrderedUri =
struct
  type t = UriManager.uri * string
  let compare (u1, _) (u2, _) = UriManager.compare u1 u2
end

module UriSet = Set.Make (OrderedUri)

(* returns the uri of objects that were added in the meanwhile...
 * status1 ----> status2 
 * assumption: objects defined in status2 are a superset of those defined in
 * status1
 *)
let delta_status status1 status2 =
  let module S = UriSet in
  let diff l1 l2 =
    let s1 = List.fold_left (fun set uri -> S.add uri set) S.empty l1 in
    let s2 = List.fold_left (fun set uri -> S.add uri set) S.empty l2 in
    let diff = S.diff s2 s1 in
    S.fold (fun uri uris -> uri :: uris) diff []
  in
  diff status1.objects status2.objects

let remove_coercion uri = 
  CoercDb.remove_coercion (fun (_,_,u) -> UriManager.eq u uri)
  
let time_travel ~present ~past =
  let list_of_objs_to_remove = List.rev (delta_status past present) in
    (* List.rev is just for the debugging code, which otherwise may list both
    * something.ind and something.ind#xpointer ... (ask Enrico :-) *)
  let debug_list = ref [] in
  List.iter (fun (uri,p) -> 
    remove_object_from_disk uri p;
    remove_coercion uri;
    (try 
      CicEnvironment.remove_obj uri
    with CicEnvironment.Object_not_found _ -> 
      MatitaLog.debug
        (sprintf "time_travel removes from cache %s that is not in" 
          (UriManager.string_of_uri uri)));
    let l = MatitaDb.remove_uri uri in
    debug_list := UriManager.string_of_uri uri :: !debug_list @ l) 
  list_of_objs_to_remove;
  
  (* this is debug code
  * idea: debug_list is the list of objects to be removed as computed from the
  * db, while list_of_objs_to_remove is the same list but computer from the
  * differences between statuses *)
  let l1 = List.sort Pervasives.compare !debug_list in
  let l2 = List.sort Pervasives.compare 
    (List.map (fun (x,_) -> UriManager.string_of_uri x) list_of_objs_to_remove)
  in
  let rec uniq = function 
    | [] -> []
    | h::[] -> [h]
    | h1::h2::tl when h1 = h2 -> uniq (h2 :: tl)
    | h1::tl (* when h1 <> h2 *) -> h1 :: uniq tl
  in
  let l1 =  uniq l1 in
  let l2 =  uniq l2 in
  try
    List.iter2 (fun x y -> if x <> y then raise Exit) l1 l2
  with
  | Invalid_argument _ | Exit -> 
      MatitaLog.debug "It seems you garbaged something...";
      MatitaLog.debug "l1:";
      List.iter MatitaLog.debug l1;
      MatitaLog.debug "l2:";
      List.iter MatitaLog.debug l2
    
let alias_diff ~from status = 
  let module Map = DisambiguateTypes.Environment in
  Map.fold
    (fun domain_item codomain_item acc ->
       if not (Map.mem domain_item from.aliases) then
         Map.add domain_item codomain_item acc
       else
         acc)
    status.aliases Map.empty