(* Copyright (C) 2004-2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

open Printf

module Ast = CicNotationPt

let debug = false
let debug_print s = if debug then prerr_endline (Lazy.force s) else ()

type pattern_id = int
type interpretation_id = pattern_id
type pretty_printer_id = pattern_id

type term_info =
  { sort: (Cic.id, Ast.sort_kind) Hashtbl.t;
    uri: (Cic.id, UriManager.uri) Hashtbl.t;
  }

let get_types uri =
  let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
    match o with
      | Cic.InductiveDefinition (l,_,_,_) -> l 
      | _ -> assert false

let name_of_inductive_type uri i = 
  let types = get_types uri in
  let (name, _, _, _) = try List.nth types i with Not_found -> assert false in
  name

  (* returns <name, type> pairs *)
let constructors_of_inductive_type uri i =
  let types = get_types uri in
  let (_, _, _, constructors) = 
    try List.nth types i with Not_found -> assert false
  in
  constructors

  (* returns name only *)
let constructor_of_inductive_type uri i j =
  (try
    fst (List.nth (constructors_of_inductive_type uri i) (j-1))
  with Not_found -> assert false)

let idref id t = Ast.AttributedTerm (`IdRef id, t)

let resolve_binder = function
  | `Lambda -> "\\lambda"
  | `Pi -> "\\Pi"
  | `Forall -> "\\forall"
  | `Exists -> "\\exists"

let add_level_info prec assoc t = Ast.AttributedTerm (`Level (prec, assoc), t)
let add_pos_info pos t = Ast.AttributedTerm (`ChildPos pos, t)
let left_pos = add_pos_info `Left
let right_pos = add_pos_info `Right
let inner_pos = add_pos_info `Inner

let rec top_pos t = add_level_info ~-1 Gramext.NonA (inner_pos t)
(*   function
  | Ast.AttributedTerm (`Level _, t) ->
      add_level_info ~-1 Gramext.NonA (inner_pos t)
  | Ast.AttributedTerm (attr, t) -> Ast.AttributedTerm (attr, top_pos t)
  | t -> add_level_info ~-1 Gramext.NonA (inner_pos t) *)

let rec remove_level_info =
  function
  | Ast.AttributedTerm (`Level _, t) -> remove_level_info t
  | Ast.AttributedTerm (a, t) -> Ast.AttributedTerm (a, remove_level_info t)
  | t -> t

let add_xml_attrs attrs t =
  if attrs = [] then t else Ast.AttributedTerm (`XmlAttrs attrs, t)

let add_keyword_attrs =
  add_xml_attrs (RenderingAttrs.keyword_attributes `MathML)

let box kind spacing indent content =
  Ast.Layout (Ast.Box ((kind, spacing, indent), content))

let hbox = box Ast.H
let vbox = box Ast.V
let hvbox = box Ast.HV
let hovbox = box Ast.HOV
let break = Ast.Layout Ast.Break
let builtin_symbol s = Ast.Literal (`Symbol s)
let keyword k = add_keyword_attrs (Ast.Literal (`Keyword k))

let number s =
  add_xml_attrs (RenderingAttrs.number_attributes `MathML)
    (Ast.Literal (`Number s))

let ident i =
  add_xml_attrs (RenderingAttrs.ident_attributes `MathML) (Ast.Ident (i, None))

let ident_w_href href i =
  match href with
  | None -> ident i
  | Some href ->
      let href = UriManager.string_of_uri href in
      add_xml_attrs [Some "xlink", "href", href] (ident i)

let binder_symbol s =
  add_xml_attrs (RenderingAttrs.builtin_symbol_attributes `MathML)
    (builtin_symbol s)

let string_of_sort_kind = function
  | `Prop -> "Prop"
  | `Set -> "Set"
  | `CProp -> "CProp"
  | `Type _ -> "Type"

let pp_ast0 t k =
  let rec aux =
    function
    | Ast.Appl ts ->
        let rec aux_args pos =
          function
          | [] -> []
          | [ last ] ->
              let last = k last in
              if pos = `Left then [ left_pos last ] else [ right_pos last ]
          | hd :: tl ->
              (add_pos_info pos (k hd)) :: aux_args `Inner tl
        in
        add_level_info Ast.apply_prec Ast.apply_assoc
          (hovbox true true (CicNotationUtil.dress break (aux_args `Left ts)))
    | Ast.Binder (binder_kind, (id, ty), body) ->
        add_level_info Ast.binder_prec Ast.binder_assoc
          (hvbox false true
            [ binder_symbol (resolve_binder binder_kind);
              k id; builtin_symbol ":"; aux_ty ty; break;
              builtin_symbol "."; right_pos (k body) ])
    | Ast.Case (what, indty_opt, outty_opt, patterns) ->
        let outty_box =
          match outty_opt with
          | None -> []
          | Some outty ->
              [ builtin_symbol "["; remove_level_info (k outty);
                builtin_symbol "]"; break ]
        in
        let indty_box =
          match indty_opt with
          | None -> []
          | Some (indty, href) -> [ keyword "in"; ident_w_href href indty ]
        in
        let match_box =
          hvbox false true [
            keyword "match"; break;
            hvbox false false ([ top_pos (k what) ] @ indty_box); break;
            keyword "with" ]
        in
        let mk_case_pattern (head, href, vars) =
          hbox true false (ident_w_href href head :: List.map aux_var vars)
        in
        let patterns' =
          List.map
            (fun (lhs, rhs) ->
              remove_level_info
                (hvbox false true [
                  hbox false true [
                    mk_case_pattern lhs; builtin_symbol "\\Rightarrow" ];
                  break; top_pos (k rhs) ]))
            patterns
        in
        let patterns'' =
          let rec aux_patterns = function
            | [] -> assert false
            | [ last ] ->
                [ break; 
                  hbox false false [
                    builtin_symbol "|";
                    last; builtin_symbol "]" ] ]
            | hd :: tl ->
                [ break; hbox false false [ builtin_symbol "|"; hd ] ]
                @ aux_patterns tl
          in
          match patterns' with
          | [] ->
              [ hbox false false [ builtin_symbol "["; builtin_symbol "]" ] ]
          | [ one ] ->
              [ hbox false false [
                builtin_symbol "["; one; builtin_symbol "]" ] ]
          | hd :: tl ->
              hbox false false [ builtin_symbol "["; hd ]
              :: aux_patterns tl
        in
        add_level_info Ast.simple_prec Ast.simple_assoc
          (hvbox false false [
            hvbox false false (outty_box @ [ match_box ]); break;
            hbox false false [ hvbox false false patterns'' ] ])
    | Ast.Cast (bo, ty) ->
        add_level_info Ast.simple_prec Ast.simple_assoc
          (hvbox false true [
            builtin_symbol "("; top_pos (k bo); break; builtin_symbol ":";
            top_pos (k ty); builtin_symbol ")"])
    | Ast.LetIn (var, s, t) ->
        add_level_info Ast.let_in_prec Ast.let_in_assoc
          (hvbox false true [
            hvbox false true [
              keyword "let";
              hvbox false true [
                aux_var var; builtin_symbol "\\def"; break; top_pos (k s) ];
              break; keyword "in" ];
            break;
            k t ])
    | Ast.LetRec (rec_kind, funs, where) ->
        let rec_op =
          match rec_kind with `Inductive -> "rec" | `CoInductive -> "corec"
        in
        let mk_fun (var, body, _) = aux_var var, k body in
        let mk_funs = List.map mk_fun in
        let fst_fun, tl_funs =
          match mk_funs funs with hd :: tl -> hd, tl | [] -> assert false
        in
        let fst_row =
          let (name, body) = fst_fun in
          hvbox false true [
            keyword "let"; keyword rec_op; name; builtin_symbol "\\def"; break;
            top_pos body ]
        in
        let tl_rows =
          List.map
            (fun (name, body) ->
              [ break;
                hvbox false true [
                  keyword "and"; name; builtin_symbol "\\def"; break; body ] ])
            tl_funs
        in
        add_level_info Ast.let_in_prec Ast.let_in_assoc
          ((hvbox false false
            (fst_row :: List.flatten tl_rows
             @ [ break; keyword "in"; break; k where ])))
    | Ast.Implicit -> builtin_symbol "?"
    | Ast.Meta (n, l) ->
        let local_context l =
          CicNotationUtil.dress (builtin_symbol ";")
            (List.map (function None -> builtin_symbol "_" | Some t -> k t) l)
        in
        hbox false false
          ([ builtin_symbol "?"; number (string_of_int n) ]
            @ (if l <> [] then local_context l else []))
    | Ast.Sort sort -> aux_sort sort
    | Ast.Num _
    | Ast.Symbol _
    | Ast.Ident (_, None) | Ast.Ident (_, Some [])
    | Ast.Uri (_, None) | Ast.Uri (_, Some [])
    | Ast.Literal _
    | Ast.UserInput as leaf -> leaf
    | t -> CicNotationUtil.visit_ast ~special_k k t
  and aux_sort sort_kind =
    add_xml_attrs (RenderingAttrs.keyword_attributes `MathML)
      (Ast.Ident (string_of_sort_kind sort_kind, None))
  and aux_ty = function
    | None -> builtin_symbol "?"
    | Some ty -> k ty
  and aux_var = function
    | name, Some ty ->
        hvbox false true [
          builtin_symbol "("; name; builtin_symbol ":"; break; k ty;
          builtin_symbol ")" ]
    | name, None -> name
  and special_k = function
    | Ast.AttributedTerm (attrs, t) -> Ast.AttributedTerm (attrs, k t)
    | t ->
        prerr_endline ("unexpected special: " ^ CicNotationPp.pp_term t);
        assert false
  in
  aux t

let ast_of_acic0 term_info acic k =
  let k = k term_info in
  let id_to_uris = term_info.uri in
  let register_uri id uri = Hashtbl.add id_to_uris id uri in
  let sort_of_id id =
    try
      Hashtbl.find term_info.sort id
    with Not_found ->
      prerr_endline (sprintf "warning: sort of id %s not found, using Type" id);
      `Type (CicUniv.fresh ())
  in
  let aux_substs substs =
    Some
      (List.map
        (fun (uri, annterm) -> (UriManager.name_of_uri uri, k annterm))
        substs)
  in
  let aux_context context =
    List.map
      (function
        | None -> None
        | Some annterm -> Some (k annterm))
      context
  in
  let aux = function
    | Cic.ARel (id,_,_,b) -> idref id (Ast.Ident (b, None))
    | Cic.AVar (id,uri,substs) ->
        register_uri id uri;
        idref id (Ast.Ident (UriManager.name_of_uri uri, aux_substs substs))
    | Cic.AMeta (id,n,l) -> idref id (Ast.Meta (n, aux_context l))
    | Cic.ASort (id,Cic.Prop) -> idref id (Ast.Sort `Prop)
    | Cic.ASort (id,Cic.Set) -> idref id (Ast.Sort `Set)
    | Cic.ASort (id,Cic.Type u) -> idref id (Ast.Sort (`Type u))
    | Cic.ASort (id,Cic.CProp) -> idref id (Ast.Sort `CProp)
    | Cic.AImplicit _ -> assert false
    | Cic.AProd (id,n,s,t) ->
        let binder_kind =
          match sort_of_id id with
          | `Set | `Type _ -> `Pi
          | `Prop | `CProp -> `Forall
        in
        idref id (Ast.Binder (binder_kind,
          (CicNotationUtil.name_of_cic_name n, Some (k s)), k t))
    | Cic.ACast (id,v,t) -> idref id (Ast.Cast (k v, k t))
    | Cic.ALambda (id,n,s,t) ->
        idref id (Ast.Binder (`Lambda,
          (CicNotationUtil.name_of_cic_name n, Some (k s)), k t))
    | Cic.ALetIn (id,n,s,t) ->
        idref id (Ast.LetIn ((CicNotationUtil.name_of_cic_name n, None),
          k s, k t))
    | Cic.AAppl (aid,args) -> idref aid (Ast.Appl (List.map k args))
    | Cic.AConst (id,uri,substs) ->
        register_uri id uri;
        idref id (Ast.Ident (UriManager.name_of_uri uri, aux_substs substs))
    | Cic.AMutInd (id,uri,i,substs) as t ->
        let name = name_of_inductive_type uri i in
        let uri_str = UriManager.string_of_uri uri in
        let puri_str = sprintf "%s#xpointer(1/%d)" uri_str (i+1) in
        register_uri id (UriManager.uri_of_string puri_str);
        idref id (Ast.Ident (name, aux_substs substs))
    | Cic.AMutConstruct (id,uri,i,j,substs) ->
        let name = constructor_of_inductive_type uri i j in
        let uri_str = UriManager.string_of_uri uri in
        let puri_str = sprintf "%s#xpointer(1/%d/%d)" uri_str (i + 1) j in
        register_uri id (UriManager.uri_of_string puri_str);
        idref id (Ast.Ident (name, aux_substs substs))
    | Cic.AMutCase (id,uri,typeno,ty,te,patterns) ->
        let name = name_of_inductive_type uri typeno in
        let uri_str = UriManager.string_of_uri uri in
        let puri_str = sprintf "%s#xpointer(1/%d)" uri_str (typeno+1) in
        let ctor_puri j =
          UriManager.uri_of_string
            (sprintf "%s#xpointer(1/%d/%d)" uri_str (typeno+1) j)
        in
        let case_indty = name, Some (UriManager.uri_of_string puri_str) in
        let constructors = constructors_of_inductive_type uri typeno in
        let rec eat_branch ty pat =
          match (ty, pat) with
          | Cic.Prod (_, _, t), Cic.ALambda (_, name, s, t') ->
              let (cv, rhs) = eat_branch t t' in
              (CicNotationUtil.name_of_cic_name name, Some (k s)) :: cv, rhs
          | _, _ -> [], k pat
        in
        let j = ref 0 in
        let patterns =
          try
            List.map2
              (fun (name, ty) pat ->
                incr j;
                let (capture_variables, rhs) = eat_branch ty pat in
                ((name, Some (ctor_puri !j), capture_variables), rhs))
              constructors patterns
          with Invalid_argument _ -> assert false
        in
        idref id (Ast.Case (k te, Some case_indty, Some (k ty), patterns))
    | Cic.AFix (id, no, funs) -> 
        let defs = 
          List.map
            (fun (_, n, decr_idx, ty, bo) ->
              ((Ast.Ident (n, None), Some (k ty)), k bo, decr_idx))
            funs
        in
        let name =
          try
            (match List.nth defs no with
            | (Ast.Ident (n, _), _), _, _ when n <> "_" -> n
            | _ -> assert false)
          with Not_found -> assert false
        in
        idref id (Ast.LetRec (`Inductive, defs, Ast.Ident (name, None)))
    | Cic.ACoFix (id, no, funs) -> 
        let defs = 
          List.map
            (fun (_, n, ty, bo) ->
              ((Ast.Ident (n, None), Some (k ty)), k bo, 0))
            funs
        in
        let name =
          try
            (match List.nth defs no with
            | (Ast.Ident (n, _), _), _, _ when n <> "_" -> n
            | _ -> assert false)
          with Not_found -> assert false
        in
        idref id (Ast.LetRec (`CoInductive, defs, Ast.Ident (name, None)))
  in
  aux acic

  (* persistent state *)

let level1_patterns21 = Hashtbl.create 211
let level2_patterns32 = Hashtbl.create 211
let interpretations = Hashtbl.create 211  (* symb -> id list ref *)

let compiled21 = ref None
let compiled32 = ref None

let pattern21_matrix = ref []
let pattern32_matrix = ref []

let get_compiled21 () =
  match !compiled21 with
  | None -> assert false
  | Some f -> Lazy.force f
let get_compiled32 () =
  match !compiled32 with
  | None -> assert false
  | Some f -> Lazy.force f

let set_compiled21 f = compiled21 := Some f
let set_compiled32 f = compiled32 := Some f

let add_idrefs =
  List.fold_right (fun idref t -> Ast.AttributedTerm (`IdRef idref, t))

let instantiate21 idrefs env l1 =
  let rec subst_singleton pos env =
    function
      Ast.AttributedTerm (attr, t) ->
        Ast.AttributedTerm (attr, subst_singleton pos env t)
    | t -> CicNotationUtil.group (subst pos env t)
  and subst pos env = function
    | Ast.AttributedTerm (attr, t) as term ->
(*         prerr_endline ("loosing attribute " ^ CicNotationPp.pp_attribute attr); *)
        subst pos env t
    | Ast.Variable var ->
        let name, expected_ty = CicNotationEnv.declaration_of_var var in
        let ty, value =
          try
            List.assoc name env
          with Not_found ->
            prerr_endline ("name " ^ name ^ " not found in environment");
            assert false
        in
        assert (CicNotationEnv.well_typed ty value); (* INVARIANT *)
        (* following assertion should be a conditional that makes this
         * instantiation fail *)
        assert (CicNotationEnv.well_typed expected_ty value);
        [ add_pos_info pos (CicNotationEnv.term_of_value value) ]
    | Ast.Magic m -> subst_magic pos env m
    | Ast.Literal l as t ->
        let t = add_idrefs idrefs t in
        (match l with
        | `Keyword k -> [ add_keyword_attrs t ]
        | _ -> [ t ])
    | Ast.Layout l -> [ Ast.Layout (subst_layout pos env l) ]
    | t -> [ CicNotationUtil.visit_ast (subst_singleton pos env) t ]
  and subst_magic pos env = function
    | Ast.List0 (p, sep_opt)
    | Ast.List1 (p, sep_opt) ->
        let rec_decls = CicNotationEnv.declarations_of_term p in
        let rec_values =
          List.map (fun (n, _) -> CicNotationEnv.lookup_list env n) rec_decls
        in
        let values = CicNotationUtil.ncombine rec_values in
        let sep =
          match sep_opt with
            | None -> []
            | Some l -> [ Ast.Literal l ]
	in
        let rec instantiate_list acc = function
          | [] -> List.rev acc
	  | value_set :: [] ->
	      let env = CicNotationEnv.combine rec_decls value_set in
              instantiate_list (CicNotationUtil.group (subst pos env p) :: acc)
                []
          | value_set :: tl ->
              let env = CicNotationEnv.combine rec_decls value_set in
              let terms = subst pos env p in
              instantiate_list (CicNotationUtil.group (terms @ sep) :: acc) tl
        in
        instantiate_list [] values
    | Ast.Opt p ->
        let opt_decls = CicNotationEnv.declarations_of_term p in
        let env =
          let rec build_env = function
            | [] -> []
            | (name, ty) :: tl ->
                  (* assumption: if one of the value is None then all are *)
                (match CicNotationEnv.lookup_opt env name with
                | None -> raise Exit
                | Some v -> (name, (ty, v)) :: build_env tl)
          in
          try build_env opt_decls with Exit -> []
        in
	  begin
	    match env with
	      | [] -> []
	      | _ -> subst pos env p
	  end
    | _ -> assert false (* impossible *)
  and subst_layout pos env = function
    | Ast.Box (kind, tl) ->
        let tl' = subst_children pos env tl in
        Ast.Box (kind, List.concat tl')
    | l -> CicNotationUtil.visit_layout (subst_singleton pos env) l
  and subst_children pos env =
    function
    | [] -> []
    | [ child ] ->
        let pos' =
          match pos with
          | `Inner -> `Right
          | `Left -> `Left
(*           | `None -> assert false *)
          | `Right -> `Right
        in
        [ subst pos' env child ]
    | hd :: tl ->
        let pos' =
          match pos with
          | `Inner -> `Inner
          | `Left -> `Inner
(*           | `None -> assert false *)
          | `Right -> `Right
        in
        (subst pos env hd) :: subst_children pos' env tl
  in
    subst_singleton `Left env l1

let rec pp_ast1 term = 
  let rec pp_value = function
    | CicNotationEnv.NumValue _ as v -> v
    | CicNotationEnv.StringValue _ as v -> v
(*     | CicNotationEnv.TermValue t when t == term -> CicNotationEnv.TermValue (pp_ast0 t pp_ast1) *)
    | CicNotationEnv.TermValue t -> CicNotationEnv.TermValue (pp_ast1 t)
    | CicNotationEnv.OptValue None as v -> v
    | CicNotationEnv.OptValue (Some v) -> 
        CicNotationEnv.OptValue (Some (pp_value v))
    | CicNotationEnv.ListValue vl ->
        CicNotationEnv.ListValue (List.map pp_value vl)
  in
  let ast_env_of_env env =
    List.map (fun (var, (ty, value)) -> (var, (ty, pp_value value))) env
  in
(* prerr_endline ("pattern matching from 2 to 1 on term " ^ CicNotationPp.pp_term term); *)
  match term with
  | Ast.AttributedTerm (attrs, term') ->
      Ast.AttributedTerm (attrs, pp_ast1 term')
  | _ ->
      (match (get_compiled21 ()) term with
      | None -> pp_ast0 term pp_ast1
      | Some (env, ctors, pid) ->
          let idrefs =
            List.flatten (List.map CicNotationUtil.get_idrefs ctors)
          in
          let l1 =
            try
              Hashtbl.find level1_patterns21 pid
            with Not_found -> assert false
          in
          instantiate21 idrefs (ast_env_of_env env) l1)

let instantiate32 term_info idrefs env symbol args =
  let rec instantiate_arg = function
    | Ast.IdentArg (n, name) ->
        let t = (try List.assoc name env with Not_found -> assert false) in
        let rec count_lambda = function
          | Ast.AttributedTerm (_, t) -> count_lambda t
          | Ast.Binder (`Lambda, _, body) -> 1 + count_lambda body
          | _ -> 0
        in
        let rec add_lambda t n =
          if n > 0 then
            let name = CicNotationUtil.fresh_name () in
            Ast.Binder (`Lambda, (Ast.Ident (name, None), None),
              Ast.Appl [add_lambda t (n - 1); Ast.Ident (name, None)])
          else
            t
        in
        add_lambda t (n - count_lambda t)
  in
  let head =
    let symbol = Ast.Symbol (symbol, 0) in
    add_idrefs idrefs symbol
  in
  if args = [] then head
  else Ast.Appl (head :: List.map instantiate_arg args)

let rec ast_of_acic1 term_info annterm = 
  let id_to_uris = term_info.uri in
  let register_uri id uri = Hashtbl.add id_to_uris id uri in
  match (get_compiled32 ()) annterm with
  | None -> ast_of_acic0 term_info annterm ast_of_acic1
  | Some (env, ctors, pid) -> 
      let idrefs =
        List.map
          (fun annterm ->
            let idref = CicUtil.id_of_annterm annterm in
            (try
              register_uri idref
                (CicUtil.uri_of_term (Deannotate.deannotate_term annterm))
            with Invalid_argument _ -> ());
            idref)
          ctors
      in
      let env' =
        List.map (fun (name, term) -> (name, ast_of_acic1 term_info term)) env
      in
      let _, symbol, args, _ =
        try
          Hashtbl.find level2_patterns32 pid
        with Not_found -> assert false
      in
      let ast = instantiate32 term_info idrefs env' symbol args in
      Ast.AttributedTerm (`IdRef (CicUtil.id_of_annterm annterm), ast)

let load_patterns32 t =
  set_compiled32 (lazy (CicNotationMatcher.Matcher32.compiler t))

let load_patterns21 t =
  set_compiled21 (lazy (CicNotationMatcher.Matcher21.compiler t))

let ast_of_acic id_to_sort annterm =
  debug_print (lazy ("ast_of_acic <- "
    ^ CicPp.ppterm (Deannotate.deannotate_term annterm)));
  let term_info = { sort = id_to_sort; uri = Hashtbl.create 211 } in
  let ast = ast_of_acic1 term_info annterm in
  debug_print (lazy ("ast_of_acic -> " ^ CicNotationPp.pp_term ast));
  ast, term_info.uri

let pp_ast ast =
  debug_print (lazy "pp_ast <-");
  let ast' = pp_ast1 ast in
  debug_print (lazy ("pp_ast -> " ^ CicNotationPp.pp_term ast'));
  ast'

let fresh_id =
  let counter = ref ~-1 in
  fun () ->
    incr counter;
    !counter

let add_interpretation dsc (symbol, args) appl_pattern =
  let id = fresh_id () in
  Hashtbl.add level2_patterns32 id (dsc, symbol, args, appl_pattern);
  pattern32_matrix := (appl_pattern, id) :: !pattern32_matrix;
  load_patterns32 !pattern32_matrix;
  (try
    let ids = Hashtbl.find interpretations symbol in
    ids := id :: !ids
  with Not_found -> Hashtbl.add interpretations symbol (ref [id]));
  id

exception Interpretation_not_found
exception Pretty_printer_not_found

let rec list_uniq = function 
  | [] -> []
  | h::[] -> [h]
  | h1::h2::tl when h1 = h2 -> list_uniq (h2 :: tl) 
  | h1::tl (* when h1 <> h2 *) -> h1 :: list_uniq tl

let lookup_interpretations symbol =
  try
   list_uniq
    (List.sort Pervasives.compare
     (List.map
      (fun id ->
        let (dsc, _, args, appl_pattern) =
          try
            Hashtbl.find level2_patterns32 id
          with Not_found -> assert false 
        in
        dsc, args, appl_pattern)
      !(Hashtbl.find interpretations symbol)))
  with Not_found -> raise Interpretation_not_found

let fill_pos_info l1_pattern = l1_pattern
(*   let rec aux toplevel pos =
    function
    | Ast.Layout l ->
        (match l 

    | Ast.Magic m ->
        Ast.Box (
    | Ast.Variable _ as t -> add_pos_info pos t
    | t -> t
  in
  aux true l1_pattern *)

let add_pretty_printer ~precedence ~associativity l2 l1 =
  let id = fresh_id () in
  let l1' = add_level_info precedence associativity (fill_pos_info l1) in
  let l2' = CicNotationUtil.strip_attributes l2 in
  Hashtbl.add level1_patterns21 id l1';
  pattern21_matrix := (l2', id) :: !pattern21_matrix;
  load_patterns21 !pattern21_matrix;
  id

let remove_interpretation id =
  (try
    let _, symbol, _, _ = Hashtbl.find level2_patterns32 id in
    let ids = Hashtbl.find interpretations symbol in
    ids := List.filter ((<>) id) !ids;
    Hashtbl.remove level2_patterns32 id;
  with Not_found -> raise Interpretation_not_found);
  pattern32_matrix := List.filter (fun (_, id') -> id <> id') !pattern32_matrix;
  load_patterns32 !pattern32_matrix

let remove_pretty_printer id =
  (try
    Hashtbl.remove level1_patterns21 id;
  with Not_found -> raise Pretty_printer_not_found);
  pattern21_matrix := List.filter (fun (_, id') -> id <> id') !pattern21_matrix;
  load_patterns21 !pattern21_matrix

let _ =
  load_patterns21 [];
  load_patterns32 []