(* Copyright (C) 2002, HELM Team.
 *
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 *
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 *
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 *
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)
 

let rewrite_tac ~direction ~pattern equality =
 let rewrite_tac ~direction ~pattern:(wanted,hyps_pat,concl_pat) equality status
 =
  let module C = Cic in
  let module U = UriManager in
  let module PET = ProofEngineTypes in
  let module PER = ProofEngineReduction in
  let module PEH = ProofEngineHelpers in
  let module PT = PrimitiveTactics in
  let module HLO = HelmLibraryObjects in
  assert (wanted = None);   (* this should be checked syntactically *)
  assert (hyps_pat = []); (*CSC: not implemented yet! *)
  let proof,goal = status in
  let if_right_to_left a b = 
    match direction with
    | `RightToLeft -> a
    | `LeftToRight -> b
  in
  let curi, metasenv, pbo, pty = proof in
  let (metano,context,gty) as conjecture = CicUtil.lookup_meta goal metasenv in
  let eq_uri = HLO.Logic.eq_URI in
  let ty_eq,_ = 
    CicTypeChecker.type_of_aux' metasenv context equality 
      CicUniv.empty_ugraph
  in 
  let eq_ind, ty, t1, t2 =
    match ty_eq with
    | C.Appl [C.MutInd (uri, 0, []); ty; t1; t2] when U.eq uri eq_uri ->
        let eq_ind = 
          C.Const (if_right_to_left HLO.Logic.eq_ind_URI HLO.Logic.eq_ind_r_URI,[])
        in
        if_right_to_left (eq_ind, ty, t2, t1) (eq_ind, ty, t1, t2)
    | _ -> raise (PET.Fail "Rewrite: argument is not a proof of an equality") in
  (* now we always do as if direction was `LeftToRight *)
  let fresh_name = 
    FreshNamesGenerator.mk_fresh_name 
    ~subst:[] metasenv context C.Anonymous ~typ:ty in
  let lifted_t1 = CicSubstitution.lift 1 t1 in
  let lifted_gty = CicSubstitution.lift 1 gty in
  let lifted_conjecture =
    metano,(Some (fresh_name,Cic.Decl ty))::context,lifted_gty in
  let lifted_pattern = Some lifted_t1,[],CicSubstitution.lift 1 concl_pat in
  let _,selected_terms_with_context =
   ProofEngineHelpers.select
    ~metasenv ~conjecture:lifted_conjecture ~pattern:lifted_pattern in
  let what,with_what = 
   (* Note: Rel 1 does not live in the context context_of_t           *)
   (* The replace_lifting_csc_0 function will take care of lifting it *)
   (* to context_of_t                                                 *)
   List.fold_right
    (fun (context_of_t,t) (l1,l2) -> t::l1, Cic.Rel 1::l2)
    selected_terms_with_context ([],[]) in
  let abstr_gty =
   ProofEngineReduction.replace_lifting_csc 0
    ~equality:(==) ~what ~with_what:with_what ~where:lifted_gty in
  let gty' = CicSubstitution.subst t2 abstr_gty in
  let fresh_meta = ProofEngineHelpers.new_meta_of_proof proof in
  let irl = CicMkImplicit.identity_relocation_list_for_metavariable context in
  let metasenv' = (fresh_meta,context,gty')::metasenv in
  let pred = C.Lambda (fresh_name, ty, abstr_gty) in
  let exact_proof = 
    C.Appl [eq_ind ; ty ; t2 ; pred ; C.Meta (fresh_meta,irl) ; t1 ;equality]
  in
  let (proof',goals) =
    PET.apply_tactic 
      (PT.exact_tac ~term:exact_proof) ((curi,metasenv',pbo,pty),goal)
  in
  assert (List.length goals = 0) ;
  (proof',[fresh_meta])
 in
  ProofEngineTypes.mk_tactic (rewrite_tac ~direction ~pattern equality)
  
 
let rewrite_simpl_tac ~direction ~pattern equality =
 let rewrite_simpl_tac ~direction ~pattern equality status =
  ProofEngineTypes.apply_tactic
  (Tacticals.then_ 
   ~start:(rewrite_tac ~direction ~pattern equality)
   ~continuation:
     (ReductionTactics.simpl_tac
       ~pattern:(ProofEngineTypes.conclusion_pattern None)))
   status
 in
   ProofEngineTypes.mk_tactic (rewrite_simpl_tac ~direction ~pattern equality)
;;

let replace_tac ~pattern ~with_what =
 let replace_tac ~pattern:(wanted,hyps_pat,concl_pat) ~with_what status =
  let (proof, goal) = status in
  let module C = Cic in
  let module U = UriManager in
  let module P = PrimitiveTactics in
  let module T = Tacticals in
  let _,metasenv,_,_ = proof in
  let (_,context,_) as conjecture = CicUtil.lookup_meta goal metasenv in
  assert (hyps_pat = []); (*CSC: not implemented yet *)
  let context_len = List.length context in
  let _,selected_terms_with_context =
   ProofEngineHelpers.select ~metasenv ~conjecture ~pattern in
  let ty_of_with_what,u =
   CicTypeChecker.type_of_aux'
    metasenv context with_what CicUniv.empty_ugraph in
  let whats =
   match selected_terms_with_context with
      [] -> raise (ProofEngineTypes.Fail "Replace: no term selected")
    | l ->
      List.map
       (fun (context_of_t,t) ->
         let t_in_context =
          try
           let context_of_t_len = List.length context_of_t in
           if context_of_t_len = context_len then t
           else
            (let t_in_context,subst,metasenv' =
              CicMetaSubst.delift_rels [] metasenv
               (context_of_t_len - context_len) t
             in
              assert (subst = []);
              assert (metasenv = metasenv');
              t_in_context)
          with
           CicMetaSubst.DeliftingARelWouldCaptureAFreeVariable ->
            (*CSC: we could implement something stronger by completely changing
              the semantics of the tactic *)
            raise (ProofEngineTypes.Fail
             "Replace: one of the selected terms is not closed") in
         let ty_of_t_in_context,u = (* TASSI: FIXME *)
          CicTypeChecker.type_of_aux' metasenv context t_in_context
           CicUniv.empty_ugraph in
         let b,u = CicReduction.are_convertible ~metasenv context
          ty_of_with_what ty_of_t_in_context u in
         if b then t_in_context
         else
          raise
           (ProofEngineTypes.Fail
             "Replace: one of the selected terms and the term to be replaced with have not convertible types")
       ) l
  in
   let rec aux whats status =
    match whats with
       [] -> ProofEngineTypes.apply_tactic T.id_tac status
     | what::tl ->
        ProofEngineTypes.apply_tactic
          (T.thens
             ~start:(
               P.cut_tac 
                (C.Appl [
                  (C.MutInd (HelmLibraryObjects.Logic.eq_URI, 0, [])) ;
                  ty_of_with_what ; 
                  what ; 
                  with_what]))
             ~continuations:[            
               T.then_
                 ~start:(
                   rewrite_simpl_tac ~direction:`LeftToRight ~pattern (C.Rel 1))
                  ~continuation:(
                    let hyp =
                     try
                      match List.hd context with
                         Some (Cic.Name name,_) -> name
                       | _ -> assert false
                     with (Failure "hd") -> assert false
                    in
                     ProofEngineStructuralRules.clear ~hyp) ;
               aux_tac tl])
          status
   and aux_tac tl = ProofEngineTypes.mk_tactic (aux tl) in
    aux whats status
 in
   ProofEngineTypes.mk_tactic (replace_tac ~pattern ~with_what)
;;


(* All these tacs do is applying the right constructor/theorem *)

let reflexivity_tac =
  IntroductionTactics.constructor_tac ~n:1
;;

let symmetry_tac =
 let symmetry_tac (proof, goal) =
  let module C = Cic in
  let module R = CicReduction in
  let module U = UriManager in
   let (_,metasenv,_,_) = proof in
    let metano,context,ty = CicUtil.lookup_meta goal metasenv in
     match (R.whd context ty) with
        (C.Appl [(C.MutInd (uri, 0, [])); _; _; _])
	 when (U.eq uri HelmLibraryObjects.Logic.eq_URI) ->
	  ProofEngineTypes.apply_tactic 
           (PrimitiveTactics.apply_tac 
	    ~term: (C.Const (HelmLibraryObjects.Logic.sym_eq_URI, []))) 
	   (proof,goal)

      | _ -> raise (ProofEngineTypes.Fail "Symmetry failed")
 in
  ProofEngineTypes.mk_tactic symmetry_tac
;;

let transitivity_tac ~term =
 let transitivity_tac ~term status =
  let (proof, goal) = status in
  let module C = Cic in
  let module R = CicReduction in
  let module U = UriManager in
  let module T = Tacticals in
   let (_,metasenv,_,_) = proof in
    let metano,context,ty = CicUtil.lookup_meta goal metasenv in
     match (R.whd context ty) with
        (C.Appl [(C.MutInd (uri, 0, [])); _; _; _]) 
	when (uri = HelmLibraryObjects.Logic.eq_URI) ->
         ProofEngineTypes.apply_tactic 
	 (T.thens
          ~start:(PrimitiveTactics.apply_tac
            ~term: (C.Const (HelmLibraryObjects.Logic.trans_eq_URI, [])))
          ~continuations:
            [PrimitiveTactics.exact_tac ~term ; T.id_tac ; T.id_tac])
          status

      | _ -> raise (ProofEngineTypes.Fail "Transitivity failed")
 in
  ProofEngineTypes.mk_tactic (transitivity_tac ~term)
;;