(* Copyright (C) 2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

open GrafiteAst

type notation_id =
  | RuleId of CicNotationParser.rule_id
  | InterpretationId of CicNotationRew.interpretation_id
  | PrettyPrinterId of CicNotationRew.pretty_printer_id

let process_notation st =
  match st with
  | Notation (loc, dir, l1, associativity, precedence, l2) ->
      let rule_id =
        if dir <> Some `RightToLeft then
          [ RuleId (CicNotationParser.extend l1 ?precedence ?associativity
              (fun env loc -> CicNotationFwd.instantiate_level2 env l2)) ]
        else
          []
      in
      let pp_id =
        if dir <> Some `LeftToRight then
          [ PrettyPrinterId
              (CicNotationRew.add_pretty_printer ?precedence ?associativity
                l2 l1) ]
        else
          []
      in
      st, rule_id @ pp_id
  | Interpretation (loc, dsc, l2, l3) ->
      let interp_id = CicNotationRew.add_interpretation dsc l2 l3 in
      st, [ InterpretationId interp_id ]
  | st -> st, []

let remove_notation = function
  | RuleId id -> CicNotationParser.delete id
  | PrettyPrinterId id -> CicNotationRew.remove_pretty_printer id
  | InterpretationId id -> CicNotationRew.remove_interpretation id

let load_notation fname =
  let ic = open_in fname in
  let lexbuf = Ulexing.from_utf8_channel ic in
  try
    while true do
      match GrafiteParser.parse_statement lexbuf with
      | Executable (_, Command (_, cmd)) -> ignore (process_notation cmd)
      | _ -> ()
    done
  with End_of_file -> close_in ic

let get_all_notations () =
  List.map
    (fun (interp_id, dsc) ->
      InterpretationId interp_id, "interpretation: " ^ dsc)
    (CicNotationRew.get_all_interpretations ())

let get_active_notations () =
  List.map (fun id -> InterpretationId id)
    (CicNotationRew.get_active_interpretations ())

let set_active_notations ids =
  let interp_ids =
    HExtlib.filter_map
      (function InterpretationId interp_id -> Some interp_id | _ -> None)
      ids
  in
  CicNotationRew.set_active_interpretations interp_ids