(* Copyright (C) 2000, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

(******************************************************************************)
(*                                                                            *)
(*                               PROJECT HELM                                 *)
(*                                                                            *)
(*                     Ferruccio Guidi <fguidi@cs.unibo.it>                   *)
(*                                 30/04/2002                                 *)
(*                                                                            *)
(*                                                                            *)
(******************************************************************************)


(* text linearization and parsing *******************************************)

let rec txt_list f s = function
   | []        -> ""
   | [a]       -> f a
   | a :: tail -> f a ^ s ^ txt_list f s tail
   
let txt_str s = "\"" ^ s ^ "\""

let txt_path (p0, p1) =
   txt_str p0 ^ (if p1 <> [] then "/" ^ txt_list txt_str "/" p1 else "")

let txt_svar sv = "%" ^ sv 

let txt_rvar rv = "@" ^ rv 

let txt_vvar vv = "$" ^ vv 

let text_of_query x =
   let module M = MathQL in
   let txt_inv i = if i then "inverse " else "" in
   let txt_ref = function
      | M.RefineExact -> ""
      | M.RefineSub   -> "sub "
      | M.RefineSuper -> "super "
   in
   let txt_refpath i r p = txt_inv i ^ txt_ref r ^ txt_path p ^ " " in
   let txt_assign (pl, pr) = txt_vvar (fst pl) ^ " <- " ^ txt_path pr in
   let rec txt_val = function
      | M.Const [s]             -> txt_str s
      | M.Const l               -> "{" ^ txt_list txt_str ", " l ^ "}"
      | M.VVar vv               -> txt_vvar vv
      | M.Record (rv, p)        -> txt_rvar rv ^ "." ^ txt_vvar (fst p)
      | M.Fun (s, x)            -> "fun " ^ txt_str s ^ " " ^ txt_val x
      | M.Property (i, r, p, x) -> "property " ^ txt_refpath i r p ^ txt_val x
      | M.RefOf x               -> "refof " ^ txt_set x
   and txt_boole = function
      | M.False       -> "false"
      | M.True        -> "true"
      | M.Ex b x      -> "ex " ^ txt_boole x
(*    | M.Ex b x      -> "ex [" ^ txt_list txt_rvar "," b ^ "] " ^ txt_boole x
*)    | M.Not x       -> "not " ^ txt_boole x
      | M.And (x, y)  -> "(" ^ txt_boole x ^ " and " ^ txt_boole y ^ ")"
      | M.Or (x, y)   -> "(" ^ txt_boole x ^ " or " ^ txt_boole y ^ ")"
      | M.Sub (x, y)  -> "(" ^ txt_val x ^ " sub " ^ txt_val y ^ ")"
      | M.Meet (x, y) -> "(" ^ txt_val x ^ " meet " ^ txt_val y ^ ")"
      | M.Eq (x, y)   -> "(" ^ txt_val x ^ " eq " ^ txt_val y ^ ")"
   and txt_set = function
      | M.SVar sv                   -> txt_svar sv
      | M.RVar rv                   -> txt_rvar rv
      | M.Relation (i, r, p, M.Ref x, []) -> "relation " ^ txt_refpath i r p ^ txt_val x
      | M.Relation (i, r, p, M.Ref x, l)  -> "relation " ^ txt_refpath i r p ^ txt_val x ^ " attr " ^ txt_list txt_assign ", " l
      | M.Union (x, y)              -> "(" ^ txt_set x ^ " union " ^ txt_set y ^ ")"
      | M.Intersect (x, y)          -> "(" ^ txt_set x ^ " intersect " ^ txt_set y ^ ")"
      | M.Diff (x, y)               -> "(" ^ txt_set x ^ " diff " ^ txt_set y ^ ")"
      | M.LetSVar (sv, x, y)        -> "let " ^ txt_svar sv ^ " be " ^ txt_set x ^ " in " ^ txt_set y
      | M.LetVVar (vv, x, y)        -> "let " ^ txt_vvar vv ^ " be " ^ txt_val x ^ " in " ^ txt_set y
      | M.Select (rv, x, y)         -> "select " ^ txt_rvar rv ^ " in " ^ txt_set x ^ " where " ^ txt_boole y
      | M.Pattern x                 -> "pattern " ^ txt_val x
      | M.Ref x                     -> "ref " ^ txt_val x
      | _                           -> assert false
   in 
   txt_set x

let text_of_result x sep =
   let txt_attr = function
      | (p, []) -> txt_vvar (fst p)
      | (p, l)  -> txt_vvar (fst p) ^ " = " ^ txt_list txt_str ", " l
   in
   let txt_group l = "{" ^ txt_list txt_attr "; " l ^ "}" in
   let txt_res = function
      | (s, []) -> txt_str s 
      | (s, l)  -> txt_str s ^ " attr " ^ txt_list txt_group ", " l
   in   
   let txt_set l = txt_list txt_res ("; " ^ sep) l ^ sep in
   txt_set x

let query_of_text lexbuf =
   MQueryTParser.query MQueryTLexer.query_token lexbuf 

let result_of_text lexbuf =
   MQueryTParser.result MQueryTLexer.result_token lexbuf 

(* conversion functions *****************************************************)

type uriref = UriManager.uri * (int list)

let string_of_uriref (uri, fi) =
   let module UM = UriManager in
   let str = UM.string_of_uri uri in
   let xp t = "#xpointer(1/" ^ string_of_int (t + 1) in
   match fi with
      | []          -> str 
      | [t]         -> str ^ xp t ^ ")" 
      | t :: c :: _ -> str ^ xp t ^ "/" ^ string_of_int c ^ ")"