(* Copyright (C) 2000, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

(******************************************************************************)
(*                                                                            *)
(*                               PROJECT HELM                                 *)
(*                                                                            *)
(*                     Ferruccio Guidi <fguidi@cs.unibo.it>                   *)
(*                                 30/04/2002                                 *)
(*                                                                            *)
(*                                                                            *)
(******************************************************************************)


(* text linearization and parsing *******************************************)

let rec txt_list out f s = function
   | []        -> ()
   | [a]       -> f a
   | a :: tail -> f a; out s; txt_list out f s tail
   
let txt_str out s = out ("\"" ^ s ^ "\"")

let txt_path out (p0, p1) =
   txt_str out p0; if p1 <> [] then out "/"; txt_list out (txt_str out) "/" p1

let txt_svar out sv = out ("%" ^ sv) 

let txt_rvar out rv = out ("@" ^ rv) 

let txt_vvar out vv = out ("$" ^ vv) 

let text_of_query out x sep =
   let module M = MathQL in
   let txt_inv i = if i then out "inverse " in
   let txt_ref = function
      | M.RefineExact -> ()
      | M.RefineSub   -> out "sub "
      | M.RefineSuper -> out "super "
   in
   let txt_refpath i r p = txt_inv i; txt_ref r; txt_path out p; out " " in
   let txt_assign (pl, pr) = txt_vvar out (fst pl); out " <- "; txt_path out pr in
   let rec txt_val = function
      | M.Const [s]             -> txt_str out s
      | M.Const l               -> out "{"; txt_list out (txt_str out) ", " l; out "}"
      | M.VVar vv               -> txt_vvar out vv
      | M.Record (rv, p)        -> txt_rvar out rv; out "."; txt_vvar out (fst p)
      | M.Fun (s, x)            -> out "fun "; txt_str out s; out " "; txt_val x
      | M.Property (i, r, p, x) -> out "property "; txt_refpath i r p; txt_val x
      | M.RefOf x               -> out "refof "; txt_set x
   and txt_boole = function
      | M.False       -> out "false"
      | M.True        -> out "true"
      | M.Ex b x      -> out "ex "; txt_boole x
(*    | M.Ex b x      -> "ex [" ^ txt_list txt_rvar "," b ^ "] " ^ txt_boole x
*)    | M.Not x       -> out "not "; txt_boole x
      | M.And (x, y)  -> out "("; txt_boole x; out " and "; txt_boole y; out ")"
      | M.Or (x, y)   -> out "("; txt_boole x; out " or "; txt_boole y; out ")"
      | M.Sub (x, y)  -> out "("; txt_val x; out " sub "; txt_val y; out ")"
      | M.Meet (x, y) -> out "("; txt_val x; out " meet "; txt_val y; out ")"
      | M.Eq (x, y)   -> out "("; txt_val x; out " eq "; txt_val y; out ")"
   and txt_set = function
      | M.SVar sv                   -> txt_svar out sv
      | M.RVar rv                   -> txt_rvar out rv
      | M.Relation (i, r, p, M.Ref x, []) -> out "relation "; txt_refpath i r p; txt_val x
      | M.Relation (i, r, p, M.Ref x, l)  -> out "relation "; txt_refpath i r p; txt_val x; out " attr "; txt_list out txt_assign ", " l
      | M.Union (x, y)              -> out "("; txt_set x; out " union "; txt_set y; out ")"
      | M.Intersect (x, y)          -> out "("; txt_set x; out " intersect "; txt_set y; out ")"
      | M.Diff (x, y)               -> out "("; txt_set x; out " diff "; txt_set y; out ")"
      | M.LetSVar (sv, x, y)        -> out "let "; txt_svar out sv; out " be "; txt_set x; out " in "; txt_set y
      | M.LetVVar (vv, x, y)        -> out "let "; txt_vvar out vv; out " be "; txt_val x; out " in "; txt_set y
      | M.Select (rv, x, y)         -> out "select "; txt_rvar out rv; out " in "; txt_set x; out " where "; txt_boole y
      | M.Pattern x                 -> out "pattern "; txt_val x
      | M.Ref x                     -> out "ref "; txt_val x
      | _                           -> assert false
   in 
   txt_set x; out sep

let text_of_result out x sep =
   let txt_attr = function
      | (p, []) -> txt_vvar out (fst p)
      | (p, l)  -> txt_vvar out (fst p); out " = "; txt_list out (txt_str out) ", " l
   in
   let txt_group l = out "{"; txt_list out txt_attr "; " l; out "}" in
   let txt_res = function
      | (s, []) -> txt_str out s 
      | (s, l)  -> txt_str out s; out " attr "; txt_list out txt_group ", " l
   in   
   let txt_set l = txt_list out txt_res ("; " ^ sep) l in
   txt_set x; out sep

let query_of_text lexbuf =
   MQueryTParser.query MQueryTLexer.query_token lexbuf 

let result_of_text lexbuf =
   MQueryTParser.result MQueryTLexer.result_token lexbuf 

(* conversion functions *****************************************************)

type uriref = UriManager.uri * (int list)

let string_of_uriref (uri, fi) =
   let module UM = UriManager in
   let str = UM.string_of_uri uri in
   let xp t = "#xpointer(1/" ^ string_of_int (t + 1) in
   match fi with
      | []          -> str 
      | [t]         -> str ^ xp t ^ ")" 
      | t :: c :: _ -> str ^ xp t ^ "/" ^ string_of_int c ^ ")"