(* Copyright (C) 2004-2005, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://helm.cs.unibo.it/
 *)

open Printf

type pattern_id = int
type interpretation_id = pattern_id
type pretty_printer_id = pattern_id

let default_prec = 50
let default_assoc = Gramext.NonA

type term_info =
  { sort: (Cic.id, CicNotationPt.sort_kind) Hashtbl.t;
    uri: (Cic.id, string) Hashtbl.t;
  }

let warning s = prerr_endline ("CicNotation WARNING: " ^ s)

let get_types uri =
  let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
    match o with
      | Cic.InductiveDefinition (l,_,_,_) -> l 
      | _ -> assert false

let name_of_inductive_type uri i = 
  let types = get_types uri in
  let (name, _, _, _) = try List.nth types i with Not_found -> assert false in
  name

  (* returns <name, type> pairs *)
let constructors_of_inductive_type uri i =
  let types = get_types uri in
  let (_, _, _, constructors) = 
    try List.nth types i with Not_found -> assert false
  in
  constructors

  (* returns name only *)
let constructor_of_inductive_type uri i j =
  (try
    fst (List.nth (constructors_of_inductive_type uri i) (j-1))
  with Not_found -> assert false)

module Ast = CicNotationPt
module Parser = CicNotationParser

let string_of_name = function
  | Cic.Name s -> s
  | Cic.Anonymous -> "_"

let ident_of_name n = Ast.Ident (string_of_name n, None)

let idref id t = Ast.AttributedTerm (`IdRef id, t)

let resolve_binder = function
  | `Lambda -> "\\lambda"
  | `Pi -> "\\Pi"
  | `Forall -> "\\forall"
  | `Exists -> "\\exists"

let pp_ast0 t k =
  let rec aux = function
    | Ast.Appl ts ->
        Ast.AttributedTerm (`Level (Parser.apply_prec, Parser.apply_assoc),
          Ast.Layout (Ast.Box ((Ast.HOV, true, true), List.map k ts)))
    | Ast.Binder (`Forall, (Ast.Ident ("_", _), ty), body)
    | Ast.Binder (`Pi, (Ast.Ident ("_", _), ty), body) ->
        Ast.AttributedTerm (`Level (Parser.binder_prec, Parser.binder_assoc),
          Ast.Layout (Ast.Box ((Ast.HV, false, true), [
            aux_ty ty;
            Ast.Layout (Ast.Box ((Ast.H, false, false), [
              Ast.Literal (`Symbol "\\to"); k body]))])))
    | Ast.Binder (binder_kind, (id, ty), body) ->
        Ast.AttributedTerm (`Level (Parser.binder_prec, Parser.binder_assoc),
          Ast.Layout (Ast.Box ((Ast.HV, false, true), [
            Ast.Layout (Ast.Box ((Ast.H, false, false), [
              Ast.Literal (`Symbol (resolve_binder binder_kind));
              k id;
              Ast.Literal (`Symbol ":");
              aux_ty ty ]));
            Ast.Layout (Ast.Box ((Ast.H, false, false), [
              Ast.Literal (`Symbol ".");
              k body ]))])))
    | t -> CicNotationUtil.visit_ast ~special_k k t
  and aux_ty = function
    | None -> Ast.Literal (`Symbol "?")
    | Some ty -> k ty
  and special_k = function
    | Ast.AttributedTerm (attrs, t) -> Ast.AttributedTerm (attrs, k t)
    | _ -> assert false
  in
  aux t

let ast_of_acic0 term_info acic k =
(*   prerr_endline "ast_of_acic0"; *)
  let k = k term_info in
  let register_uri id uri = Hashtbl.add term_info.uri id uri in
  let sort_of_id id =
    try
      Hashtbl.find term_info.sort id
    with Not_found -> assert false
  in
  let aux_substs substs =
    Some
      (List.map
        (fun (uri, annterm) -> (UriManager.name_of_uri uri, k annterm))
        substs)
  in
  let aux_context context =
    List.map
      (function
        | None -> None
        | Some annterm -> Some (k annterm))
      context
  in
  let aux = function
    | Cic.ARel (id,_,_,b) -> idref id (Ast.Ident (b, None))
    | Cic.AVar (id,uri,substs) ->
        register_uri id (UriManager.string_of_uri uri);
        idref id (Ast.Ident (UriManager.name_of_uri uri, aux_substs substs))
    | Cic.AMeta (id,n,l) -> idref id (Ast.Meta (n, aux_context l))
    | Cic.ASort (id,Cic.Prop) -> idref id (Ast.Sort `Prop)
    | Cic.ASort (id,Cic.Set) -> idref id (Ast.Sort `Set)
    | Cic.ASort (id,Cic.Type _) -> idref id (Ast.Sort `Type)
    | Cic.ASort (id,Cic.CProp) -> idref id (Ast.Sort `CProp)
    | Cic.AImplicit _ -> assert false
    | Cic.AProd (id,n,s,t) ->
        let binder_kind =
          match sort_of_id id with
          | `Set | `Type -> `Pi
          | `Prop | `CProp -> `Forall
        in
        idref id (Ast.Binder (binder_kind, (ident_of_name n, Some (k s)), k t))
    | Cic.ACast (id,v,t) ->
        idref id (Ast.Appl [idref id (Ast.Symbol ("cast", 0)); k v; k t])
    | Cic.ALambda (id,n,s,t) ->
        idref id (Ast.Binder (`Lambda, (ident_of_name n, Some (k s)), k t))
    | Cic.ALetIn (id,n,s,t) ->
        idref id (Ast.LetIn ((ident_of_name n, None), k s, k t))
    | Cic.AAppl (aid,args) -> idref aid (Ast.Appl (List.map k args))
    | Cic.AConst (id,uri,substs) ->
        register_uri id (UriManager.string_of_uri uri);
        idref id (Ast.Ident (UriManager.name_of_uri uri, aux_substs substs))
    | Cic.AMutInd (id,uri,i,substs) as t ->
        let name = name_of_inductive_type uri i in
        let uri_str = UriManager.string_of_uri uri in
        let puri_str =
          uri_str ^ "#xpointer(1/" ^ (string_of_int (i + 1)) ^ ")"
        in
        register_uri id puri_str;
        idref id (Ast.Ident (name, aux_substs substs))
    | Cic.AMutConstruct (id,uri,i,j,substs) ->
        let name = constructor_of_inductive_type uri i j in
        let uri_str = UriManager.string_of_uri uri in
        let puri_str = sprintf "%s#xpointer(1/%d/%d)" uri_str (i + 1) j in
        register_uri id puri_str;
        idref id (Ast.Ident (name, aux_substs substs))
    | Cic.AMutCase (id,uri,typeno,ty,te,patterns) ->
        let name = name_of_inductive_type uri typeno in
        let constructors = constructors_of_inductive_type uri typeno in
        let rec eat_branch ty pat =
          match (ty, pat) with
          | Cic.Prod (_, _, t), Cic.ALambda (_, name, s, t') ->
              let (cv, rhs) = eat_branch t t' in
              (ident_of_name name, Some (k s)) :: cv, rhs
          | _, _ -> [], k pat
        in
        let patterns =
          List.map2
            (fun (name, ty) pat ->
              let (capture_variables, rhs) = eat_branch ty pat in
              ((name, capture_variables), rhs))
            constructors patterns
        in
        idref id (Ast.Case (k te, Some name, Some (k ty), patterns))
    | Cic.AFix (id, no, funs) -> 
        let defs = 
          List.map
            (fun (_, n, decr_idx, ty, bo) ->
              ((Ast.Ident (n, None), Some (k ty)), k bo, decr_idx))
            funs
        in
        let name =
          try
            (match List.nth defs no with
            | (Ast.Ident (n, _), _), _, _ when n <> "_" -> n
            | _ -> assert false)
          with Not_found -> assert false
        in
        idref id (Ast.LetRec (`Inductive, defs, Ast.Ident (name, None)))
    | Cic.ACoFix (id, no, funs) -> 
        let defs = 
          List.map
            (fun (_, n, ty, bo) -> ((Ast.Ident (n, None), Some (k ty)), k bo, 0))
            funs
        in
        let name =
          try
            (match List.nth defs no with
            | (Ast.Ident (n, _), _), _, _ when n <> "_" -> n
            | _ -> assert false)
          with Not_found -> assert false
        in
        idref id (Ast.LetRec (`CoInductive, defs, Ast.Ident (name, None)))
  in
  aux acic

  (* persistent state *)

let level1_patterns21 = Hashtbl.create 211
let level2_patterns32 = Hashtbl.create 211

let (compiled21: (CicNotationPt.term -> (CicNotationEnv.t * int) option)
option ref) =
  ref None
let (compiled32: (Cic.annterm -> ((string * Cic.annterm) list * int) option)
option ref) =
  ref None

let pattern21_matrix = ref []
let pattern32_matrix = ref []

let get_compiled21 () =
  match !compiled21 with
  | None -> assert false
  | Some f -> f
let get_compiled32 () =
  match !compiled32 with
  | None -> assert false
  | Some f -> f

let set_compiled21 f = compiled21 := Some f
let set_compiled32 f = compiled32 := Some f

let instantiate21 env (* precedence associativity *) l1 =
  let rec subst_singleton env t =
    CicNotationUtil.boxify (subst env t)
  and subst env = function
    | Ast.AttributedTerm (_, t) -> subst env t
    | Ast.Variable var ->
        let name, expected_ty = CicNotationEnv.declaration_of_var var in
        let ty, value =
          try
            List.assoc name env
          with Not_found -> assert false
        in
        assert (CicNotationEnv.well_typed ty value); (* INVARIANT *)
        (* following assertion should be a conditional that makes this
         * instantiation fail *)
        assert (CicNotationEnv.well_typed expected_ty value);
        [ CicNotationEnv.term_of_value value ]
    | Ast.Magic m -> subst_magic env m
    | Ast.Literal _ as t -> [ t ]
    | Ast.Layout l -> [ Ast.Layout (subst_layout env l) ]
    | t -> [ CicNotationUtil.visit_ast (subst_singleton env) t ]
  and subst_magic env = function
    | Ast.List0 (p, sep_opt)
    | Ast.List1 (p, sep_opt) ->
        let rec_decls = CicNotationEnv.declarations_of_term p in
        let rec_values =
          List.map (fun (n, _) -> CicNotationEnv.lookup_list env n) rec_decls
        in
        let values = CicNotationUtil.ncombine rec_values in
        let sep =
          match sep_opt with
          | None -> []
          | Some l -> [ CicNotationPt.Literal l ]
        in
        let rec instantiate_list acc = function
          | [] -> List.rev acc
	  | value_set :: [] ->
	      let env = CicNotationEnv.combine rec_decls value_set in
		instantiate_list
                  ((CicNotationUtil.boxify (subst env p)) :: acc) []
          | value_set :: tl ->
              let env = CicNotationEnv.combine rec_decls value_set in
              instantiate_list
                ((CicNotationUtil.boxify (subst env p @ sep)) :: acc) tl
        in
        instantiate_list [] values
    | Ast.Opt p ->
        let opt_decls = CicNotationEnv.declarations_of_term p in
        let env =
          let rec build_env = function
            | [] -> []
            | (name, ty) :: tl ->
                  (* assumption: if one of the value is None then all are *)
                (match CicNotationEnv.lookup_opt env name with
                | None -> raise Exit
                | Some v -> (name, (ty, v)) :: build_env tl)
          in
          try build_env opt_decls with Exit -> []
        in
	  begin
	    match env with
	      | [] -> []
	      | _ -> subst env p
	  end
    | _ -> assert false (* impossible *)
  and subst_layout env = function
    | Ast.Box (kind, tl) -> Ast.Box (kind, List.concat (List.map (subst env) tl))
    | l -> CicNotationUtil.visit_layout (subst_singleton env) l
  in
    subst_singleton env l1

let rec pp_ast1 term = 
  let rec pp_value = function
    | CicNotationEnv.NumValue _ as v -> v
    | CicNotationEnv.StringValue _ as v -> v
    | CicNotationEnv.TermValue t -> CicNotationEnv.TermValue (pp_ast1 t)
    | CicNotationEnv.OptValue None as v -> v
    | CicNotationEnv.OptValue (Some v) -> 
        CicNotationEnv.OptValue (Some (pp_value v))
    | CicNotationEnv.ListValue vl ->
        CicNotationEnv.ListValue (List.map pp_value vl)
  in
  let ast_env_of_env env =
    List.map (fun (var, (ty, value)) -> (var, (ty, pp_value value))) env
  in
  match (get_compiled21 ()) term with
  | None -> pp_ast0 term pp_ast1
  | Some (env, pid) ->
      let precedence, associativity, l1 =
        try
          Hashtbl.find level1_patterns21 pid
        with Not_found -> assert false
      in
      Ast.AttributedTerm (`Level (precedence, associativity),
        (instantiate21 (ast_env_of_env env) (* precedence associativity *) l1))

let instantiate32 term_info env symbol args =
  let rec instantiate_arg = function
    | Ast.IdentArg (n, name) ->
        let t = (try List.assoc name env with Not_found -> assert false) in
        let rec count_lambda = function
          | Ast.Binder (`Lambda, _, body) -> 1 + count_lambda body
          | _ -> 0
        in
        let rec add_lambda t n =
          if n > 0 then
            let name = CicNotationUtil.fresh_name () in
            Ast.Binder (`Lambda, (Ast.Ident (name, None), None),
              Ast.Appl [add_lambda t (n - 1); Ast.Ident (name, None)])
          else
            t
        in
        add_lambda t (n - count_lambda t)
  in
  let args' = List.map instantiate_arg args in
  Ast.Appl (Ast.Symbol (symbol, 0) :: args')

let rec ast_of_acic1 term_info annterm = 
  match (get_compiled32 ()) annterm with
  | None -> ast_of_acic0 term_info annterm ast_of_acic1
  | Some (env, pid) -> 
      let env' =
        List.map (fun (name, term) -> (name, ast_of_acic1 term_info term)) env
      in
      let symbol, args =
        try
          Hashtbl.find level2_patterns32 pid
        with Not_found -> assert false
      in
      instantiate32 term_info env' symbol args

let load_patterns32 t =
  set_compiled32 (CicNotationMatcher.Matcher32.compiler t)

let load_patterns21 t =
  set_compiled21 (CicNotationMatcher.Matcher21.compiler t)

let ast_of_acic id_to_sort annterm =
  let term_info = { sort = id_to_sort; uri = Hashtbl.create 211 } in
  let ast = ast_of_acic1 term_info annterm in
  ast, term_info.uri

let pp_ast term = pp_ast1 term

let fresh_id =
  let counter = ref ~-1 in
  fun () ->
    incr counter;
    !counter

let add_interpretation (symbol, args) appl_pattern =
  let id = fresh_id () in
  Hashtbl.add level2_patterns32 id (symbol, args);
  pattern32_matrix := (appl_pattern, id) :: !pattern32_matrix;
  load_patterns32 !pattern32_matrix;
  id

let add_pretty_printer
  ?(precedence = default_prec) ?(associativity = default_assoc) l2 l1
=
  let id = fresh_id () in
  let l2' = CicNotationUtil.strip_attributes l2 in
  Hashtbl.add level1_patterns21 id (precedence, associativity, l1);
  pattern21_matrix := (l2', id) :: !pattern21_matrix;
  load_patterns21 !pattern21_matrix;
  id

exception Interpretation_not_found
exception Pretty_printer_not_found

let remove_interpretation id =
  (try
    Hashtbl.remove level2_patterns32 id;
  with Not_found -> raise Interpretation_not_found);
  pattern32_matrix := List.filter (fun (_, id') -> id <> id') !pattern32_matrix;
  load_patterns32 !pattern32_matrix

let remove_pretty_printer id =
  (try
    Hashtbl.remove level1_patterns21 id;
  with Not_found -> raise Pretty_printer_not_found);
  pattern21_matrix := List.filter (fun (_, id') -> id <> id') !pattern21_matrix;
  load_patterns21 !pattern21_matrix

let _ =
  load_patterns21 [];
  load_patterns32 []