(* Copyright (C) 2000, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

let expect_possible_parameters = ref false;;

exception NotExpectingPossibleParameters;;

let rec deannotate_term =
 let module C = Cic in
  function
     C.ARel (_,_,n,_) -> C.Rel n
   | C.AVar (_,_,uri) -> C.Var uri
   | C.AMeta (_,_,n) -> C.Meta n
   | C.ASort (_,_,s) -> C.Sort s
   | C.AImplicit _ -> C.Implicit
   | C.ACast (_,_,va,ty) -> C.Cast (deannotate_term va, deannotate_term ty)
   | C.AProd (_,_,name,so,ta) ->
      C.Prod (name, deannotate_term so, deannotate_term ta)
   | C.ALambda (_,_,name,so,ta) ->
      C.Lambda (name, deannotate_term so, deannotate_term ta)
   | C.ALetIn (_,_,name,so,ta) ->
      C.LetIn (name, deannotate_term so, deannotate_term ta)
   | C.AAppl (_,_,l) -> C.Appl (List.map deannotate_term l)
   | C.AConst (_,_,uri, cookingsno) -> C.Const (uri, cookingsno)
   | C.AAbst (_,_,uri) -> C.Abst uri
   | C.AMutInd (_,_,uri,cookingsno,i) -> C.MutInd (uri,cookingsno,i)
   | C.AMutConstruct (_,_,uri,cookingsno,i,j) ->
      C.MutConstruct (uri,cookingsno,i,j)
   | C.AMutCase (_,_,uri,cookingsno,i,outtype,te,pl) ->
      C.MutCase (uri,cookingsno,i,deannotate_term outtype,
       deannotate_term te, List.map deannotate_term pl)
   | C.AFix (_,_,funno,ifl) ->
      C.Fix (funno, List.map deannotate_inductiveFun ifl)
   | C.ACoFix (_,_,funno,ifl) ->
      C.CoFix (funno, List.map deannotate_coinductiveFun ifl)

and deannotate_inductiveFun (name,index,ty,bo) =
 (name, index, deannotate_term ty, deannotate_term bo)

and deannotate_coinductiveFun (name,ty,bo) =
 (name, deannotate_term ty, deannotate_term bo)
;;

let deannotate_inductiveType (name, isinductive, arity, cons) =
 (name, isinductive, deannotate_term arity,
  List.map (fun (id,ty,recs) -> (id,deannotate_term ty, recs)) cons)
;;

let deannotate_obj =
 let module C = Cic in
  function
     C.ADefinition (_, _, id, bo, ty, params) ->
      (match params with
          C.Possible params ->
           if !expect_possible_parameters then
            C.Definition (id, deannotate_term bo, deannotate_term ty, params)
           else
            raise NotExpectingPossibleParameters
        | C.Actual params ->
           C.Definition (id, deannotate_term bo, deannotate_term ty, params)
      )
   | C.AAxiom (_, _, id, ty, params) ->
      C.Axiom (id, deannotate_term ty, params)
   | C.AVariable (_, _, name, bo, ty) ->
      C.Variable (name,
       (match bo with None -> None | Some bo -> Some (deannotate_term bo)),
       deannotate_term ty)
   | C.ACurrentProof (_, _, name, conjs, bo, ty) ->
      C.CurrentProof (
       name, List.map (fun (id,con) -> (id,deannotate_term con)) conjs,
       deannotate_term bo, deannotate_term ty
      )
   | C.AInductiveDefinition (_, _, tys, params, parno) ->
      C.InductiveDefinition ( List.map deannotate_inductiveType tys,
       params, parno)
;;