(* Copyright (C) 2000, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

(*  AUTOR: Ferruccio Guidi <fguidi@cs.unibo.it>
 *)

module M = MathQL
module P = MQIPostgres
module C = MQIConn
module U = MQIUtil

let not_supported s = 
   raise (Failure ("MQIProperty: feature not supported: " ^ s)) 

(* debugging  ***************************************************************)

let pg_print l =
   let rec pg_record = function 
      | []           -> prerr_newline ()
      | head :: tail -> prerr_string (head ^ " "); pg_record tail
   in
   List.iter pg_record l

let cl_print l =  
   let c_print (b, p, v) =
      prerr_string (if b then "match " else "in ");
      List.iter (fun x -> prerr_string ("/" ^ x)) p;
      prerr_newline ();
      List.iter prerr_endline v
   in
   List.iter c_print l

(* PostgreSQL backend  ******************************************************)

let pg_query h table cols ct cfl =
   let exec q = 
      if C.set h C.Log then C.log h (q ^ "\n");
      P.exec (C.pgc h) q 
   in
   let rec iter f sep = function
      | []           -> ""
      | [head]       -> f head 
      | head :: tail -> f head ^ sep ^ iter f sep tail
   in
   let pg_cols = iter (fun x -> x) ", " cols in
   let pg_msval v = iter P.quote ", " v in
   let pg_con (pat, col, v) = 
      if col <> "" then 
         let f s = col ^ " ~ " ^ P.quote ("^" ^ s ^ "$") in
         if pat then "(" ^ iter f " or " v ^ ")"
	 else match v with 
	    | [s] -> col ^ " = " ^ (P.quote s)     
	    | v   -> col ^ " in (" ^ pg_msval v ^ ")"
      else "true"
   in
   let pg_cons l = iter pg_con " and " l in
   let pg_cons_not l = "not (" ^ pg_cons l ^ ")" in
   let pg_cons_not_l ll = iter pg_cons_not " and " ll in
   let pg_where = match ct, cfl with
      | [], []  -> ""
      | lt, []  -> " where " ^ pg_cons lt
      | [], llf -> " where " ^ pg_cons_not_l llf
      | lt, llf -> " where " ^ pg_cons lt ^ " and " ^ pg_cons_not_l llf
   in
   if cols = [] then
      let r = exec ("select count (source) from " ^ table ^ pg_where) in
      match r with
         | [[s]] when int_of_string s > 0 -> [[]]
	 | _                              -> []
   else
      exec ("select " ^ pg_cols ^ " from " ^ table ^ pg_where ^ 
            " order by " ^ List.hd cols ^ " asc")

(* Galax backend  ***********************************************************)

let gx_query h table cols ct cfl = not_supported "Galax"

(* Common functions  ********************************************************)

let pg_result distinct subj el res =
  let compose = if distinct then List.map else fun f -> U.mql_iter (fun x -> [f x]) in 
  let get_name = function (p, None) -> p | (_, Some p) -> p in
  let names = List.map get_name el in
  let mk_grp l = 
     let grp = U.mql_iter2 (fun p s -> [(p, [s])]) names l in 
     if grp = [] then [] else [grp]
  in
  let mk_avs l =
     if subj = "" then ("", mk_grp l) else (List.hd l, mk_grp (List.tl l))
  in
  compose mk_avs res

let get_table mc ct cfl el =
   let fst = function
      | []           -> None
      | head :: tail -> Some head
   in
   let comp n1 n2 = match n1, n2 with
      | None, _                   -> n2 
      | Some h, Some k when h = k -> n2
      | _, None                   -> n1
      | _                         -> not_supported "comp"
   in   
   let rec get_c prev = function
      | []                -> prev
      | (_, p, _) :: tail -> get_c (comp prev (fst p)) tail
   in
   let rec get_e prev = function
      | []             -> prev
      | (p, _) :: tail -> get_e (comp prev (fst p)) tail
   in
   get_e (get_c (get_c (fst mc) ct) (List.concat cfl)) el  

let rec decolon s =
   let l = String.length s in
   try 
      let i = String.index s ':' in
      String.sub s 0 i ^ "_" ^ decolon (String.sub s (succ i) (l - succ i))
   with Not_found -> s

let conv_bp = function
   | []                  -> "h_occurrence" 
   | [t]                 -> ""
   | [_; "h:occurrence"] -> "source"
   | [_; t]              -> decolon t
   | _                   -> not_supported "conv_bp"

let conv_gen = function
   | []             -> "source"
   | ["objectName"] -> "value" 
   | [t]            -> ""
   | [_; t]         -> decolon t
   | _              -> not_supported "conv" 

let exec_single h mc ct cfl el t =
   let table = match t with Some t -> decolon t | None -> "objectName" in
   let table, conv = 
      if table = "backPointer" then "refObj", conv_bp else table, conv_gen
   in
   let first = conv mc in
   let mk_con l = List.map (fun (pat, p, v) -> (pat, conv p, v)) l in
   let cons_true = mk_con ct in 
   let cons_false = List.map mk_con cfl in
   let other_cols = List.map (fun (p, _) -> conv p) el in 
   let cols = if first = "" then other_cols else first :: other_cols in
   let low_level = if C.set h C.Galax then gx_query else pg_query in
   pg_result false first el (low_level h table cols cons_true cons_false) 
   
let deadline = 100

let exec h refine mc ct cfl el =
   if refine <> M.RefineExact then not_supported "exec";   
   let table = get_table mc ct cfl el in
   let rec exec_aux ct = match ct with 
      | (pat, p, v) :: tail when List.length v > deadline ->
         let single s = exec_aux ((pat, p, [s]) :: tail) in
	 U.mql_iter single v
      | _                                                 ->
         exec_single h mc ct cfl el table
   in exec_aux ct	 

(* funzioni vecchie  ********************************************************)

let pg_name h s = 
   let q = "select id from registry where uri = " ^ P.quote s in
   match P.exec h q with
      | [[id]] -> "t" ^ id
      | _      -> ""

let get_id b = if b then ["B"] else ["F"]