(* Copyright (C) 2004, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

let debug = true
let debug_print s =
  if debug then begin
    prerr_endline "<NEW_TEXTUAL_PARSER>";
    prerr_endline s;
    prerr_endline "</NEW_TEXTUAL_PARSER>"
  end

open Printf

exception Parse_error of string

let choice_of_uri (uri: string) =
  let cic = HelmLibraryObjects.term_of_uri (UriManager.uri_of_string uri) in
  (uri, (fun _ _ _ -> cic))

let grammar = Grammar.gcreate CicTextualLexer2.cic_lexer

let term = Grammar.Entry.create grammar "term"
let term0 = Grammar.Entry.create grammar "term0"
(* let tactic = Grammar.Entry.create grammar "tactic" *)
(* let tactical = Grammar.Entry.create grammar "tactical" *)

let return_term loc term = CicTextualParser2Ast.LocatedTerm (loc, term)
(* let return_term loc term = term *)

let fail (x, y) msg =
  failwith (Printf.sprintf "Error at characters %d - %d: %s" x y msg)

EXTEND
  GLOBAL: term term0;
  meta_subst: [
    [ s = SYMBOL "_" -> None
    | t = term -> Some t ]
  ];
  binder: [
    [ SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
    | SYMBOL <:unicode<pi>> (* π *) -> `Pi
    | SYMBOL <:unicode<exists>> (* ∃ *) -> `Exists
    | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
    ]
  ];
  substituted_name: [ (* a subs.name is an explicit substitution subject *)
    [ s = [ IDENT | SYMBOL ];
      subst = OPT [
        SYMBOL "\subst";  (* to avoid catching frequent "a [1]" cases *)
        PAREN "[";
        substs = LIST1 [
          i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
        ] SEP SYMBOL ";";
        PAREN "]" ->
          substs
      ] ->
        (match subst with
        | Some l -> CicTextualParser2Ast.Ident (s, l)
        | None -> CicTextualParser2Ast.Ident (s, []))
    ]
  ];
  name: [ (* as substituted_name with no explicit substitution *)
    [ s = [ IDENT | SYMBOL ] -> s ]
  ];
  pattern: [
    [ n = name -> [n]
    | PAREN "("; names = LIST1 name; PAREN ")" -> names ]
  ];
  term0: [ [ t = term -> return_term loc t ] ];
  term:
    [ "arrow" RIGHTA
      [ t1 = term; SYMBOL <:unicode<to>>; t2 = term ->
          return_term loc
            (CicTextualParser2Ast.Binder (`Pi, Cic.Anonymous, Some t1, t2))
      ]
    | "binder" RIGHTA
      [
        b = binder; vars = LIST1 IDENT SEP SYMBOL ",";
        typ = OPT [ SYMBOL ":"; t = term -> t ];
        SYMBOL "."; body = term ->
          let binder =
            List.fold_right
              (fun var body ->
                let name =
                  match var with
                  | "_" -> Cic.Anonymous
                  | var -> Cic.Name var
                in
                CicTextualParser2Ast.Binder (b, name, typ, body))
              vars body
          in
          return_term loc binder
      ]
    | "eq" LEFTA
      [ t1 = term; SYMBOL "="; t2 = term ->
        return_term loc (CicTextualParser2Ast.Appl_symbol ("eq", 0, [t1; t2]))
      ]
    | "add" LEFTA     [ (* nothing here by default *) ]
    | "mult" LEFTA    [ (* nothing here by default *) ]
    | "inv" NONA      [ (* nothing here by default *) ]
    | "simple" NONA
      [
        sort_kind = [
          "Prop" -> `Prop | "Set" -> `Set | "Type" -> `Type | "CProp" -> `CProp
        ] ->
          CicTextualParser2Ast.Sort sort_kind
      | n = substituted_name -> return_term loc n
      | PAREN "("; head = term; args = LIST1 term; PAREN ")" ->
          return_term loc (CicTextualParser2Ast.Appl (head :: args))
      | i = NUM -> return_term loc (CicTextualParser2Ast.Num (i, 0))
      | m = META;
        substs = [
          PAREN "["; substs = LIST0 meta_subst SEP SYMBOL ";" ; PAREN "]" ->
            substs
        ] ->
            let index =
              try
                int_of_string (String.sub m 1 (String.length m - 1))
              with Failure "int_of_string" ->
                fail loc ("Invalid meta variable number: " ^ m)
            in
            return_term loc (CicTextualParser2Ast.Meta (index, substs))
        (* actually "in" and "and" are _not_ keywords. Parsing works anyway
         * since applications are required to be bound by parens *)
      | "let"; name = IDENT;
(*         SYMBOL <:unicode<def>> (* ≝ *); *)
        SYMBOL "=";
        t1 = term;
        IDENT "in"; t2 = term ->
          return_term loc (CicTextualParser2Ast.LetIn (name, t1, t2))
      | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
          defs = LIST1 [
            name = IDENT;
            index = OPT [ PAREN "("; index = NUM; PAREN ")" ->
              int_of_string index
            ];
            typ = OPT [ SYMBOL ":"; typ = term -> typ ];
(*             SYMBOL <:unicode<def>> (* ≝ *); *)
            SYMBOL "=";
            t1 = term ->
              (name, t1, typ, (match index with None -> 1 | Some i -> i))
          ] SEP (IDENT "and");
          IDENT "in"; body = term ->
            return_term loc (CicTextualParser2Ast.LetRec (ind_kind, defs, body))
      | outtyp = OPT [ PAREN "["; typ = term; PAREN "]" -> typ ];
        "match"; t = term;
        SYMBOL ":"; indty = IDENT;
        "with";
        PAREN "[";
        patterns = LIST0 [
          p = pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *); t = term ->
            (p, t)
        ] SEP SYMBOL "|";
        PAREN "]" ->
          return_term loc
            (CicTextualParser2Ast.Case (t, indty, outtyp, patterns))
      | PAREN "("; t = term; PAREN ")" -> return_term loc t
      ]
    ];
END

let parse_term stream =
  try
    Grammar.Entry.parse term0 stream
  with Stdpp.Exc_located ((x, y), exn) ->
    raise (Parse_error (sprintf "parse error at characters %d-%d: %s" x y
        (Printexc.to_string exn)))

(**/**)

(** {2 Interface for gTopLevel} *)

open DisambiguateTypes

module EnvironmentP3 =
  struct
    type t = environment

    let empty = ""

    let aliases_grammar = Grammar.gcreate CicTextualLexer2.cic_lexer
    let aliases = Grammar.Entry.create aliases_grammar "aliases"

    let to_string env =
      let aliases =
        Environment.fold
          (fun domain_item (dsc, _) acc ->
            let s =
              match domain_item with
              | Id id -> sprintf "alias id %s = %s" id dsc
              | Symbol (symb, instance) ->
                  sprintf "alias symbol \"%s\" (instance %d) = \"%s\""
                    symb instance dsc
              | Num instance ->
                  sprintf "alias num (instance %d) = \"%s\"" instance dsc
            in
            s :: acc)
          env []
      in
      String.concat "\n" (List.sort compare aliases)

    EXTEND
      GLOBAL: aliases;
      aliases: [  (* build an environment from an aliases list *)
        [ aliases = LIST0 alias; EOI ->
            List.fold_left
              (fun env (domain_item, codomain_item) ->
                Environment.add domain_item codomain_item env)
              Environment.empty aliases
        ]
      ];
      alias: [  (* return a pair <domain_item, codomain_item> from an alias *)
        [ IDENT "alias";
          choice =
            [ IDENT "id"; id = IDENT; SYMBOL "="; uri = URI ->
                (Id id, choice_of_uri uri)
            | IDENT "symbol"; symbol = QSTRING;
              PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
              SYMBOL "="; dsc = QSTRING ->
                (Symbol (symbol, int_of_string instance),
                 DisambiguateChoices.lookup_symbol_by_dsc symbol dsc)
            | IDENT "num";
              PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
              SYMBOL "="; dsc = QSTRING ->
                (Num (int_of_string instance),
                 DisambiguateChoices.lookup_num_by_dsc dsc)
            ] -> choice ]
      ];
    END

    let of_string s =
      if s = empty then
        Environment.empty
      else
        try
          Grammar.Entry.parse aliases (Stream.of_string s)
        with Stdpp.Exc_located ((x, y), exn) ->
          raise (Parse_error (sprintf "parse error at characters %d-%d: %s" x y
          (Printexc.to_string exn)))
  end