(* Copyright (C) 2000, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

exception IllFormedXml of int;;

(* Utility functions that transform a Pxp attribute into something useful *)

let string_of_attr a =
 let module T = Pxp_types in
  match a with
     T.Value s -> s
   | _ -> raise (IllFormedXml 0)
;;

exception DontKnowWhatToDo;;

let rec string_of_annotations n =
 let module D = Pxp_document in
 let module T = Pxp_types in
  match n#node_type with
     D.T_element s ->
      "<" ^ s ^
      List.fold_right
       (fun att i ->
         match n#attribute att with
            T.Value s -> " " ^ att ^ "=\"" ^ s ^ "\"" ^ i
          | T.Implied_value -> i
          | T.Valuelist l -> " " ^ att ^ "=\"" ^ String.concat " " l ^ "\"" ^ i
       ) (n#attribute_names) "" ^
      (match n#sub_nodes with
          [] -> "/>"
        | l ->
           ">" ^
           String.concat "" (List.map string_of_annotations l) ^
           "</" ^ s ^ ">"
      )
   | D.T_data -> n#data
   | _ -> raise DontKnowWhatToDo
;;

let get_annotation_from_node n =
 String.concat "" (List.map string_of_annotations (n#sub_nodes))
;;

exception MoreThanOneAnnotationFor of Cic.id;;

let set_annotation ids_to_annotations id ann =
 try
  ignore (Hashtbl.find ids_to_annotations id) ;
  raise (MoreThanOneAnnotationFor id)
 with
  Not_found -> Hashtbl.add ids_to_annotations id ann
;;

let get_annotations n =
 let module D = Pxp_document in
 let module C = Cic in
  let ids_to_annotations = Hashtbl.create 503 in
   let annotate_elem n =
    let ntype = n # node_type in
    match ntype with
      D.T_element "Annotation" ->
        let of_uri = string_of_attr (n # attribute "of") in
         set_annotation ids_to_annotations of_uri (get_annotation_from_node n)
    | D.T_element _ | D.T_data ->
       raise (IllFormedXml 1)
    | _ -> raise DontKnowWhatToDo
   in
    match n # node_type with
       D.T_element "Annotations" ->
        List.iter annotate_elem (n # sub_nodes) ;
        ids_to_annotations
     | _ -> raise (IllFormedXml 2)
;;