(* Copyright (C) 2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

open Printf

exception Parse_error of Token.flocation * string
exception Level_not_found of int

let grammar = Grammar.gcreate CicNotationLexer.notation_lexer

let level1_pattern = Grammar.Entry.create grammar "level1_pattern"
let level2_pattern = Grammar.Entry.create grammar "level2_pattern"
let level3_term = Grammar.Entry.create grammar "level3_term"
let notation = Grammar.Entry.create grammar "notation" (* level1 <-> level 2 *)
let interpretation =
  Grammar.Entry.create grammar "interpretation" (* level2 <-> level 3 *)

let return_term loc term = ()

let loc_of_floc = function
  | { Lexing.pos_cnum = loc_begin }, { Lexing.pos_cnum = loc_end } ->
      (loc_begin, loc_end)

let fail floc msg =
  let (x, y) = loc_of_floc floc in
  failwith (sprintf "Error at characters %d - %d: %s" x y msg)

let int_of_string s =
  try
    Pervasives.int_of_string s
  with Failure _ ->
    failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)

open CicNotationPt

let boxify = function
  | [ a ] -> a
  | l -> Layout (Box (H, l))

let fold_binder binder pt_names body =
  let fold_cluster binder names ty body =
    List.fold_right
      (fun name body -> Binder (binder, (Cic.Name name, ty), body))
      names body
  in
  List.fold_right
    (fun (names, ty) body -> fold_cluster binder names ty body)
    pt_names body

let return_term loc term = AttributedTerm (`Loc loc, term)

EXTEND
  GLOBAL: level1_pattern level2_pattern level3_term
          notation interpretation;
(* {{{ Grammar for concrete syntax patterns, notation level 1 *)
  level1_pattern: [ [ p = l1_pattern; EOI -> boxify p ] ];
  l1_pattern: [ [ p = LIST0 l1_simple_pattern -> p ] ];
  literal: [
    [ s = SYMBOL -> `Symbol s
    | k = KEYWORD -> `Keyword k
    | n = NUMBER -> `Number n
    ]
  ];
  sep:       [ [ SYMBOL "\\SEP";      sep = literal -> sep ] ];
(*   row_sep:   [ [ SYMBOL "\\ROWSEP";   sep = literal -> sep ] ];
  field_sep: [ [ SYMBOL "\\FIELDSEP"; sep = literal -> sep ] ]; *)
  l1_magic_pattern: [
    [ SYMBOL "\\LIST0"; p = l1_simple_pattern; sep = OPT sep -> List0 (p, sep)
    | SYMBOL "\\LIST1"; p = l1_simple_pattern; sep = OPT sep -> List1 (p, sep)
    | SYMBOL "\\OPT";   p = l1_simple_pattern -> Opt p
    ]
  ];
  l1_pattern_variable: [
    [ id = IDENT -> TermVar id
    | SYMBOL "\\TERM"; id = IDENT -> TermVar id
    | SYMBOL "\\NUM"; id = IDENT -> NumVar id
    | SYMBOL "\\IDENT"; id = IDENT -> IdentVar id
    ]
  ];
  l1_simple_pattern:
    [ "layout" LEFTA
      [ p1 = SELF; SYMBOL "\\SUB"; p2 = SELF ->
          return_term loc (Layout (Sub (p1, p2)))
      | p1 = SELF; SYMBOL "\\SUP"; p2 = SELF ->
          return_term loc (Layout (Sup (p1, p2)))
      | p1 = SELF; SYMBOL "\\BELOW"; p2 = SELF ->
          return_term loc (Layout (Below (p1, p2)))
      | p1 = SELF; SYMBOL "\\ABOVE"; p2 = SELF ->
          return_term loc (Layout (Above (p1, p2)))
      | SYMBOL "["; p1 = l1_pattern; SYMBOL "\\OVER"; p2 = l1_pattern;
        SYMBOL "]" ->
          return_term loc (Layout (Over (boxify p1, boxify p2)))
      | SYMBOL "["; p1 = l1_pattern; SYMBOL "\\ATOP"; p2 = l1_pattern;
        SYMBOL "]" ->
          return_term loc (Layout (Atop (boxify p1, boxify p2)))
(*       | SYMBOL "\\ARRAY"; p = SELF; csep = OPT field_sep; rsep = OPT row_sep ->
          return_term loc (Array (p, csep, rsep)) *)
      | SYMBOL "\\FRAC"; p1 = SELF; p2 = SELF ->
          return_term loc (Layout (Frac (p1, p2)))
      | SYMBOL "\\SQRT"; p = SELF -> return_term loc (Layout (Sqrt p))
      | SYMBOL "\\ROOT"; index = l1_pattern; SYMBOL "\\OF"; arg = SELF ->
          return_term loc (Layout (Root (arg, Layout (Box (H, index)))))
      | SYMBOL "\\HBOX"; SYMBOL "["; p = l1_pattern; SYMBOL "]" ->
          return_term loc (Layout (Box (H, p)))
      | SYMBOL "\\VBOX"; SYMBOL "["; p = l1_pattern; SYMBOL "]" ->
          return_term loc (Layout (Box (V, p)))
      | SYMBOL "\\BREAK" -> return_term loc (Layout Break)
      | SYMBOL "["; p = l1_pattern; SYMBOL "]" ->
          return_term loc (boxify p)
      | SYMBOL "["; p = l1_pattern; SYMBOL "\\AS"; id = IDENT; SYMBOL "]" ->
          return_term loc (Variable (Ascription (Layout (Box (H, p)), id)))
      ]
    | "simple" NONA
      [ m = l1_magic_pattern -> return_term loc (Magic m)
      | v = l1_pattern_variable -> return_term loc (Variable v)
      | l = literal -> return_term loc (Literal l)
      ]
    ];
(* }}} *)
(* {{{ Grammar for ast patterns, notation level 2 *)
  level2_pattern: [ [ p = l2_pattern -> p ] ];
  sort: [
    [ SYMBOL "\\PROP" -> `Prop
    | SYMBOL "\\SET" -> `Set
    | SYMBOL "\\TYPE" -> `Type
    ]
  ];
  explicit_subst: [
    [ (* TODO explicit substitution *)
    ]
  ];
  meta_subst: [
    [ (* TODO meta substitution *)
    ]
  ];
  possibly_typed_name: [
    [ SYMBOL "("; id = IDENT; SYMBOL ":"; typ = l2_pattern; SYMBOL ")" ->
        Cic.Name id, Some typ
    | id = IDENT -> Cic.Name id, None
    ]
  ];
  match_pattern: [
    [ id = IDENT -> id, []
    | SYMBOL "("; id = IDENT; vars = LIST1 possibly_typed_name; SYMBOL ")" ->
        id, vars
    ]
  ];
  binder: [
    [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
    | SYMBOL <:unicode<exists>> (* ∃ *) -> `Exists
    | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
    | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
    ]
  ];
  bound_names: [
    [ vars = LIST1 IDENT SEP SYMBOL ",";
      ty = OPT [ SYMBOL ":"; p = l2_pattern -> p ] ->
        [ vars, ty ]
    | clusters = LIST1 [
        SYMBOL "(";
        vars = LIST1 IDENT SEP SYMBOL ",";
        ty = OPT [ SYMBOL ":"; p = l2_pattern -> p ];
        SYMBOL ")" ->
          vars, ty
      ] ->
        clusters
    ]
  ];
  induction_kind: [
    [ IDENT "rec" -> `Inductive
    | IDENT "corec" -> `CoInductive
    ]
  ];
  let_defs: [
    [ defs = LIST1 [
        name = IDENT; args = bound_names;
        index_name = OPT [ IDENT "on"; id = IDENT -> id ];
        ty = OPT [ SYMBOL ":" ; p = l2_pattern -> p ];
        SYMBOL <:unicode<def>> (* ≝ *); body = l2_pattern ->
          let body = fold_binder `Lambda args body in
          let ty = 
            match ty with 
            | None -> None
            | Some ty -> Some (fold_binder `Pi args ty)
          in
          let rec position_of name p = function 
            | [] -> None, p
            | n :: _ when n = name -> Some p, p
            | _ :: tl -> position_of name (p + 1) tl
          in
          let rec find_arg name n = function 
            | [] -> fail loc (sprintf "Argument %s not found" name)
            | (l,_) :: tl -> 
                (match position_of name 0 l with
                | None, len -> find_arg name (n + len) tl
                | Some where, len -> n + where)
          in
          let index = 
            match index_name with 
            | None -> 0 
            | Some name -> find_arg name 0 args
          in
          (Cic.Name name, ty), body, index
      ] SEP IDENT "and" ->
        defs
    ]
  ];
  l2_pattern_variable: [
    [ SYMBOL "\\NUM"; id = IDENT -> NumVar id
    | SYMBOL "\\IDENT"; id = IDENT -> IdentVar id
    | SYMBOL "\\FRESH"; id = IDENT -> FreshVar id
    ]
  ];
  l2_magic_pattern: [
    [ SYMBOL "\\FOLD";
      kind = [ IDENT "left" -> `Left | IDENT "right" -> `Right ];
      base = l2_pattern;
      SYMBOL "\\LAMBDA"; id = IDENT; recursive = l2_pattern ->
        Fold (kind, base, [id], recursive)
    | SYMBOL "\\DEFAULT"; some = l2_pattern; none = l2_pattern ->
        Default (some, none)
    ]
  ];
  l2_pattern:
    [ "0" [ ]
    | "10" NONA (* let in *)
      [ IDENT "let"; var = possibly_typed_name; SYMBOL <:unicode<def>> (* ≝ *);
        p1 = l2_pattern; "in"; p2 = l2_pattern ->
          return_term loc (LetIn (var, p1, p2))
      | IDENT "let"; k = induction_kind; defs = let_defs; IDENT "in";
        body = l2_pattern ->
          return_term loc (LetRec (k, defs, body))
      ]
    | "20" RIGHTA (* binder *)
      [ b = binder; names = bound_names; SYMBOL "."; body = l2_pattern ->
          return_term loc (fold_binder b names body)
      ]
    | "30" [ ]
    | "40" [ ]
    | "50" [ ]
    | "60" [ ]
    | "70" LEFTA (* apply *)
      [ p1 = l2_pattern; p2 = l2_pattern ->
          let rec aux = function
            | Appl (hd :: tl)
            | AttributedTerm (_, Appl (hd :: tl)) ->
                aux hd @ tl
            | term -> [term]
          in
          return_term loc (Appl (aux p1 @ [p2]))
      ]
    | "80" [ ]
    | "90" NONA (* simple *)
      [ id = IDENT -> return_term loc (Ident (id, None))
      | id = IDENT; s = explicit_subst -> return_term loc (Ident (id, Some s))
      | u = URI -> return_term loc (Uri (u, None))
      | n = NUMBER -> return_term loc (Num (n, 0))
      | IMPLICIT -> return_term loc (Implicit)
      | m = META -> return_term loc (Meta (int_of_string m, []))
      | m = META; s = meta_subst -> return_term loc (Meta (int_of_string m, s))
      | s = sort -> return_term loc (Sort s)
      | s = SYMBOL -> return_term loc (Symbol (s, 0))
      | outtyp = OPT [ SYMBOL "["; ty = l2_pattern; SYMBOL "]" -> ty ];
        IDENT "match"; t = l2_pattern;
        indty_ident = OPT [ SYMBOL ":"; id = IDENT -> id ];
        IDENT "with"; SYMBOL "[";
        patterns = LIST0 [
          lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
          rhs = l2_pattern ->
            lhs, rhs
        ] SEP SYMBOL "|";
        SYMBOL "]" ->
          return_term loc (Case (t, indty_ident, outtyp, patterns))
      | SYMBOL "("; p1 = l2_pattern; SYMBOL ":"; p2 = l2_pattern; SYMBOL ")" ->
          return_term loc (Appl [ Symbol ("cast", 0); p1; p2 ])
      | SYMBOL "("; p = l2_pattern; SYMBOL ")" -> p
      | v = l2_pattern_variable -> return_term loc (Variable v)
      | m = l2_magic_pattern -> return_term loc (Magic m)
      ]
    | "100" [ ]
    ];
(* }}} *)
(* {{{ Grammar for interpretation, notation level 3 *)
  argument: [
    [ id = IDENT -> IdentArg id
    | SYMBOL <:unicode<eta>> (* η *); SYMBOL "."; a = SELF -> EtaArg (None, a)
    | SYMBOL <:unicode<eta>> (* η *); id = IDENT; SYMBOL "."; a = SELF ->
        EtaArg (Some id, a)
    ]
  ];
  level3_term: [
    [ u = URI -> UriPattern u
    | a = argument -> ArgPattern a
    | SYMBOL "("; terms = LIST1 SELF; SYMBOL ")" ->
        (match terms with
        | [] -> assert false
        | [term] -> term
        | terms -> ApplPattern terms)
    ]
  ];
(* }}} *)
(* {{{ Notation glues *)
  associativity: [
    [ IDENT "left";  IDENT "associative" -> `Left
    | IDENT "right"; IDENT "associative" -> `Right
    ]
  ];
  precedence: [ [ IDENT "at"; IDENT "precedence"; n = NUMBER -> n ] ];
  notation: [
    [ IDENT "notation"; p1 = level1_pattern; IDENT "for"; p2 = level2_pattern;
      assoc = OPT associativity; prec = OPT precedence ->
        ()
    ]
  ];
  interpretation: [
    [ IDENT "interpretation"; s = SYMBOL; args = LIST1 argument; IDENT "as";
      t = level3_term ->
        ()
    ]
  ];
(* }}} *)
END

let exc_located_wrapper f =
  try
    f ()
  with
  | Stdpp.Exc_located (floc, Stream.Error msg) ->
      raise (Parse_error (floc, msg))
  | Stdpp.Exc_located (floc, exn) ->
      raise (Parse_error (floc, (Printexc.to_string exn)))

let parse_syntax_pattern stream =
  exc_located_wrapper (fun () -> Grammar.Entry.parse level1_pattern stream)

let parse_ast_pattern stream =
  exc_located_wrapper (fun () -> Grammar.Entry.parse level2_pattern stream)

let parse_interpretation stream =
  exc_located_wrapper (fun () -> Grammar.Entry.parse level3_term stream)

(** {2 Grammar extension} *)

type associativity_kind = [ `Left | `Right | `None ]

let symbol s = Gramext.Stoken ("SYMBOL", s)
let ident s = Gramext.Stoken ("IDENT", s)
let number s = Gramext.Stoken ("NUMBER", s)
let term = Gramext.Sself

type env_type = (string * (value_type * value)) list

let make_action action =
  let rec aux (vl : env_type) =
    function
      [] -> Gramext.action (fun (loc: location) -> action vl loc)
    | None :: tl -> Gramext.action (fun _ -> aux vl tl)
    | Some (name, typ) :: tl ->
        (* i tipi servono? Magari servono solo quando si verifica la
         * correttezza della notazione?
         *)
        Gramext.action (fun (v: value) -> aux ((name, (typ, v))::vl) tl)
  in
    aux []

let flatten_opt =
  let rec aux acc =
    function
      [] -> List.rev acc
    | None::tl -> aux acc tl
    | Some hd::tl -> aux (hd::acc) tl
  in
  aux []

  (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
let extract_term_production pattern =
  let rec aux = function
    | Literal l -> aux_literal l
    | Layout l -> aux_layout l
    | Magic m -> aux_magic m
    | Variable v -> aux_variable v
    | _ -> assert false
  and aux_literal = function
    | `Symbol s -> [None, symbol s]
    | `Keyword s -> [None, ident s]
    | `Number s -> [None, number s]
  and aux_layout = function
    | Sub (p1, p2) -> aux p1 @ [None, symbol "\\SUB"] @ aux p2
    | Sup (p1, p2) -> aux p1 @ [None, symbol "\\SUP"] @ aux p2
    | Below (p1, p2) -> aux p1 @ [None, symbol "\\BELOW"] @ aux p2
    | Above (p1, p2) -> aux p1 @ [None, symbol "\\ABOVE"] @ aux p2
    | Frac (p1, p2) -> aux p1 @ [None, symbol "\\FRAC"] @ aux p2
    | Atop (p1, p2) -> aux p1 @ [None, symbol "\\ATOP"] @ aux p2
    | Over (p1, p2) -> aux p1 @ [None, symbol "\\OVER"] @ aux p2
    | Root (p1, p2) ->
        [None, symbol "\\ROOT"] @ aux p2 @ [None, symbol "\\OF"] @ aux p1
    | Sqrt p -> [None, symbol "\\SQRT"] @ aux p
    | Break -> []
    | Box (_, pl) -> List.flatten (List.map aux pl)
  and aux_magic = function
    | Opt p ->
        let p_bindings, p_atoms = List.split (aux p) in
        let p_names = flatten_opt p_bindings in
        [ None,
          Gramext.srules
            [ [ Gramext.Sopt
                  (Gramext.srules
                    [ p_atoms,
                      (make_action
                        (fun (env : env_type) (loc : location) -> env)
                        p_bindings)])],
              Gramext.action
                (fun (env_opt : env_type option) (loc : location) ->
                  match env_opt with
                    Some env ->
                      List.map
                        (fun (name, (typ, v)) ->
                          (name, (OptType typ, OptValue (Some v))))
                        env
                  | None -> 
                      List.map
                        (fun (name, typ) ->
                          (name, (OptType typ, OptValue None)))
                        p_names) ]]
    | _ -> assert false
  and aux_variable = function
    | NumVar s -> [Some (s, NumType), number ""]
    | TermVar s -> [Some (s, TermType), term]
    | IdentVar s -> [Some (s, StringType), ident ""]
    | Ascription (p, s) -> assert false (* TODO *)
    | FreshVar _ -> assert false
  in
  aux pattern

let level_of_int precedence =
  (* TODO "mod" test to be removed as soon as we add all 100 levels *)
  if precedence mod 10 <> 0 || precedence < 0 || precedence > 100 then
    raise (Level_not_found precedence);
  string_of_int precedence

type rule_id = term Grammar.Entry.e * Token.t Gramext.g_symbol list

let extend level1_pattern ?(precedence = 0) ?associativity action =
  let p_bindings, p_atoms =
    List.split (extract_term_production level1_pattern)
  in
  let level = level_of_int precedence in
  let p_names = flatten_opt p_bindings in
  let entry = Grammar.Entry.obj (level2_pattern: 'a Grammar.Entry.e) in
  let _ =
    Grammar.extend
      [ entry, Some (Gramext.Level level),
        [ Some level,  (* TODO should we put None here? *)
          associativity,
          [ p_atoms, 
            (make_action
              (fun (env: env_type)(loc: location) -> TermValue (action env loc))
              p_bindings) ]]]
  in
  (level2_pattern, p_atoms)

let delete (entry, atoms) = Grammar.delete_rule entry atoms

let print_level2_pattern () =
  Grammar.print_entry Format.std_formatter (Grammar.Entry.obj level2_pattern);
  Format.pp_print_flush Format.std_formatter ()

(* vim:set encoding=utf8 foldmethod=marker: *)