(* Copyright (C) 2004, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

exception Meta_not_found of int
exception Subst_not_found of int


let lookup_meta index metasenv =
  try
    List.find (fun (index', _, _) -> index = index') metasenv
  with Not_found -> raise (Meta_not_found index)

let lookup_subst n subst =
  try
    List.assoc n subst
  with Not_found -> raise (Subst_not_found n)

let exists_meta index = List.exists (fun (index', _, _) -> (index = index'))

(* clean_up_meta take a substitution, a metasenv a meta_inex and a local
context l and clean up l with respect to the hidden hipothesis in the 
canonical context *)

let clean_up_local_context subst metasenv n l =
  let cc =
    (try
       let (cc,_) = lookup_subst n subst in cc
     with Subst_not_found _ ->
       try
	 let (_,cc,_) = lookup_meta n metasenv in cc
       with Meta_not_found _ -> assert false) in
  (try 
     List.map2
       (fun t1 t2 ->
	  match t1,t2 with 
	      None , _ -> None
	    | _ , t -> t) cc l
   with 
       Invalid_argument _ -> assert false)

let is_closed =
 let module C = Cic in
 let rec is_closed k =
  function
      C.Rel m when m > k -> false
    | C.Rel m -> true
    | C.Meta (_,l) ->
       List.fold_left
        (fun i t -> i && (match t with None -> true | Some t -> is_closed k t)
        ) true l
    | C.Sort _ -> true
    | C.Implicit _ -> assert false
    | C.Cast (te,ty) -> is_closed k te && is_closed k ty
    | C.Prod (name,so,dest) -> is_closed k so && is_closed (k+1) dest
    | C.Lambda (_,so,dest) -> is_closed k so && is_closed (k+1) dest
    | C.LetIn (_,so,dest) -> is_closed k so && is_closed (k+1) dest
    | C.Appl l ->
       List.fold_right (fun x i -> i && is_closed k x) l true
    | C.Var (_,exp_named_subst)
    | C.Const (_,exp_named_subst)
    | C.MutInd (_,_,exp_named_subst)
    | C.MutConstruct (_,_,_,exp_named_subst) ->
       List.fold_right (fun (_,x) i -> i && is_closed k x)
        exp_named_subst true
    | C.MutCase (_,_,out,te,pl) ->
       is_closed k out && is_closed k te &&
        List.fold_right (fun x i -> i && is_closed k x) pl true
    | C.Fix (_,fl) ->
       let len = List.length fl in
        let k_plus_len = k + len in
         List.fold_right
          (fun (_,_,ty,bo) i -> i && is_closed k ty && is_closed k_plus_len bo
          ) fl true
    | C.CoFix (_,fl) ->
       let len = List.length fl in
        let k_plus_len = k + len in
         List.fold_right
          (fun (_,ty,bo) i -> i && is_closed k ty && is_closed k_plus_len bo
          ) fl true
in 
 is_closed 0
;;

(* CPS iterators on Cic.term ************************************************)

let rec visit_l visit_t map f r = function
   | []        -> f r
   | h :: tail -> 
      let f r = visit_l visit_t map f r tail in 
      visit_t f r (map h) 

let meta_closed t =
   let rec visit_t f r = function
      | Cic.Meta _                     -> raise Exit
      | Cic.Implicit _
      | Cic.Sort _      
      | Cic.Rel _                      -> f r 
      | Cic.Cast (t, u) 
      | Cic.Prod (_, t, u) 
      | Cic.Lambda (_, t, u) 
      | Cic.LetIn (_, t, u)            -> 
         let f r = visit_t f r u in visit_t f r t 
      | Cic.Appl tl                    -> 
         visit_l visit_t (fun x -> x) f r tl 
      | Cic.Fix (_, tl)                ->  
         let f r = visit_l visit_t (fun (_, _, _, u) -> u) f r tl in
         visit_l visit_t (fun (_, _, t, _) -> t) f r tl
      | Cic.CoFix (_, tl)              -> 
         let f r = visit_l visit_t (fun (_, _, u) -> u) f r tl in
         visit_l visit_t (fun (_, t, _) -> t) f r tl
      | Cic.Var (k, tl)
      | Cic.Const (k, tl)             
      | Cic.MutInd (k, _, tl) 
      | Cic.MutConstruct (k, _, _, tl) -> 
         visit_l visit_t (fun (_, u) -> u) f r tl
      | Cic.MutCase (_, _, t, u, tl)   -> 
         let f r = visit_l visit_t (fun u -> u) f r tl in
         let f r = visit_t f r u in
         visit_t f r t
   in	  
   try visit_t (fun x -> x) () t; false with Exit -> true

let xpointer_RE = Str.regexp "\\([^#]+\\)#xpointer(\\(.*\\))"
let slash_RE = Str.regexp "/"

let term_of_uri s =
  let uri = UriManager.uri_of_string s in
  try
    (if String.sub s (String.length s - 4) 4 = ".con" then
      Cic.Const (uri, [])
    else if String.sub s (String.length s - 4) 4 = ".var" then
      Cic.Var (uri, [])
    else if not (Str.string_match xpointer_RE s 0) then
      raise (UriManager.IllFormedUri s)
    else
      let (baseuri,xpointer) = (Str.matched_group 1 s, Str.matched_group 2 s) in
      let baseuri = UriManager.uri_of_string baseuri in
      (match Str.split slash_RE xpointer with
      | [_; tyno] -> Cic.MutInd (baseuri, int_of_string tyno - 1, [])
      | [_; tyno; consno] ->
          Cic.MutConstruct
            (baseuri, int_of_string tyno - 1, int_of_string consno, [])
      | _ -> raise Exit))
  with
  | Exit
  | Failure _
  | Not_found -> raise (UriManager.IllFormedUri s)