type retrieval_mode = Matching | Unification;;


let empty_table () =
  Path_indexing.PSTrie.empty
;;

let index = Path_indexing.index
and remove_index = Path_indexing.remove_index
and in_index = Path_indexing.in_index;;
  
let get_candidates mode trie term =
  let s = 
    match mode with
    | Matching -> Path_indexing.retrieve_generalizations trie term
    | Unification -> Path_indexing.retrieve_unifiables trie term
  in
  Path_indexing.PosEqSet.elements s
;;


(*
let empty_table () =
  Discrimination_tree.DiscriminationTree.empty
;;

let index = Discrimination_tree.index
and remove_index = Discrimination_tree.remove_index
and in_index = Discrimination_tree.in_index;;

let get_candidates mode tree term =
  match mode with
  | Matching -> Discrimination_tree.retrieve_generalizations tree term
  | Unification -> Discrimination_tree.retrieve_unifiables tree term
;;
*)


let rec find_matches metasenv context ugraph lift_amount term =
  let module C = Cic in
  let module U = Utils in
  let module S = CicSubstitution in
  let module M = CicMetaSubst in
  let module HL = HelmLibraryObjects in
  let cmp = !Utils.compare_terms in
  let names = Utils.names_of_context context in
  function
    | [] -> None
    | candidate::tl ->
        let pos, (proof, (ty, left, right, o), metas, args) = candidate in
        let do_match c other eq_URI =
          let subst', metasenv', ugraph' =
            Inference.matching (metasenv @ metas) context
              term (S.lift lift_amount c) ugraph
          in
          Some (C.Rel (1 + lift_amount), subst', metasenv', ugraph',
                (candidate, eq_URI))
        in
        let c, other, eq_URI =
          if pos = Utils.Left then left, right, HL.Logic.eq_ind_URI
          else right, left, HL.Logic.eq_ind_r_URI
        in
        if o <> U.Incomparable then
          try
            do_match c other eq_URI
          with e ->
            find_matches metasenv context ugraph lift_amount term tl
        else
          let res = try do_match c other eq_URI with e -> None in
          match res with
          | Some (_, s, _, _, _) ->
              let c' = M.apply_subst s c
              and other' = M.apply_subst s other in
              let order = cmp c' other' in
              let names = U.names_of_context context in
              if order = U.Gt then
                res
              else
                find_matches metasenv context ugraph lift_amount term tl
          | None ->
              find_matches metasenv context ugraph lift_amount term tl
;;


let rec find_all_matches ?(unif_fun=CicUnification.fo_unif)
    metasenv context ugraph lift_amount term =
  let module C = Cic in
  let module U = Utils in
  let module S = CicSubstitution in
  let module M = CicMetaSubst in
  let module HL = HelmLibraryObjects in
  let cmp = !Utils.compare_terms in
  let names = Utils.names_of_context context in
  function
    | [] -> []
    | candidate::tl ->
        let pos, (proof, (ty, left, right, o), metas, args) = candidate in
        let do_match c other eq_URI =
          let subst', metasenv', ugraph' =
            unif_fun (metasenv @ metas) context
              term (S.lift lift_amount c) ugraph
          in
          (C.Rel (1 + lift_amount), subst', metasenv', ugraph',
           (candidate, eq_URI))
        in
        let c, other, eq_URI =
          if pos = Utils.Left then left, right, HL.Logic.eq_ind_URI
          else right, left, HL.Logic.eq_ind_r_URI
        in
        if o <> U.Incomparable then
          try
            let res = do_match c other eq_URI in
            res::(find_all_matches ~unif_fun metasenv context ugraph
                    lift_amount term tl)
          with e ->
            find_all_matches ~unif_fun metasenv context ugraph
              lift_amount term tl
        else
          try
            let res = do_match c other eq_URI in
            match res with
            | _, s, _, _, _ ->
                let c' = M.apply_subst s c
                and other' = M.apply_subst s other in
                let order = cmp c' other' in
                let names = U.names_of_context context in
                if order <> U.Lt && order <> U.Le then
                  res::(find_all_matches ~unif_fun metasenv context ugraph
                          lift_amount term tl)
                else
                  find_all_matches ~unif_fun metasenv context ugraph
                    lift_amount term tl
          with e ->
            find_all_matches ~unif_fun metasenv context ugraph
              lift_amount term tl
;;


let subsumption env table target =
  let _, (ty, tl, tr, _), tmetas, _ = target in
  let metasenv, context, ugraph = env in
  let metasenv = metasenv @ tmetas in
  let samesubst subst subst' =
    let tbl = Hashtbl.create (List.length subst) in
    List.iter (fun (m, (c, t1, t2)) -> Hashtbl.add tbl m (c, t1, t2)) subst;
    List.for_all
      (fun (m, (c, t1, t2)) ->
         try
           let c', t1', t2' = Hashtbl.find tbl m in
           if (c = c') && (t1 = t1') && (t2 = t2') then true
           else false
         with Not_found ->
           true)
      subst'
  in
  let subsaux left right =
    let leftc = get_candidates Matching table left in
    let leftr =
      find_all_matches ~unif_fun:Inference.matching
        metasenv context ugraph 0 left leftc
    in
    let ok what (_, subst, menv, ug, ((pos, (_, (_, l, r, o), _, _)), _)) =
      try
        let other = if pos = Utils.Left then r else l in
        let subst', menv', ug' =
          Inference.matching metasenv context what other ugraph in
        samesubst subst subst'
      with e ->
        false
    in
    let r = List.exists (ok right) leftr in
    if r then
      true
    else
      let rightc = get_candidates Matching table right in
      let rightr =
        find_all_matches ~unif_fun:Inference.matching
          metasenv context ugraph 0 right rightc
      in
      List.exists (ok left) rightr
  in
  let res =  subsaux tl tr in
  if res then (
    Printf.printf "subsumption!:\ntarget: %s\n"
      (Inference.string_of_equality ~env target);
    print_newline ();
  );
  res
;;


let rec demodulate_term metasenv context ugraph table lift_amount term =
  let module C = Cic in
  let module S = CicSubstitution in
  let module M = CicMetaSubst in
  let module HL = HelmLibraryObjects in
  let candidates = get_candidates Matching table term in
  match term with
  | C.Meta _ -> None
  | term ->
      let res =
        find_matches metasenv context ugraph lift_amount term candidates
      in
      if res <> None then
        res
      else
        match term with
        | C.Appl l ->
            let res, ll = 
              List.fold_left
                (fun (res, tl) t ->
                   if res <> None then
                     (res, tl @ [S.lift 1 t])
                   else 
                     let r =
                       demodulate_term metasenv context ugraph table
                         lift_amount t
                     in
                     match r with
                     | None -> (None, tl @ [S.lift 1 t])
                     | Some (rel, _, _, _, _) -> (r, tl @ [rel]))
                (None, []) l
            in (
              match res with
              | None -> None
              | Some (_, subst, menv, ug, eq_found) ->
                  Some (C.Appl ll, subst, menv, ug, eq_found)
            )
        | C.Prod (nn, s, t) ->
            let r1 =
              demodulate_term metasenv context ugraph table lift_amount s in (
              match r1 with
              | None ->
                  let r2 =
                    demodulate_term metasenv
                      ((Some (nn, C.Decl s))::context) ugraph
                      table (lift_amount+1) t
                  in (
                    match r2 with
                    | None -> None
                    | Some (t', subst, menv, ug, eq_found) ->
                        Some (C.Prod (nn, (S.lift 1 s), t'),
                              subst, menv, ug, eq_found)
                  )
              | Some (s', subst, menv, ug, eq_found) ->
                  Some (C.Prod (nn, s', (S.lift 1 t)),
                        subst, menv, ug, eq_found)
            )
        | t ->
            None
;;


let rec demodulation newmeta env table target =
  let module C = Cic in
  let module S = CicSubstitution in
  let module M = CicMetaSubst in
  let module HL = HelmLibraryObjects in
  let metasenv, context, ugraph = env in
  let proof, (eq_ty, left, right, order), metas, args = target in
  let metasenv' = metasenv @ metas in
  let build_newtarget is_left (t, subst, menv, ug, (eq_found, eq_URI)) =
    let pos, (proof', (ty, what, other, _), menv', args') = eq_found in
    let what, other = if pos = Utils.Left then what, other else other, what in
    let newterm, newproof =
      let bo = M.apply_subst subst (S.subst other t) in
      let bo'' =
        C.Appl ([C.MutInd (HL.Logic.eq_URI, 0, []);
                 S.lift 1 eq_ty] @
                 if is_left then [bo; S.lift 1 right] else [S.lift 1 left; bo])
      in
      let t' = C.Lambda (C.Anonymous, ty, bo'') in
      bo,
      M.apply_subst subst (C.Appl [C.Const (eq_URI, []); ty; what; t';
                                   proof; other; proof'])
    in
    let left, right = if is_left then newterm, right else left, newterm in
    let m =
      (Inference.metas_of_term left) @ (Inference.metas_of_term right)
    in
    let newmetasenv = List.filter (fun (i, _, _) -> List.mem i m) metas
    and newargs =
      List.filter
        (function C.Meta (i, _) -> List.mem i m | _ -> assert false)
        args
    in
    let ordering = !Utils.compare_terms left right in
    newmeta, (newproof, (eq_ty, left, right, ordering), newmetasenv, newargs)
  in
  let res = demodulate_term metasenv' context ugraph table 0 left in
  let build_identity (p, (t, l, r, o), m, a) =
    match o with
    | Utils.Gt -> (p, (t, r, r, Utils.Eq), m, a)
    | _ -> (p, (t, l, l, Utils.Eq), m, a)
  in
  match res with
  | Some t ->
      let newmeta, newtarget = build_newtarget true t in
      if (Inference.is_identity (metasenv', context, ugraph) newtarget) ||
        (Inference.meta_convertibility_eq target newtarget) then
          newmeta, newtarget
      else
        if subsumption env table newtarget then
          newmeta, build_identity newtarget
        else
          demodulation newmeta env table newtarget
  | None ->
      let res = demodulate_term metasenv' context ugraph table 0 right in
      match res with
      | Some t ->
          let newmeta, newtarget = build_newtarget false t in
          if (Inference.is_identity (metasenv', context, ugraph) newtarget) ||
            (Inference.meta_convertibility_eq target newtarget) then
              newmeta, newtarget
          else
            if subsumption env table newtarget then
              newmeta, build_identity newtarget
            else
              demodulation newmeta env table newtarget
      | None ->
          newmeta, target
;;


let rec betaexpand_term metasenv context ugraph table lift_amount term =
  let module C = Cic in
  let module S = CicSubstitution in
  let module M = CicMetaSubst in
  let module HL = HelmLibraryObjects in
  let candidates = get_candidates Unification table term in
  let res, lifted_term = 
    match term with
    | C.Meta (i, l) ->
        let l', lifted_l = 
          List.fold_right
            (fun arg (res, lifted_tl) ->
               match arg with
               | Some arg ->
                   let arg_res, lifted_arg =
                     betaexpand_term metasenv context ugraph table
                       lift_amount arg in
                   let l1 =
                     List.map
                       (fun (t, s, m, ug, eq_found) ->
                          (Some t)::lifted_tl, s, m, ug, eq_found)
                       arg_res
                   in
                   (l1 @
                      (List.map
                         (fun (l, s, m, ug, eq_found) ->
                            (Some lifted_arg)::l, s, m, ug, eq_found)
                         res),
                    (Some lifted_arg)::lifted_tl)
               | None ->
                   (List.map
                      (fun (r, s, m, ug, eq_found) ->
                         None::r, s, m, ug, eq_found) res, 
                    None::lifted_tl)
            ) l ([], [])
        in
        let e = 
          List.map
            (fun (l, s, m, ug, eq_found) ->
               (C.Meta (i, l), s, m, ug, eq_found)) l'
        in
        e, C.Meta (i, lifted_l)
          
    | C.Rel m ->
        [], if m <= lift_amount then C.Rel m else C.Rel (m+1)
          
    | C.Prod (nn, s, t) ->
        let l1, lifted_s =
          betaexpand_term metasenv context ugraph table lift_amount s in
        let l2, lifted_t =
          betaexpand_term metasenv ((Some (nn, C.Decl s))::context) ugraph
            table (lift_amount+1) t in
        let l1' =
          List.map
            (fun (t, s, m, ug, eq_found) ->
               C.Prod (nn, t, lifted_t), s, m, ug, eq_found) l1
        and l2' =
          List.map
            (fun (t, s, m, ug, eq_found) ->
               C.Prod (nn, lifted_s, t), s, m, ug, eq_found) l2 in
        l1' @ l2', C.Prod (nn, lifted_s, lifted_t)
          
    | C.Appl l ->
        let l', lifted_l =
          List.fold_right
            (fun arg (res, lifted_tl) ->
               let arg_res, lifted_arg =
                 betaexpand_term metasenv context ugraph table lift_amount arg
               in
               let l1 =
                 List.map
                   (fun (a, s, m, ug, eq_found) ->
                      a::lifted_tl, s, m, ug, eq_found)
                   arg_res
               in
               (l1 @
                  (List.map
                     (fun (r, s, m, ug, eq_found) ->
                        lifted_arg::r, s, m, ug, eq_found)
                     res),
                lifted_arg::lifted_tl)
            ) l ([], [])
        in
        (List.map
           (fun (l, s, m, ug, eq_found) -> (C.Appl l, s, m, ug, eq_found)) l',
         C.Appl lifted_l)

    | t -> [], (S.lift lift_amount t)
  in
  match term with
  | C.Meta _ -> res, lifted_term
  | term ->
      let r = 
        find_all_matches metasenv context ugraph lift_amount term candidates
      in
      r @ res, lifted_term
;;


let superposition_left (metasenv, context, ugraph) table target =
  let module C = Cic in
  let module S = CicSubstitution in
  let module M = CicMetaSubst in
  let module HL = HelmLibraryObjects in
  let module CR = CicReduction in
  let module U = Utils in
  let proof, (eq_ty, left, right, ordering), _, _ = target in
  let expansions, _ =
    let term = if ordering = U.Gt then left else right in
    betaexpand_term metasenv context ugraph table 0 term
  in
  let build_new (bo, s, m, ug, (eq_found, eq_URI)) =
    let pos, (proof', (ty, what, other, _), menv', args') = eq_found in
    let what, other = if pos = Utils.Left then what, other else other, what in
    let newgoal, newproof =
      let bo' = M.apply_subst s (S.subst other bo) in
      let bo'' =
        C.Appl (
          [C.MutInd (HL.Logic.eq_URI, 0, []);
           S.lift 1 eq_ty] @
            if ordering = U.Gt then [bo'; S.lift 1 right]
            else [S.lift 1 left; bo'])
      in
      let t' = C.Lambda (C.Anonymous, ty, bo'') in
      bo',
      M.apply_subst s
        (C.Appl [C.Const (eq_URI, []); ty; what; t';
                 proof; other; proof'])
    in
    let left, right =
      if ordering = U.Gt then newgoal, right else left, newgoal in
    let neworder = !Utils.compare_terms left right in
    (newproof, (eq_ty, left, right, neworder), [], [])
  in
  List.map build_new expansions
;;


let superposition_right newmeta (metasenv, context, ugraph) table target =
  let module C = Cic in
  let module S = CicSubstitution in
  let module M = CicMetaSubst in
  let module HL = HelmLibraryObjects in
  let module CR = CicReduction in
  let module U = Utils in
  let eqproof, (eq_ty, left, right, ordering), newmetas, args = target in
  let metasenv' = metasenv @ newmetas in
  let maxmeta = ref newmeta in
  let res1, res2 =
    match ordering with
    | U.Gt -> fst (betaexpand_term metasenv' context ugraph table 0 left), []
    | U.Lt -> [], fst (betaexpand_term metasenv' context ugraph table 0 right)
    | _ ->
        let res l r =
          List.filter
            (fun (_, subst, _, _, _) ->
               let subst = M.apply_subst subst in
               let o = !Utils.compare_terms (subst l) (subst r) in
               o <> U.Lt && o <> U.Le)
            (fst (betaexpand_term metasenv' context ugraph table 0 l))
        in
        (res left right), (res right left)
  in
  let build_new ordering (bo, s, m, ug, (eq_found, eq_URI)) =
    let pos, (proof', (ty, what, other, _), menv', args') = eq_found in
    let what, other = if pos = Utils.Left then what, other else other, what in
    let newgoal, newproof =
      let bo' = M.apply_subst s (S.subst other bo) in
      let bo'' =
        C.Appl (
          [C.MutInd (HL.Logic.eq_URI, 0, []); S.lift 1 eq_ty] @
            if ordering = U.Gt then [bo'; S.lift 1 right]
            else [S.lift 1 left; bo'])
      in
      let t' = C.Lambda (C.Anonymous, ty, bo'') in
      bo',
      M.apply_subst s
        (C.Appl [C.Const (eq_URI, []); ty; what; t';
                 eqproof; other; proof'])
    in
    let newmeta, newequality = 
      let left, right =
        if ordering = U.Gt then newgoal, M.apply_subst s right
        else M.apply_subst s left, newgoal in
      let neworder = !Utils.compare_terms left right 
      and newmenv = newmetas @ menv'
      and newargs = args @ args' in
      let eq' = (newproof, (eq_ty, left, right, neworder), newmenv, newargs)
      and env = (metasenv, context, ugraph) in
      let newm, eq' = Inference.fix_metas !maxmeta eq' in
      newm, eq'
    in
    maxmeta := newmeta;
    newequality
  in
  let new1 = List.map (build_new U.Gt) res1
  and new2 = List.map (build_new U.Lt) res2 in
  let ok = function
    | _, (_, left, right, _), _, _ ->
        not (fst (CR.are_convertible context left right ugraph))
  in
  (!maxmeta,
   (List.filter ok (new1 @ new2)))
;;