(* type naif_indexing =
    (Cic.term * ((bool * Inference.equality) list)) list 
;; *)

type pos = Left | Right ;;

let head_of_term = function
  | Cic.Appl (hd::tl) -> hd
  | t -> t
;;


let index table (sign, eq) =
  let _, (_, l, r, ordering), _, _ = eq in
  let hl = head_of_term l in
  let hr = head_of_term r in
  let index x pos = 
    let x_entry = try Hashtbl.find table x with Not_found -> [] in
    Hashtbl.replace table x ((pos, sign, eq)::x_entry)
  in
(*   (match ordering with *)
(*    | Utils.Gt ->  *)
(*        index hl Left *)
(*    | Utils.Lt ->  *)
(*        index hr Right *)
(*    | _ -> index hl Left; *)
(*        index hr Right); *)
  index hl Left;
  index hr Right;
  table
;;


let remove_index table (sign, eq) =
  let _, (_, l, r, ordering), _, _ = eq in
  let hl = head_of_term l
  and hr = head_of_term r in
  let remove_index x pos =
    let x_entry = try Hashtbl.find table x with Not_found -> [] in
    let newentry = List.filter (fun e -> e <> (pos, sign, eq)) x_entry in
    Hashtbl.replace table x newentry
  in
  remove_index hl Left;
  remove_index hr Right;
  table
;;


let rec find_matches metasenv context ugraph lift_amount term =
  let module C = Cic in
  let module U = Utils in
  let module S = CicSubstitution in
  let module M = CicMetaSubst in
  let module HL = HelmLibraryObjects in
  let cmp = !Utils.compare_terms in
  function
    | [] -> None
    | (_, U.Negative, _)::tl ->
        find_matches metasenv context ugraph lift_amount term tl
    | (pos, U.Positive, (_, (_, _, _, o), _, _))::tl
        when (pos = Left && o = U.Lt) || (pos = Right && o = U.Gt) ->
        find_matches metasenv context ugraph lift_amount term tl
    | (pos, U.Positive, (proof, (ty, left, right, o), metas, args))::tl ->
        let do_match c other eq_URI =
          let subst', metasenv', ugraph' =
            Inference.matching (metasenv @ metas) context term
              (S.lift lift_amount c) ugraph
          in
          Some (C.Rel (1 + lift_amount), subst', metasenv', ugraph',
                (proof, ty, c, other, eq_URI))
        in
        let c, other, eq_URI =
          if pos = Left then left, right, HL.Logic.eq_ind_URI
          else right, left, HL.Logic.eq_ind_r_URI
        in
        if o <> U.Incomparable then
          try do_match c other eq_URI
          with e -> find_matches metasenv context ugraph lift_amount term tl
        else
          let res = try do_match c other eq_URI with e -> None in
          match res with
          | Some (_, s, _, _, _) -> 
              if cmp (M.apply_subst s left) (M.apply_subst s right) =
                (if pos = Left then U.Gt else U.Lt) then
                  res
              else
                find_matches metasenv context ugraph lift_amount term tl
          | None ->
              find_matches metasenv context ugraph lift_amount term tl
;;


let rec demodulate_term metasenv context ugraph table lift_amount term =
  let module C = Cic in
  let module S = CicSubstitution in
  let module M = CicMetaSubst in
  let module HL = HelmLibraryObjects in
  let hd_term = head_of_term term in
  let candidates = try Hashtbl.find table hd_term with Not_found -> [] in
  match term with
  | C.Meta _ -> None
  | term ->
      let res =
        find_matches metasenv context ugraph lift_amount term candidates
      in
      if res <> None then
        res
      else
        match term with
        | C.Appl l ->
            let res, ll = 
              List.fold_left
                (fun (res, tl) t ->
                   if res <> None then
                     (res, tl @ [S.lift 1 t])
                   else 
                     let r =
                       demodulate_term metasenv context ugraph table
                         lift_amount t
                     in
                     match r with
                     | None -> (None, tl @ [S.lift 1 t])
                     | Some (rel, _, _, _, _) -> (r, tl @ [rel]))
                (None, []) l
            in (
              match res with
              | None -> None
              | Some (_, subst, menv, ug, info) ->
                  Some (C.Appl ll, subst, menv, ug, info)
            )
        | C.Prod (nn, s, t) ->
            let r1 =
              demodulate_term metasenv context ugraph table lift_amount s in (
              match r1 with
              | None ->
                  let r2 =
                    demodulate_term metasenv
                      ((Some (nn, C.Decl s))::context) ugraph
                      table (lift_amount+1) t
                  in (
                    match r2 with
                    | None -> None
                    | Some (t', subst, menv, ug, info) ->
                        Some (C.Prod (nn, (S.lift 1 s), t'),
                              subst, menv, ug, info)
                  )
              | Some (s', subst, menv, ug, info) ->
                  Some (C.Prod (nn, s', (S.lift 1 t)), subst, menv, ug, info)
            )
        | t ->
            Printf.printf "Ne` Appl ne` Prod: %s\n"
              (CicPp.pp t (Utils.names_of_context context));
            None
;;


let rec demodulate newmeta env table target =
  let module C = Cic in
  let module S = CicSubstitution in
  let module M = CicMetaSubst in
  let module HL = HelmLibraryObjects in
  let metasenv, context, ugraph = env in
  let proof, (eq_ty, left, right, order), metas, args = target in
  let metasenv = metasenv @ metas in
  let build_newtarget is_left
      (t, subst, menv, ug, (proof', ty, what, other, eq_URI)) = 
    let newterm, newproof =
      let bo = S.subst (M.apply_subst subst other) t in
      let bo'' =
        C.Appl ([C.MutInd (HL.Logic.eq_URI, 0, []);
                 S.lift 1 eq_ty] @
                  if is_left then [bo; S.lift 1 right] else [S.lift 1 left; bo])
      in
      let t' = C.Lambda (C.Anonymous, ty, bo'') in
      bo,
      M.apply_subst subst (C.Appl [C.Const (eq_URI, []); ty; what; t';
                                   proof; other; proof'])
    in
    let newmeta, newtarget =
      let left, right = if is_left then newterm, right else left, newterm in
      let m =
        (Inference.metas_of_term left) @ (Inference.metas_of_term right)
      in
      let newmetasenv = List.filter (fun (i, _, _) -> List.mem i m) metas
      and newargs =
        List.filter
          (function C.Meta (i, _) -> List.mem i m | _ -> assert false)
          args
      in
      let ordering = !Utils.compare_terms left right in
      newmeta, (newproof, (eq_ty, left, right, ordering), newmetasenv, newargs)
    in
    newmeta, newtarget
  in
  let res = demodulate_term metasenv context ugraph table 0 left in
  match res with
  | Some t ->
      let newmeta, newtarget = build_newtarget true t in
      if Inference.is_identity (metasenv, context, ugraph) newtarget then
        newmeta, newtarget
      else
        demodulate newmeta env table newtarget
  | None ->
      let res = demodulate_term metasenv context ugraph table 0 right in
      match res with
      | Some t ->
          let newmeta, newtarget = build_newtarget false t in
          if Inference.is_identity (metasenv, context, ugraph) newtarget then
            newmeta, newtarget
          else
            demodulate newmeta env table newtarget
      | None ->
          newmeta, target
;;


let rec betaexpand_term metasenv context ugraph table lift_amount term =
  let module C = Cic in
  let module S = CicSubstitution in
  let module M = CicMetaSubst in
  let module HL = HelmLibraryObjects in
  let hd_term = head_of_term term in
  let candidates = try Hashtbl.find table hd_term with Not_found -> [] in
  let res, lifted_term = 
    match term with
    | C.Meta (i, l) ->
        let l = 
          List.map (function
                      | Some t -> Some (S.lift lift_amount t)
                      | None -> None) l
        in
        [], C.Meta (i, l)
          
    | C.Rel m ->
        [], if m <= lift_amount then C.Rel m else C.Rel (m+1)
          
    | C.Prod (nn, s, t) ->
        let l1, lifted_s =
          betaexpand_term metasenv context ugraph table lift_amount s in
        let l2, lifted_t =
          betaexpand_term metasenv ((Some (nn, C.Decl s))::context) ugraph
            table (lift_amount+1) t in
        let l1' =
          List.map
            (fun (t, s, m, ug, info) ->
               C.Prod (nn, t, lifted_t), s, m, ug, info) l1
        and l2' =
          List.map
            (fun (t, s, m, ug, info) ->
               C.Prod (nn, lifted_s, t), s, m, ug, info) l2 in
        l1' @ l2', C.Prod (nn, lifted_s, lifted_t)
          
    | C.Appl l ->
        let l', lifted_l =
          List.fold_right
            (fun arg (res, lifted_tl) ->
               let arg_res, lifted_arg =
                 betaexpand_term metasenv context ugraph table lift_amount arg
               in
               let l1 =
                 List.map
                   (fun (a, s, m, ug, info) -> a::lifted_tl, s, m, ug, info)
                   arg_res
               in
               (l1 @
                  (List.map
                     (fun (r, s, m, ug, info) -> lifted_arg::r, s, m, ug, info)
                     res),
                lifted_arg::lifted_tl)
            ) l ([], [])
        in
        (List.map (fun (l, s, m, ug, info) -> (C.Appl l, s, m, ug, info)) l',
         C.Appl lifted_l)

    | t -> [], (S.lift lift_amount t)
  in
  match term with
  | C.Meta _ -> res, lifted_term
  | _ ->
      match
        find_matches metasenv context ugraph lift_amount term candidates
      with
      | None -> res, lifted_term
      | Some r -> r::res, lifted_term
;;


let superposition_left (metasenv, context, ugraph) table target =
  let module C = Cic in
  let module S = CicSubstitution in
  let module M = CicMetaSubst in
  let module HL = HelmLibraryObjects in
  let module CR = CicReduction in
  let module U = Utils in
  let proof, (eq_ty, left, right, ordering), _, _ = target in
  let expansions, _ =
    let term = if ordering = U.Gt then left else right in
    betaexpand_term metasenv context ugraph table 0 term
  in
  let build_new (bo, s, m, ug, (proof', ty, what, other, eq_URI)) =
    let newgoal, newproof =
      let bo' = S.subst (M.apply_subst s other) bo in
      let bo'' =
        C.Appl (
          [C.MutInd (HL.Logic.eq_URI, 0, []);
           S.lift 1 eq_ty] @
            if ordering = U.Gt then [bo'; S.lift 1 right]
            else [S.lift 1 left; bo'])
      in
      let t' = C.Lambda (C.Anonymous, ty, bo'') in
      S.subst (M.apply_subst s other) bo,
      M.apply_subst s
        (C.Appl [C.Const (eq_URI, []); ty; what; t';
                 proof; other; proof'])
    in
    let left, right, newordering =
      if ordering = U.Gt then
        newgoal, right, !Utils.compare_terms newgoal right
      else
        left, newgoal, !Utils.compare_terms left newgoal
    in
    (newproof, (eq_ty, left, right, ordering), [], [])
  in
  List.map build_new expansions
;;


let superposition_right newmeta (metasenv, context, ugraph) table target =
  let module C = Cic in
  let module S = CicSubstitution in
  let module M = CicMetaSubst in
  let module HL = HelmLibraryObjects in
  let module CR = CicReduction in
  let module U = Utils in
  let eqproof, (eq_ty, left, right, ordering), newmetas, args = target in
  let maxmeta = ref newmeta in
  let res1, res2 =
    match ordering with
    | U.Gt -> fst (betaexpand_term metasenv context ugraph table 0 left), []
    | U.Lt -> [], fst (betaexpand_term metasenv context ugraph table 0 right)
    | _ ->
        let res l r =
          List.filter
            (fun (_, subst, _, _, _) ->
               let subst = M.apply_subst subst in
               let o = !Utils.compare_terms (subst l) (subst r) in
               o <> U.Lt && o <> U.Le)
            (fst (betaexpand_term metasenv context ugraph table 0 l))
        in
        (res left right), (res right left)
  in
  let build_new ordering (bo, s, m, ug, (proof', ty, what, other, eq_URI)) =
    let newgoal, newproof =
      let bo' = S.subst (M.apply_subst s other) bo in
      let bo'' =
        C.Appl (
          [C.MutInd (HL.Logic.eq_URI, 0, []);
           S.lift 1 eq_ty] @
            if ordering = U.Gt then [bo'; S.lift 1 right]
            else [S.lift 1 left; bo'])
      in
      let t' = C.Lambda (C.Anonymous, ty, bo'') in
      S.subst (M.apply_subst s other) bo,
      M.apply_subst s
        (C.Appl [C.Const (eq_URI, []); ty; what; t';
                 eqproof; other; proof'])
    in
    let newmeta, newequality = 
      let left, right, newordering =
        if ordering = U.Gt then
          newgoal, right, !Utils.compare_terms newgoal right
        else
          left, newgoal, !Utils.compare_terms left newgoal
      in
      Inference.fix_metas !maxmeta
        (newproof, (eq_ty, left, right, ordering), [], [])
    in
    maxmeta := newmeta;
    newequality
  in
  let new1 = List.map (build_new U.Gt) res1
  and new2 = List.map (build_new U.Lt) res2 in
  let ok = function
    | _, (_, left, right, _), _, _ ->
        not (fst (CR.are_convertible context left right ugraph))
  in
  (!maxmeta,
   (List.filter ok (new1 @ new2)))
;;