(* Copyright (C) 2004-2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

open CicNotationPt

exception Value_not_found of string

type value =
  | TermValue of term
  | StringValue of string
  | NumValue of string
  | OptValue of value option
  | ListValue of value list

type value_type =
  | TermType
  | StringType
  | NumType
  | OptType of value_type
  | ListType of value_type

type declaration = string * value_type
type binding = string * (value_type * value)
type t = (string * (value_type * value)) list

let lookup_value env name =
  try
    snd (List.assoc name env)
  with Not_found -> raise (Value_not_found name)

let lookup_term env name =
  match lookup_value env name with
  | TermValue x -> x
  | _ -> raise (Value_not_found name)

let lookup_num env name =
  match lookup_value env name with
  | NumValue x -> x
  | _ -> raise (Value_not_found name)

let lookup_string env name =
  match lookup_value env name with
  | StringValue x -> x
  | _ -> raise (Value_not_found name)

let opt_binding_some (n, (ty, v)) = (n, (OptType ty, OptValue (Some v)))
let opt_binding_none (n, (ty, v)) = (n, (OptType ty, OptValue None))
let opt_binding_of_name (n, ty) = (n, (OptType ty, OptValue None))
let list_binding_of_name (n, ty) = (n, (ListType ty, ListValue []))
let opt_declaration (n, ty) = (n, OptType ty)
let list_declaration (n, ty) = (n, ListType ty)