(* Copyright (C) 2004, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

open Disambiguate_struct
open Disambiguate_types

let debug = true
let debug_print = if debug then prerr_endline else ignore

type interpretation_domain = Domain.t
type domain_and_interpretation = interpretation_domain * interpretation

let string_of_interpretation_domain_item = function
  | Id s -> "ID " ^ s
  | Symbol (s, i) -> "SYMBOL " ^ s ^ " " ^ string_of_int i
  | Num (s, i) -> "NUM " ^ s ^ " " ^ string_of_int i

let descr_of_domain_item = function
 | Id s -> s
 | Symbol (s, _) -> s
 | Num (s, _) -> s

let rec build_natural =
  function
  | 0 -> HelmLibraryObjects.Datatypes.zero
  | n -> Cic.Appl [ HelmLibraryObjects.Datatypes.succ; (build_natural (n - 1)) ]

exception Invalid_choice

let symbol_choices: (string, interpretation_codomain_item list) Hashtbl.t = Hashtbl.create 1023
let _ =
  Hashtbl.add symbol_choices "eq"
    [ ("Leibnitz's equality",
     (fun interp args ->
       let t1, t2 =
         match args with
         | [t1; t2] -> t1, t2
         | _ -> raise Invalid_choice
       in
       Cic.Appl [
         Cic.MutInd (HelmLibraryObjects.Logic.eq_URI, 0, []);
           Cic.Implicit; t1; t2
       ])) ]
(*
let add_symbol_choice = Hashtbl.add symbol_choices
let add_symbol_choices symbol = List.iter (add_symbol_choice symbol)
*)
let num_choices =
  ref [
    "natural number",
    (fun num ->
      let num = int_of_string num in
      assert (num >= 0);
      build_natural num)
  ]

let add_num_choice choice =
  num_choices := choice :: !num_choices

type test_result =
  | Ok of Cic.term * Cic.metasenv
  | Ko
  | Uncertain

let refine metasenv context term =
  let metasenv, term = CicMkImplicit.expand_implicits metasenv context term in
  try
    let term', _, _, metasenv' = CicRefine.type_of_aux' metasenv context term in
    Ok (term', metasenv')
  with
    | CicRefine.MutCaseFixAndCofixRefineNotImplemented ->
        (* TODO remove this case as soon as refine is fully implemented *)
        (try
          let term' = CicTypeChecker.type_of_aux' metasenv context term in
          Ok (term',metasenv)
        with _ -> Ko)
    | CicRefine.Uncertain _ ->
        debug_print ("%%% UNCERTAIN!!! " ^ CicPp.ppterm term) ;
        Uncertain
    | _ ->
        debug_print ("%%% PRUNED!!! " ^ CicPp.ppterm term) ;
        Ko

open Printf

open UriManager

let indtyuri_of_uri uri =
  let index_sharp =  String.index uri '#' in
  let index_num = index_sharp + 3 in
  (UriManager.uri_of_string (String.sub uri 0 index_sharp),
   int_of_string(String.sub uri index_num (String.length uri - index_num)) - 1)

let indconuri_of_uri uri =
  let index_sharp =  String.index uri '#' in
  let index_div = String.rindex uri '/' in
  let index_con = index_div + 1 in
    (UriManager.uri_of_string (String.sub uri 0 index_sharp),
    int_of_string
      (String.sub uri (index_sharp + 3) (index_div - index_sharp - 3)) - 1,
    int_of_string
      (String.sub uri index_con (String.length uri - index_con)))

  (* TODO move it to Cic *)
let term_of_uri uri =
  try
  (* Constant *)
  (* TODO explicit substitutions? *)
  let len = String.length uri in
  if String.sub uri (len - 4) 4 = ".con" then
    Cic.Const (uri_of_string uri, [])
  else if String.sub uri (len - 4) 4 = ".var" then
    Cic.Var (uri_of_string uri, [])
  else
    (try
      (* Inductive Type *)
      let uri',typeno = indtyuri_of_uri uri in
      Cic.MutInd (uri', typeno, [])
     with
      | UriManager.IllFormedUri _ | Failure _ | Invalid_argument _ ->
          (* Constructor of an Inductive Type *)
          let uri',typeno,consno = indconuri_of_uri uri in
          Cic.MutConstruct (uri', typeno, consno, []))
 with
 | Invalid_argument _ -> raise (UriManager.IllFormedUri uri)

module Make (C: Callbacks) =
  struct
    exception NoWellTypedInterpretation

    let choices_of_id mqi_handle id =
     let query  =  MQueryGenerator.locate id in
     let result = MQueryInterpreter.execute mqi_handle query in
     let uris =
      List.map
       (function uri,_ ->
         MQueryMisc.wrong_xpointer_format_from_wrong_xpointer_format' uri
       ) result in
      C.output_html (`Msg (`T "Locate query:"));
      MQueryUtil.text_of_query
       (fun s -> C.output_html ~append_NL:false (`Msg (`T s)))
       "" query; 
      C.output_html (`Msg (`T "Result:"));
      MQueryUtil.text_of_result
        (fun s -> C.output_html (`Msg (`T s))) "" result;
      let uris' =
       match uris with
        | [] ->
           [UriManager.string_of_uri (C.input_or_locate_uri
            ~title:("URI matching \"" ^ id ^ "\" unknown."))]
        | [uri] -> [uri]
        | _ ->
            C.interactive_user_uri_choice ~selection_mode:`MULTIPLE
             ~ok:"Try every selection." ~enable_button_for_non_vars:true
             ~title:"Ambiguous input." ~id
             ~msg: ("Ambiguous input \"" ^ id ^
                "\". Please, choose one or more interpretations:")
             uris
      in
      List.map (fun uri -> (uri, term_of_uri uri)) uris'

    let disambiguate_input
      mqi_handle context metasenv parser_dom parser_mk_term
      (current_dom, current_interpretation)
    =
      debug_print "NEW DISAMBIGUATE INPUT";
      let todo_dom = Domain.diff parser_dom current_dom in
      (* (1) for each item in todo_dom we get the associated list of choices *)
      let id_choices = Hashtbl.create 1023 in
      let _ =
        Domain.iter
          (function
            | Id id ->
                  (* pairs <description, term> *)
                let choices = choices_of_id mqi_handle id in
                debug_print (sprintf
                  "CHOICES_OF_ID di %s ha restituito %d scelte"
                  id (List.length choices));
                Hashtbl.add id_choices id choices
            | _ -> assert false)
          (Domain.filter (function Id _ -> true | _ -> false) todo_dom)
      in
      (* (2) lookup function for any item (Id/Symbol/Num) *)
      let lookup_choices item =
        try
          (match item with
          | Id id ->
              let choices = Hashtbl.find id_choices id in
              List.map (fun (descr, term) -> (descr, fun _ _ -> term)) choices
          | Symbol (symb, _) -> Hashtbl.find symbol_choices symb
          | Num (num, _) ->
              List.map
                (fun (descr, f) -> (descr, let term = f num in fun _ _ -> term))
                !num_choices)
        with Not_found -> assert false
      in
      (* (3) test an interpretation filling with meta uninterpreted identifiers
       *)
      let test_interpretation current_interpretation todo_dom =
        let filled_interpretation =
          Domain.fold
            (fun item' interpretation ->
              fun item ->
                if item = item' then
                  "Implicit", fun _ _ -> Cic.Implicit
                else
                  interpretation item)
            todo_dom current_interpretation
        in
        let term' = parser_mk_term filled_interpretation in
        refine metasenv context term'
      in
      (* (4) build all possible interpretations *)
      let rec aux current_interpretation todo_dom =
        if Domain.is_empty todo_dom then
          match test_interpretation current_interpretation Domain.empty with
          | Ok (term, metasenv) -> [ current_interpretation, term, metasenv ]
          | Ko | Uncertain -> []
        else
          let item = Domain.choose todo_dom in
          debug_print (sprintf "CHOOSED ITEM: %s"
            (string_of_interpretation_domain_item item));
          let remaining_dom = Domain.remove item todo_dom in
          let choices = lookup_choices item in
          let rec filter = function
            | [] -> []
            | codomain_item :: tl ->
                let new_interpretation =
                  fun item' ->
                    if item' = item then
                      codomain_item
                    else
                      current_interpretation item'
                in
                (match test_interpretation new_interpretation remaining_dom with
                | Ok (term, metasenv) ->
                    (if Domain.is_empty remaining_dom then
                      [ new_interpretation, term, metasenv ]
                    else
                      aux new_interpretation remaining_dom)
                    @ filter tl
                | Uncertain ->
                    (if Domain.is_empty remaining_dom then
                      []
                    else
                      aux new_interpretation remaining_dom)
                    @ filter tl
                | Ko -> filter tl)
          in
          filter choices
      in
      let (choosed_interpretation, choosed_term, choosed_metasenv) =
        match aux current_interpretation todo_dom with
        | [] -> raise NoWellTypedInterpretation
        | [ x ] ->
            debug_print "UNA SOLA SCELTA";
            x
        | l ->
            debug_print "PIU' SCELTE";
            let choices =
              List.map
                (fun (interpretation, _, _) ->
                  List.map
                    (fun domain_item ->
                      let description = fst (interpretation domain_item) in
(*
                        match interpretation domain_item with
                        | None -> assert false
                        | Some (descr, _) -> descr
                      in
*)
                      (descr_of_domain_item domain_item, description))
                    (Domain.elements parser_dom))
                l
            in
            let choosed = C.interactive_interpretation_choice choices in
            List.nth l choosed
      in
      (Domain.union current_dom todo_dom, choosed_interpretation),
       choosed_metasenv, choosed_term

  end

let apply_interp (interp: interpretation) item = snd (interp item)

let interpretate ~context ~interp ast =
  let rec aux loc context = function
    | Ast.LocatedTerm (loc, term) -> aux loc context term
    | Ast.Appl terms -> Cic.Appl (List.map (aux loc context) terms)
    | Ast.Appl_symbol (symb, args) ->
        let cic_args = List.map (aux loc context) args in
        apply_interp interp (Symbol (symb, 0)) interp cic_args
    | Ast.Binder (binder_kind, var, typ, body) ->
        let cic_type = aux_option loc context typ in
        let cic_body = aux loc (Some var :: context) body in
        (match binder_kind with
        | `Lambda -> Cic.Lambda (var, cic_type, cic_body)
        | `Pi | `Forall -> Cic.Prod (var, cic_type, cic_body)
        | `Exists ->
            apply_interp interp (Symbol ("exists", 0)) interp
              [ cic_type; Cic.Lambda (var, cic_type, cic_body) ])
    | Ast.Case (term, indty_ident, outtype, branches) ->
        let cic_term = aux loc context term in
        let cic_outtype = aux_option loc context outtype in
        let do_branch (pat, term) =
          let rec do_branch' context = function
            | [] -> aux loc context term
            | hd :: tl ->
                let cic_body = do_branch' (Some (Cic.Name hd) :: context) tl in
                Cic.Lambda (Cic.Name hd, Cic.Implicit, cic_body)
          in
          match pat with
          | _ :: tl -> (* ignoring constructor *) do_branch' context tl
          | [] -> assert false
        in
        let (indtype_uri, indtype_no) =
          match apply_interp interp (Id indty_ident) interp [] with
          | Cic.MutInd (uri, tyno, _) -> uri, tyno
          | _ -> Parser.fail loc ("Not an inductive type: " ^ indty_ident)
        in
        Cic.MutCase (indtype_uri, indtype_no, cic_outtype, cic_term,
          (List.map do_branch branches))
    | Ast.LetIn (var, def, body) ->
        let cic_def = aux loc context def in
        let name = Cic.Name var in
        let cic_body = aux loc (Some name :: context) body in
        Cic.LetIn (name, cic_def, cic_body)
    | Ast.LetRec (kind, defs, body) ->
        let context' =
          List.fold_left (fun acc (var, _, _, _) -> Some (Cic.Name var) :: acc)
            context defs
        in
        let cic_body = aux loc context' body in
        let inductiveFuns =
          List.map
            (fun (var, body, typ, decr_idx) ->
              let cic_body = aux loc context' body in
              let cic_type = aux_option loc context typ in
              (var, decr_idx, cic_type, cic_body))
            defs
        in
        let counter = ref 0 in
        let build_term funs =
          (* this is the body of the fold_right function below. Rationale: Fix
           * and CoFix cases differs only in an additional index in the
           * indcutiveFun list, see Cic.term *)
          match kind with
          | `Inductive ->
              (fun (var, _, _, _) cic ->
                incr counter;
                Cic.LetIn (Cic.Name var, Cic.Fix (!counter, funs), cic))
          | `CoInductive ->
              let funs =
                List.map (fun (name, _, typ, body) -> (name, typ, body)) funs
              in
              (fun (var, _, _, _) cic ->
                Cic.LetIn (Cic.Name var, Cic.CoFix (!counter, funs), cic))
        in
        List.fold_right (build_term inductiveFuns) inductiveFuns cic_body
    | Ast.Ident (name, subst) ->
        let rec find acc e = function
          | [] -> raise Not_found
          | Some (Cic.Name hd) :: tl when e = hd -> acc
          | _ :: tl ->  find (acc + 1) e tl
        in
        (try
          let index = find 1 name context in
          if subst <> [] then
            Parser.fail loc "Explicit substitutions not allowed here";
          Cic.Rel index
        with Not_found ->
          apply_interp interp (Id name) interp [])
    | Ast.Num num -> apply_interp interp (Num (num, 0)) interp []
    | Ast.Meta (index, subst) ->
        let cic_subst =
          List.map
            (function None -> None | Some term -> Some (aux loc context term))
            subst
        in
        Cic.Meta (index, cic_subst)
    | Ast.Sort `Prop -> Cic.Sort Cic.Prop
    | Ast.Sort `Set -> Cic.Sort Cic.Set
    | Ast.Sort `Type -> Cic.Sort Cic.Type
    | Ast.Sort `CProp -> Cic.Sort Cic.CProp
  and aux_option loc context = function
    | None -> Cic.Implicit
    | Some term -> aux loc context term
  in
  match ast with
  | Ast.LocatedTerm (loc, term) -> aux loc context term
  | _ -> assert false