(* Copyright (C) 2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

let paths_to_search_in = ref [];;

let add_l l = fun s -> l := s :: !l ;;

let arg_spec = [
  "-I", Arg.String (add_l paths_to_search_in), 
    "<path> Adds path to the list of searched paths for the include command";
]
let usage =
  Printf.sprintf "MatitaDep v%s\nUsage: matitadep [options] file...\nOptions:"
    BuildTimeConf.version

module GA = GrafiteAst 
module U = UriManager

(* all are maps from "file" to "something" *)
let include_deps = Hashtbl.create (Array.length Sys.argv)
let baseuri_of = Hashtbl.create (Array.length Sys.argv)
let uri_deps = Hashtbl.create (Array.length Sys.argv)

let buri alias = 
  U.buri_of_uri (U.uri_of_string alias)

let resolve alias current_buri=
 let buri = buri alias in
  if buri <> current_buri then Some buri else None
 
let find path = 
  let rec aux = function
  | [] -> close_in (open_in path); path
  | p :: tl ->
      try
        close_in (open_in (p ^ "/" ^ path)); p ^ "/" ^ path
      with Sys_error _ -> aux tl
  in
  let paths = !paths_to_search_in in
  try
    aux paths
  with Sys_error _ as exc ->
    MatitaLog.error ("Unable to read " ^ path);
    MatitaLog.error ("opts.include_paths was " ^ String.concat ":" paths);
    raise exc
;;

let main () =
  MatitaInit.load_config_only ();
  let files = ref [] in
  Arg.parse arg_spec (add_l files) usage;
  List.iter
   (fun file -> 
    let ic = open_in file in
    let istream = Stream.of_channel ic in
    let dependencies = GrafiteParser.parse_dependencies istream in
    close_in ic;
    List.iter 
      (function
      | GrafiteAst.UriDep uri -> 
          let uri = UriManager.string_of_uri uri in
          Hashtbl.add uri_deps file uri
      | GrafiteAst.BaseuriDep uri -> 
          let uri = MatitaMisc.strip_trailing_slash uri in
          Hashtbl.add baseuri_of file uri
      | GrafiteAst.IncludeDep path -> 
          try 
            let ma_file = if path <> "coq.ma" then find path else path in
            let moo_file = MatitaMisc.obj_file_of_script ma_file in
            Hashtbl.add include_deps file moo_file
          with Sys_error _ -> 
            MatitaLog.warn 
              ("Unable to find " ^ path ^ " that is included in " ^ file))
    dependencies)
  !files;
  Hashtbl.iter 
    (fun file alias -> 
      let dep = resolve alias (Hashtbl.find baseuri_of file) in
      match dep with 
      | None -> ()
      | Some u -> 
          Hashtbl.add include_deps file (MatitaMisc.obj_file_of_baseuri u))
  uri_deps;
  List.iter
   (fun file -> 
    let deps = Hashtbl.find_all include_deps file in
    let deps = List.fast_sort Pervasives.compare deps in
    let deps = MatitaMisc.list_uniq deps in
    let deps = file :: deps in
    let moo = MatitaMisc.obj_file_of_script file in
     Printf.printf "%s: %s\n" moo (String.concat " " deps);
     Printf.printf "%s: %s\n" (Pcre.replace ~pat:"ma$" ~templ:"mo" file) moo)
  !files
;;
  
let _ =
  main ()