(*
 * Copyright (C) 2003-2004:
 *    Stefano Zacchiroli <zack@cs.unibo.it>
 *    for the HELM Team http://helm.cs.unibo.it/
 *
 *  This file is part of HELM, an Hypertextual, Electronic
 *  Library of Mathematics, developed at the Computer Science
 *  Department, University of Bologna, Italy.
 *
 *  HELM is free software; you can redistribute it and/or
 *  modify it under the terms of the GNU General Public License
 *  as published by the Free Software Foundation; either version 2
 *  of the License, or (at your option) any later version.
 *
 *  HELM is distributed in the hope that it will be useful,
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *  GNU General Public License for more details.
 *
 *  You should have received a copy of the GNU General Public License
 *  along with HELM; if not, write to the Free Software
 *  Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 *  MA  02111-1307, USA.
 *
 *  For details, see the HELM World-Wide-Web page,
 *  http://helm.cs.unibo.it/
 *)

open Http_getter_types;;
open Printf;;

let string_of_ls_flag = function No -> "NO" | Yes -> "YES" | Ann -> "ANN"
let string_of_encoding = function
  | Enc_normal -> "Normal"
  | Enc_gzipped -> "GZipped"

let is_cic_obj_uri uri = Pcre.pmatch ~pat:"^cic:" uri
let is_theory_uri uri = Pcre.pmatch ~pat:"^theory:" uri
let is_cic_uri uri = is_cic_obj_uri uri || is_theory_uri uri
let is_nuprl_uri uri = Pcre.pmatch ~pat:"^nuprl:" uri
let is_rdf_uri uri = Pcre.pmatch ~pat:"^helm:rdf(.*):(.*)//(.*)" uri
let is_xsl_uri uri = Pcre.pmatch ~pat:"^\\w+\\.xsl" uri

let rec uri_of_string = function
  | uri when is_rdf_uri uri ->
      (match Pcre.split ~pat:"//" uri with
      | [ prefix; uri ] ->
          let rest =
            match uri_of_string uri with
            | Cic_uri xmluri -> xmluri
            | _ -> raise (Invalid_URI uri)
          in
          Rdf_uri (prefix, rest)
      | _ -> raise (Invalid_URI uri))
  | uri when is_cic_uri uri -> Cic_uri (Cic (Pcre.replace ~pat:"^cic:" uri))
  | uri when is_nuprl_uri uri -> Nuprl_uri (Pcre.replace ~pat:"^nuprl:" uri)
  | uri when is_theory_uri uri ->
      Cic_uri (Theory (Pcre.replace ~pat:"^theory:" uri))
  | uri -> raise (Invalid_URI uri)

let patch_xml line =
  Pcre.replace
    ~pat:(sprintf "DOCTYPE (.*) SYSTEM\\s+\"%s/"
      (Lazy.force Http_getter_env.dtd_base_url))
    ~templ:(sprintf "DOCTYPE $1 SYSTEM \"%s/getdtd?uri="
      (Lazy.force Http_getter_env.my_own_url))
    line
let patch_xsl line =
  let mk_patch_fun tag line =
    Pcre.replace
      ~pat:(sprintf "%s\\s+href=\"" tag)
      ~templ:(sprintf "%s href=\"%s/getxslt?uri="
        tag (Lazy.force Http_getter_env.my_own_url))
      line
  in
  let (patch_import, patch_include) =
    (mk_patch_fun "xsl:import", mk_patch_fun "xsl:include")
  in
  patch_include (patch_import line)
let patch_dtd line =
  Pcre.replace
    ~pat:(sprintf "ENTITY (.*) SYSTEM\\s+\"(%s/)?"
      (Lazy.force Http_getter_env.dtd_base_url))
    ~templ:(sprintf "ENTITY $1 SYSTEM \"%s/getdtd?uri="
      (Lazy.force Http_getter_env.my_own_url))
    line

let return_file
  ~fname ?contype ?contenc ?(patch_fun = fun x -> x) ?(gunzip = false) outchan
  =
  let headers =
    match (contype, contenc) with
    | (Some t, Some e) -> ["Content-Encoding", e; "Content-Type", t]
    | (Some t, None) -> ["Content-Type" , t]
    | (None, Some e) -> ["Content-Encoding", e]
    | (None, None) -> []
  in
  Http_daemon.send_basic_headers ~code:200 outchan;
  Http_daemon.send_headers headers outchan;
  Http_daemon.send_CRLF outchan;
  if gunzip then begin  (* gunzip needed, uncompress file, apply patch_fun to
                        it, compress the result and sent it to client *)
    let (tmp1, tmp2) =
      (Http_getter_misc.tempfile (), Http_getter_misc.tempfile ())
    in
    try
      Http_getter_misc.gunzip ~keep:true ~output:tmp1 fname;(* gunzip to tmp1 *)
      let new_file = open_out tmp2 in
      Http_getter_misc.iter_file  (* tmp2 = patch(tmp1) *)
        (fun line -> output_string new_file (patch_fun line ^ "\n"))
        tmp1;
      close_out new_file;
      Http_getter_misc.gzip ~output:tmp1 tmp2;  (* tmp1 = gzip(tmp2); rm tmp2 *)
      Http_getter_misc.iter_file  (* send tmp1 to client as is*)
        (fun line -> output_string outchan (line ^ "\n"))
        tmp1;
      Sys.remove tmp1       (* rm tmp1 *)
    with e ->
      Sys.remove tmp1;
      raise e
  end else  (* no need to gunzip, apply patch_fun directly to file *)
    Http_getter_misc.iter_file
      (fun line -> output_string outchan (patch_fun line ^ "\n"))
      fname
;;