(* Copyright (C) 2002, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

 let debug = false
 let debug_print s = if debug then prerr_endline (Lazy.force s)

(* let debug_print = fun _ -> () *)

(* Profiling code
let new_experimental_hint =
 let profile = CicUtil.profile "new_experimental_hint" in
 fun ~dbd ~facts ?signature ~universe status ->
  profile.profile (MetadataQuery.new_experimental_hint ~dbd ~facts ?signature ~universe) status
*) let new_experimental_hint = MetadataQuery.new_experimental_hint

(* In this versions of auto_tac we maintain an hash table of all inspected
   goals. We assume that the context is invariant for application. 
   To this aim, it is essential to sall hint_verbose, that in turns calls
   apply_verbose. *)

type exitus = 
    No of int 
  | Yes of Cic.term * int 
  | NotYetInspected
	
let inspected_goals = Hashtbl.create 503;;

let search_theorems_in_context status =
  let (proof, goal) = status in
  let module C = Cic in
  let module R = CicReduction in
  let module S = CicSubstitution in
  let module PET = ProofEngineTypes in 
  let module PT = PrimitiveTactics in 
  let _,metasenv,_,_ = proof in
  let _,context,ty = CicUtil.lookup_meta goal metasenv in
  let rec find n = function 
    | [] -> []
    | hd::tl ->
        let res =
          (* we should check that the hypothesys has not been cleared *)
          if List.nth context (n-1) = None then
            None
          else
            try
              let (subst,(proof, goal_list)) =
                PT.apply_tac_verbose ~term:(C.Rel n) status  
              in
              (* 
                 let goal_list =
                   List.stable_sort (compare_goal_list proof) goal_list in 
              *)
              Some (subst,(proof, goal_list))
            with 
             PET.Fail _ -> None 
        in
        (match res with
        | Some res -> res::(find (n+1) tl)
        | None -> find (n+1) tl)
  in
  try 
    find 1 context
  with Failure s -> []
;;     


let compare_goals proof goal1 goal2 =
  let _,metasenv,_,_ = proof in
  let (_, ey1, ty1) = CicUtil.lookup_meta goal1 metasenv in
  let (_, ey2, ty2) =  CicUtil.lookup_meta goal2 metasenv in
  let ty_sort1,_ = CicTypeChecker.type_of_aux' metasenv ey1 ty1 
		     CicUniv.empty_ugraph in
  let ty_sort2,_ = CicTypeChecker.type_of_aux' metasenv ey2 ty2 
		     CicUniv.empty_ugraph in
  let prop1 =
    let b,_ = CicReduction.are_convertible ey1 (Cic.Sort Cic.Prop) ty_sort1 
		CicUniv.empty_ugraph in
      if b then 0 else 1
  in
  let prop2 =
    let b,_ = CicReduction.are_convertible ey2 (Cic.Sort Cic.Prop) ty_sort2 
		CicUniv.empty_ugraph in
      if b then 0 else 1
  in
  prop1 - prop2


let new_search_theorems f dbd proof goal depth sign =
  let choices = f (proof,goal)
  in 
  List.map 
    (function (subst,(proof, goallist)) ->
       (* let goallist = reorder_goals dbd sign proof goallist in *)
        let goallist = List.sort (compare_goals proof) goallist in 
       (subst,(proof,(List.map (function g -> (g,depth)) goallist), sign)))
    choices 
;;

exception NoOtherChoices;;

let is_in_metasenv goal metasenv =
  try
    let (_, ey ,ty) =
      CicUtil.lookup_meta goal metasenv in
      true
  with CicUtil.Meta_not_found _ -> false 

let rec auto_single dbd proof goal ey ty depth width sign already_seen_goals
 universe
  =
  if depth = 0 then [] else
  if List.mem ty already_seen_goals then [] else
  let already_seen_goals = ty::already_seen_goals in
  let facts = (depth = 1) in  
  let _,metasenv,p,_ = proof in
    (* first of all we check if the goal has been already
       inspected *)
  assert (is_in_metasenv goal metasenv);
  let exitus =
    try Hashtbl.find inspected_goals ty
    with Not_found -> NotYetInspected in
  let is_meta_closed = CicUtil.is_meta_closed ty in
    begin
      match exitus with
	  Yes (bo,_) ->
            (*
              debug_print (lazy "ALREADY PROVED!!!!!!!!!!!!!!!!!!!!!!!!!!!!");
	      debug_print (lazy (CicPp.ppterm ty));
            *)
            let subst_in =
              (* if we just apply the subtitution, the type 
                 is irrelevant: we may use Implicit, since it will 
                 be dropped *)
	      CicMetaSubst.apply_subst 
	        [(goal,(ey, bo, Cic.Implicit None))] in
	    let (proof,_) = 
	      ProofEngineHelpers.subst_meta_and_metasenv_in_proof 
		proof goal subst_in metasenv in
	      [(subst_in,(proof,[],sign))]
        | No d when (d >= depth) -> 
	    (* debug_print (lazy "PRUNED!!!!!!!!!!!!!!!!!!!!!!!!!!!!"); *)
	    [] (* the empty list means no choices, i.e. failure *)
	| No _ 
	| NotYetInspected ->
	      debug_print (lazy ("CURRENT GOAL = " ^ CicPp.ppterm ty));
	      debug_print (lazy ("CURRENT PROOF = " ^ CicPp.ppterm p));
	      debug_print (lazy ("CURRENT HYP = " ^ CicPp.ppcontext ey));
	    let sign, new_sign =
	      if is_meta_closed then
		None, Some (MetadataConstraints.signature_of ty)
	      else sign,sign in (* maybe the union ? *)
	    let local_choices =
	      new_search_theorems 
		search_theorems_in_context dbd
		proof goal (depth-1) new_sign in
	    let global_choices =
	      new_search_theorems 
		(fun status -> 
		   List.map snd
		   (new_experimental_hint 
		      ~dbd ~facts:facts ?signature:sign ~universe status))
		dbd proof goal (depth-1) new_sign in 
	    let all_choices =
	      local_choices@global_choices in
	    let sorted_choices = 
	      List.stable_sort
		(fun (_, (_, goals1, _)) (_, (_, goals2, _)) ->
		   Pervasives.compare 
		   (List.length goals1) (List.length goals2))
		all_choices in 
	      (match (auto_new dbd width already_seen_goals universe sorted_choices) 
	       with
		   [] -> 
		     (* no proof has been found; we update the
			hastable *)
		     (* if is_meta_closed then *)
		       Hashtbl.add inspected_goals ty (No depth);
		     []
		 | (subst,(proof,[],sign))::tl1 -> 
		     (* a proof for goal has been found:
			in order to get the proof we apply subst to
			Meta[goal] *)
		     if is_meta_closed  then
		       begin 
			 let irl = 
			   CicMkImplicit.identity_relocation_list_for_metavariable ey in
			 let meta_proof = 
			   subst (Cic.Meta(goal,irl)) in
			   Hashtbl.add inspected_goals 
			     ty (Yes (meta_proof,depth));
(*
			   begin
			     let cty,_ = 
			       CicTypeChecker.type_of_aux' metasenv ey meta_proof CicUniv.empty_ugraph
			     in
			       if not (cty = ty) then
				 begin
				   debug_print (lazy ("ty =  "^CicPp.ppterm ty));
				   debug_print (lazy ("cty =  "^CicPp.ppterm cty));
				   assert false
				 end
				   Hashtbl.add inspected_goals 
				   ty (Yes (meta_proof,depth));
			   end;
*)
		       end;
		     (subst,(proof,[],sign))::tl1
		 | _ -> assert false)
    end
      
and auto_new dbd width already_seen_goals universe = function
  | [] -> []
  | (subst,(proof, goals, sign))::tl ->
      let _,metasenv,_,_ = proof in
      let is_in_metasenv (goal, _) =
        try
          let (_, ey ,ty) = CicUtil.lookup_meta goal metasenv in
          true
        with CicUtil.Meta_not_found _ -> false 
      in
      let goals'= List.filter is_in_metasenv goals in
    	auto_new_aux dbd 
        width already_seen_goals universe ((subst,(proof, goals', sign))::tl)

and auto_new_aux dbd width already_seen_goals universe = function
  | [] -> []
  | (subst,(proof, [], sign))::tl -> (subst,(proof, [], sign))::tl
  | (subst,(proof, (goal,0)::_, _))::tl -> 
      auto_new dbd width already_seen_goals universe tl
  | (subst,(proof, goals, _))::tl when 
      (List.length goals) > width -> 
      auto_new dbd width already_seen_goals universe tl 
  | (subst,(proof, (goal,depth)::gtl, sign))::tl -> 
      let _,metasenv,p,_ = proof in
      let (_, ey ,ty) = CicUtil.lookup_meta goal metasenv in
      match (auto_single dbd proof goal ey ty depth
	(width - (List.length gtl)) sign already_seen_goals) universe
      with
	  [] -> auto_new dbd width already_seen_goals universe tl 
	| (local_subst,(proof,[],sign))::tl1 -> 
	    let new_subst f t = f (subst t) in
	    let is_meta_closed = CicUtil.is_meta_closed ty in
	    let all_choices =
	      if is_meta_closed then 
		(new_subst local_subst,(proof,gtl,sign))::tl
	      else
		let tl2 = 
		  (List.map 
		     (function (f,(p,l,s)) -> (new_subst f,(p,l@gtl,s))) tl1)
		in			 
		  (new_subst local_subst,(proof,gtl,sign))::tl2@tl in
	      auto_new dbd width already_seen_goals universe all_choices
	| _ -> assert false
 ;; 

let default_depth = 5
let default_width = 3

(*
let auto_tac ?(depth=default_depth) ?(width=default_width) ~(dbd:HMysql.dbd)
  ()
=
  let auto_tac dbd (proof,goal) =
  let universe = MetadataQuery.signature_of_goal ~dbd (proof,goal) in
  Hashtbl.clear inspected_goals;
  debug_print (lazy "Entro in Auto");
  let id t = t in
  let t1 = Unix.gettimeofday () in
  match auto_new dbd width [] universe [id,(proof, [(goal,depth)],None)] with
      [] ->  debug_print (lazy "Auto failed");
	raise (ProofEngineTypes.Fail "No Applicable theorem")
    | (_,(proof,[],_))::_ ->
        let t2 = Unix.gettimeofday () in
	debug_print (lazy "AUTO_TAC HA FINITO");
	let _,_,p,_ = proof in
	debug_print (lazy (CicPp.ppterm p));
        Printf.printf "tempo: %.9f\n" (t2 -. t1);
	(proof,[])
    | _ -> assert false
  in
  ProofEngineTypes.mk_tactic (auto_tac dbd)
;;
*)

let paramodulation_tactic = ref
  (fun dbd ?full ?depth ?width status ->
     raise (ProofEngineTypes.Fail (lazy "Not Ready yet...")));;

let term_is_equality = ref
  (fun term -> debug_print (lazy "term_is_equality E` DUMMY!!!!"); false);;


let auto_tac ?(depth=default_depth) ?(width=default_width) ?paramodulation
    ?full ~(dbd:HMysql.dbd) () =
  let auto_tac dbd (proof, goal) =
    let normal_auto () = 
      let universe = MetadataQuery.signature_of_goal ~dbd (proof, goal) in
      Hashtbl.clear inspected_goals;
      debug_print (lazy "Entro in Auto");
      let id t = t in
      let t1 = Unix.gettimeofday () in
      match
        auto_new dbd width [] universe [id, (proof, [(goal, depth)], None)]
      with
        [] ->  debug_print(lazy "Auto failed");
	  raise (ProofEngineTypes.Fail (lazy "No Applicable theorem"))
      | (_,(proof,[],_))::_ ->
          let t2 = Unix.gettimeofday () in
	  debug_print (lazy "AUTO_TAC HA FINITO");
	  let _,_,p,_ = proof in
	  debug_print (lazy (CicPp.ppterm p));
          debug_print (lazy (Printf.sprintf "tempo: %.9f\n" (t2 -. t1)));
	  (proof,[])
      | _ -> assert false
    in
    let full = match full with None -> false | Some _ -> true in
    let paramodulation_ok =
      match paramodulation with
      | None -> false
      | Some _ ->
          let _, metasenv, _, _ = proof in
          let _, _, meta_goal = CicUtil.lookup_meta goal metasenv in
          full || (!term_is_equality meta_goal)
    in
    if paramodulation_ok then (
      debug_print (lazy "USO PARAMODULATION...");
(*       try *)
      !paramodulation_tactic dbd ~depth ~width ~full (proof, goal)
(*       with ProofEngineTypes.Fail _ -> *)
(*         normal_auto () *)
    ) else
      normal_auto () 
  in
  ProofEngineTypes.mk_tactic (auto_tac dbd)
;;