let configuration_file = ref "../../matita/matita.conf.xml";;

let core_notation_script = "../../matita/core_notation.moo";;

let get_from_user ~(dbd:Mysql.dbd) =
  let rec get () =
    match read_line () with
    | "" -> []
    | t -> t::(get ())
  in
  let term_string = String.concat "\n" (get ()) in
  let env, metasenv, term, ugraph =
    List.nth (Disambiguate.Trivial.disambiguate_string dbd term_string) 0
  in
  term, metasenv, ugraph
;;

let _ =
  let module S = Saturation in
  let set_ratio v = S.weight_age_ratio := v; S.weight_age_counter := v
  and set_sel v = S.symbols_ratio := v; S.symbols_counter := v;
  and set_conf f = configuration_file := f
  and set_ordering o =
    match o with
    | "lpo" -> Utils.compare_terms := Utils.lpo
    | "kbo" -> Utils.compare_terms := Utils.kbo
    | "nr-kbo" -> Utils.compare_terms := Utils.nonrec_kbo
    | o -> raise (Arg.Bad ("Unknown term ordering: " ^ o))
  and set_fullred b = S.use_fullred := b
  and set_time_limit v = S.time_limit := float_of_int v
  in
  Arg.parse [
    "-f", Arg.Bool set_fullred,
    "Enable/disable full-reduction strategy (default: enabled)";
    
    "-r", Arg.Int set_ratio, "Weight-Age equality selection ratio (default: 4)";

    "-s", Arg.Int set_sel,
    "symbols-based selection ratio (relative to the weight ratio, default: 0)";

    "-c", Arg.String set_conf, "Configuration file (for the db connection)";

    "-o", Arg.String set_ordering,
    "Term ordering. Possible values are:\n" ^
      "\tkbo: Knuth-Bendix ordering\n" ^
      "\tnr-kbo: Non-recursive variant of kbo (default)\n" ^
      "\tlpo: Lexicographic path ordering";

    "-l", Arg.Int set_time_limit, "Time limit in seconds (default: no limit)";
  ] (fun a -> ()) "Usage:"
in
Helm_registry.load_from !configuration_file;
CicNotation.load_notation core_notation_script;
CicNotation.load_notation "../../matita/coq.moo";
let dbd = Mysql.quick_connect
  ~host:(Helm_registry.get "db.host")
  ~user:(Helm_registry.get "db.user")
  ~database:(Helm_registry.get "db.database")
  ()
in
let term, metasenv, ugraph = get_from_user ~dbd in
Saturation.main dbd term metasenv ugraph;;