(* Copyright (C) 2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

(** CIC Notation Parse Tree *)

type binder_kind = [ `Lambda | `Pi | `Exists | `Forall ]
type induction_kind = [ `Inductive | `CoInductive ]
type sort_kind = [ `Prop | `Set | `Type | `CProp ]
type fold_kind = [ `Left | `Right ]

type location = Lexing.position * Lexing.position
(* cut and past from CicAst.loc_of_floc *)
let loc_of_floc = function
  | { Lexing.pos_cnum = loc_begin }, { Lexing.pos_cnum = loc_end } ->
      (loc_begin, loc_end)

type term_attribute =
  [ `Loc of location                  (* source file location *)
  | `IdRef of string                  (* ACic pointer *)
  | `Href of UriManager.uri list      (* hyperlinks for literals *)
  | `Level of int * Gramext.g_assoc   (* precedence, associativity *)
  ]

type literal =
  [ `Symbol of string
  | `Keyword of string
  | `Number of string
  ]

type term =
  (* CIC AST *)

  | AttributedTerm of term_attribute * term

  | Appl of term list
  | Binder of binder_kind * capture_variable * term (* kind, name, body *)
  | Case of term * string option * term option * (case_pattern * term) list
      (* what to match, inductive type, out type, <pattern,action> list *)
  | LetIn of capture_variable * term * term  (* name, body, where *)
  | LetRec of induction_kind * (capture_variable * term * int) list * term
      (* (name, body, decreasing argument) list, where *)
  | Ident of string * subst list option
      (* literal, substitutions.
      * Some [] -> user has given an empty explicit substitution list 
      * None -> user has given no explicit substitution list *)
  | Implicit
  | Meta of int * meta_subst list
  | Num of string * int (* literal, instance *)
  | Sort of sort_kind
  | Symbol of string * int  (* canonical name, instance *)

  | UserInput (* place holder for user input, used by MatitaConsole, not to be
              used elsewhere *)
  | Uri of string * subst list option (* as Ident, for long names *)

  (* Syntax pattern extensions *)

  | Literal of literal
  | Layout of layout_pattern

  | Magic of magic_term
  | Variable of pattern_variable

  (* name, type. First component must be Ident or Variable (FreshVar _) *)
and capture_variable = term * term option

and meta_subst = term option
and subst = string * term
and case_pattern = string * capture_variable list

and box_kind = H | V | HV | HOV
and box_spec = box_kind * bool * bool (* kind, spacing, indent *)

and layout_pattern =
  | Sub of term * term
  | Sup of term * term
  | Below of term * term
  | Above of term * term
  | Frac of term * term
  | Over of term * term
  | Atop of term * term
(*   | array of term * literal option * literal option
      |+ column separator, row separator +| *)
  | Sqrt of term
  | Root of term * term (* argument, index *)
  | Break
  | Box of box_spec * term list

and magic_term =
  (* level 1 magics *)
  | List0 of term * literal option (* pattern, separator *)
  | List1 of term * literal option (* pattern, separator *)
  | Opt of term

  (* level 2 magics *)
  | Fold of fold_kind * term * string list * term
    (* base case pattern, recursive case bound names, recursive case pattern *)
  | Default of term * term  (* "some" case pattern, "none" case pattern *)
  | Fail
  | If of term * term * term (* test, pattern if true, pattern if false *)

and pattern_variable =
  (* level 1 and 2 variables *)
  | NumVar of string
  | IdentVar of string
  | TermVar of string

  (* level 1 variables *)
  | Ascription of term * string

  (* level 2 variables *)
  | FreshVar of string

type argument_pattern =
  | IdentArg of int * string (* eta-depth, name *)

type cic_appl_pattern =
  | UriPattern of UriManager.uri
  | VarPattern of string
  | ApplPattern of cic_appl_pattern list

type phrase = (* TODO hackish: replace with TacticAst.statement or similar *)
  | Print of term
  | Notation of term * Gramext.g_assoc option * int option * term
      (* level 1 pattern, associativity, precedence, level 2 pattern *)
  | Interpretation of (string * argument_pattern list) * cic_appl_pattern
  | Render of UriManager.uri
  | Dump  (* dump grammar *)