(* Copyright (C) 2002, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

open ProofEngineHelpers
open ProofEngineTypes

exception TheTypeOfTheCurrentGoalIsAMetaICannotChooseTheRightElimiantionPrinciple
exception NotAnInductiveTypeToEliminate
exception WrongUriToVariable of string

(* lambda_abstract newmeta ty *)
(* returns a triple [bo],[context],[ty'] where              *)
(* [ty] = Pi/LetIn [context].[ty'] ([context] is a vector!) *)
(* and [bo] = Lambda/LetIn [context].(Meta [newmeta])       *)
(* So, lambda_abstract is the core of the implementation of *)
(* the Intros tactic.                                       *)
(* howmany = -1 means Intros, howmany > 0 means Intros n    *)
let lambda_abstract ?(howmany=(-1)) metasenv context newmeta ty mk_fresh_name =
 let module C = Cic in
  let rec collect_context context howmany ty =
   match howmany with
   | 0 ->  
        let irl =
          CicMkImplicit.identity_relocation_list_for_metavariable context
        in
         context, ty, (C.Meta (newmeta,irl))
   | _ -> 
      match ty with 
        C.Cast (te,_)   -> collect_context context howmany te 
      | C.Prod (n,s,t)  ->
         let n' = mk_fresh_name metasenv context n ~typ:s in
          let (context',ty,bo) =
           collect_context ((Some (n',(C.Decl s)))::context) (howmany - 1) t 
          in
           (context',ty,C.Lambda(n',s,bo))
      | C.LetIn (n,s,t) ->
         let (context',ty,bo) =
          collect_context ((Some (n,(C.Def (s,None))))::context) (howmany - 1) t
         in
          (context',ty,C.LetIn(n,s,bo))
      | _ as t ->
        if howmany <= 0 then
         let irl =
          CicMkImplicit.identity_relocation_list_for_metavariable context
         in
          context, t, (C.Meta (newmeta,irl))
        else
         raise (Fail (lazy "intro(s): not enough products or let-ins"))
  in
   collect_context context howmany ty 

let eta_expand metasenv context t arg =
 let module T = CicTypeChecker in
 let module S = CicSubstitution in
 let module C = Cic in
  let rec aux n =
   function
      t' when t' = S.lift n arg -> C.Rel (1 + n)
    | C.Rel m  -> if m <= n then C.Rel m else C.Rel (m+1)
    | C.Var (uri,exp_named_subst) ->
       let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
        C.Var (uri,exp_named_subst')
    | C.Meta (i,l) ->
       let l' =
        List.map (function None -> None | Some t -> Some (aux n t)) l
       in
        C.Meta (i, l')
    | C.Sort _
    | C.Implicit _ as t -> t
    | C.Cast (te,ty) -> C.Cast (aux n te, aux n ty)
    | C.Prod (nn,s,t) -> C.Prod (nn, aux n s, aux (n+1) t)
    | C.Lambda (nn,s,t) -> C.Lambda (nn, aux n s, aux (n+1) t)
    | C.LetIn (nn,s,t) -> C.LetIn (nn, aux n s, aux (n+1) t)
    | C.Appl l -> C.Appl (List.map (aux n) l)
    | C.Const (uri,exp_named_subst) ->
       let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
        C.Const (uri,exp_named_subst')
    | C.MutInd (uri,i,exp_named_subst) ->
       let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
        C.MutInd (uri,i,exp_named_subst')
    | C.MutConstruct (uri,i,j,exp_named_subst) ->
       let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
        C.MutConstruct (uri,i,j,exp_named_subst')
    | C.MutCase (sp,i,outt,t,pl) ->
       C.MutCase (sp,i,aux n outt, aux n t,
        List.map (aux n) pl)
    | C.Fix (i,fl) ->
       let tylen = List.length fl in
        let substitutedfl =
         List.map
          (fun (name,i,ty,bo) -> (name, i, aux n ty, aux (n+tylen) bo))
           fl
        in
         C.Fix (i, substitutedfl)
    | C.CoFix (i,fl) ->
       let tylen = List.length fl in
        let substitutedfl =
         List.map
          (fun (name,ty,bo) -> (name, aux n ty, aux (n+tylen) bo))
           fl
        in
         C.CoFix (i, substitutedfl)
  and aux_exp_named_subst n =
   List.map (function uri,t -> uri,aux n t)
  in
   let argty,_ = 
    T.type_of_aux' metasenv context arg CicUniv.empty_ugraph (* TASSI: FIXME *)
   in
    let fresh_name =
     FreshNamesGenerator.mk_fresh_name ~subst:[]
      metasenv context (Cic.Name "Heta") ~typ:argty
    in
     (C.Appl [C.Lambda (fresh_name,argty,aux 0 t) ; arg])

(*CSC: ma serve solamente la prima delle new_uninst e l'unione delle due!!! *)
let classify_metas newmeta in_subst_domain subst_in metasenv =
 List.fold_right
  (fun (i,canonical_context,ty) (old_uninst,new_uninst) ->
    if in_subst_domain i then
     old_uninst,new_uninst
    else
     let ty' = subst_in canonical_context ty in
      let canonical_context' =
       List.fold_right
        (fun entry canonical_context' ->
          let entry' =
           match entry with
              Some (n,Cic.Decl s) ->
               Some (n,Cic.Decl (subst_in canonical_context' s))
            | Some (n,Cic.Def (s,None)) ->
               Some (n,Cic.Def ((subst_in canonical_context' s),None))
            | None -> None
            | Some (n,Cic.Def (bo,Some ty)) ->
               Some
                (n,
                  Cic.Def
                   (subst_in canonical_context' bo,
                    Some (subst_in canonical_context' ty)))
          in
           entry'::canonical_context'
        ) canonical_context []
     in
      if i < newmeta then
       ((i,canonical_context',ty')::old_uninst),new_uninst
      else
       old_uninst,((i,canonical_context',ty')::new_uninst)
  ) metasenv ([],[])

(* Useful only inside apply_tac *)
let
 generalize_exp_named_subst_with_fresh_metas context newmeta uri exp_named_subst
=
 let module C = Cic in
  let params =
    let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
    CicUtil.params_of_obj o
  in
   let exp_named_subst_diff,new_fresh_meta,newmetasenvfragment,exp_named_subst'=
    let next_fresh_meta = ref newmeta in
    let newmetasenvfragment = ref [] in
    let exp_named_subst_diff = ref [] in
     let rec aux =
      function
         [],[] -> []
       | uri::tl,[] ->
          let ty =
            let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
              match o with
                  C.Variable (_,_,ty,_,_) ->
                    CicSubstitution.subst_vars !exp_named_subst_diff ty
                | _ -> raise (WrongUriToVariable (UriManager.string_of_uri uri))
          in
(* CSC: patch to generate ?1 : ?2 : Type in place of ?1 : Type to simulate ?1 :< Type
           (match ty with
               C.Sort (C.Type _) as s -> (* TASSI: ?? *)
                 let fresh_meta = !next_fresh_meta in
                 let fresh_meta' = fresh_meta + 1 in
                  next_fresh_meta := !next_fresh_meta + 2 ;
                  let subst_item = uri,C.Meta (fresh_meta',[]) in
                   newmetasenvfragment :=
                    (fresh_meta,[],C.Sort (C.Type (CicUniv.fresh()))) ::
                     (* TASSI: ?? *)
                     (fresh_meta',[],C.Meta (fresh_meta,[])) :: !newmetasenvfragment ;
                   exp_named_subst_diff := !exp_named_subst_diff @ [subst_item] ;
                   subst_item::(aux (tl,[]))
             | _ ->
*)
              let irl =
                CicMkImplicit.identity_relocation_list_for_metavariable context
              in
              let subst_item = uri,C.Meta (!next_fresh_meta,irl) in
               newmetasenvfragment :=
                (!next_fresh_meta,context,ty)::!newmetasenvfragment ;
               exp_named_subst_diff := !exp_named_subst_diff @ [subst_item] ;
               incr next_fresh_meta ;
               subst_item::(aux (tl,[]))(*)*)
       | uri::tl1,((uri',_) as s)::tl2 ->
          assert (UriManager.eq uri uri') ;
          s::(aux (tl1,tl2))
       | [],_ -> assert false
     in
      let exp_named_subst' = aux (params,exp_named_subst) in
       !exp_named_subst_diff,!next_fresh_meta,
        List.rev !newmetasenvfragment, exp_named_subst'
   in
    new_fresh_meta,newmetasenvfragment,exp_named_subst',exp_named_subst_diff
;;

let new_metasenv_and_unify_and_t newmeta' metasenv' context term' ty termty goal_arity =
  let (consthead,newmetasenv,arguments,_) =
   saturate_term newmeta' metasenv' context termty goal_arity in
  let subst,newmetasenv',_ = 
   CicUnification.fo_unif newmetasenv context consthead ty CicUniv.empty_ugraph
  in
  let t = 
    if List.length arguments = 0 then term' else Cic.Appl (term'::arguments)
  in
  subst,newmetasenv',t

let rec count_prods context ty =
 match CicReduction.whd context ty with
    Cic.Prod (n,s,t) -> 1 + count_prods (Some (n,Cic.Decl s)::context) t
  | _ -> 0

let apply_tac_verbose_with_subst ~term (proof, goal) =
  (* Assumption: The term "term" must be closed in the current context *)
 let module T = CicTypeChecker in
 let module R = CicReduction in
 let module C = Cic in
  let (_,metasenv,_,_) = proof in
  let metano,context,ty = CicUtil.lookup_meta goal metasenv in
  let newmeta = new_meta_of_proof ~proof in
   let exp_named_subst_diff,newmeta',newmetasenvfragment,term' =
    match term with
       C.Var (uri,exp_named_subst) ->
        let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
         generalize_exp_named_subst_with_fresh_metas context newmeta uri
          exp_named_subst
        in
         exp_named_subst_diff,newmeta',newmetasenvfragment,
          C.Var (uri,exp_named_subst')
     | C.Const (uri,exp_named_subst) ->
        let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
         generalize_exp_named_subst_with_fresh_metas context newmeta uri
          exp_named_subst
        in
         exp_named_subst_diff,newmeta',newmetasenvfragment,
          C.Const (uri,exp_named_subst')
     | C.MutInd (uri,tyno,exp_named_subst) ->
        let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
         generalize_exp_named_subst_with_fresh_metas context newmeta uri
          exp_named_subst
        in
         exp_named_subst_diff,newmeta',newmetasenvfragment,
          C.MutInd (uri,tyno,exp_named_subst')
     | C.MutConstruct (uri,tyno,consno,exp_named_subst) ->
        let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
         generalize_exp_named_subst_with_fresh_metas context newmeta uri
          exp_named_subst
        in
         exp_named_subst_diff,newmeta',newmetasenvfragment,
          C.MutConstruct (uri,tyno,consno,exp_named_subst')
     | _ -> [],newmeta,[],term
   in
   let metasenv' = metasenv@newmetasenvfragment in
   let termty,_ = 
     CicTypeChecker.type_of_aux' metasenv' context term' CicUniv.empty_ugraph
   in
   let termty =
     CicSubstitution.subst_vars exp_named_subst_diff termty in
   let goal_arity = count_prods context ty in
   let subst,newmetasenv',t = 
    let rec add_one_argument n =
     try
      new_metasenv_and_unify_and_t newmeta' metasenv' context term' ty
        termty n
     with CicUnification.UnificationFailure _ when n > 0 ->
      add_one_argument (n - 1)
    in
     add_one_argument goal_arity
   in
   let in_subst_domain i = List.exists (function (j,_) -> i=j) subst in
   let apply_subst = CicMetaSubst.apply_subst subst in
   let old_uninstantiatedmetas,new_uninstantiatedmetas =
     (* subst_in doesn't need the context. Hence the underscore. *)
     let subst_in _ = CicMetaSubst.apply_subst subst in
     classify_metas newmeta in_subst_domain subst_in newmetasenv'
   in
   let bo' = apply_subst t in
   let newmetasenv'' = new_uninstantiatedmetas@old_uninstantiatedmetas in
   let subst_in =
     (* if we just apply the subtitution, the type is irrelevant:
              we may use Implicit, since it will be dropped *)
     CicMetaSubst.apply_subst ((metano,(context,bo',Cic.Implicit None))::subst)
   in
   let (newproof, newmetasenv''') = 
     subst_meta_and_metasenv_in_proof proof metano subst_in newmetasenv''
   in
   (((metano,(context,bo',Cic.Implicit None))::subst)(* subst_in *), (* ALB *)
    (newproof, 
     List.map (function (i,_,_) -> i) new_uninstantiatedmetas))


(* ALB *)
let apply_tac_verbose_with_subst ~term status =
  try
(*     apply_tac_verbose ~term status *)
    apply_tac_verbose_with_subst ~term status
      (* TODO cacciare anche altre eccezioni? *)
  with 
  | CicUnification.UnificationFailure msg
  | CicTypeChecker.TypeCheckerFailure msg ->
      raise (Fail msg)

(* ALB *)
let apply_tac_verbose ~term status =
  let subst, status = apply_tac_verbose_with_subst ~term status in
  (CicMetaSubst.apply_subst subst), status

let apply_tac ~term status = snd (apply_tac_verbose ~term status)

  (* TODO per implementare i tatticali e' necessario che tutte le tattiche
  sollevino _solamente_ Fail *)
let apply_tac ~term =
 let apply_tac ~term status =
  try
    apply_tac ~term status
      (* TODO cacciare anche altre eccezioni? *)
  with 
  | CicUnification.UnificationFailure msg
  | CicTypeChecker.TypeCheckerFailure msg ->
      raise (Fail msg)
 in
  mk_tactic (apply_tac ~term)

let intros_tac ?howmany ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[]) ()=
 let intros_tac
  ?(mk_fresh_name_callback = (FreshNamesGenerator.mk_fresh_name ~subst:[])) ()
  (proof, goal)
 =
  let module C = Cic in
  let module R = CicReduction in
   let (_,metasenv,_,_) = proof in
   let metano,context,ty = CicUtil.lookup_meta goal metasenv in
    let newmeta = new_meta_of_proof ~proof in
     let (context',ty',bo') =
      lambda_abstract ?howmany metasenv context newmeta ty mk_fresh_name_callback
     in
      let (newproof, _) =
        subst_meta_in_proof proof metano bo' [newmeta,context',ty']
      in
       (newproof, [newmeta])
 in
  mk_tactic (intros_tac ~mk_fresh_name_callback ())
  
let cut_tac ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[]) term =
 let cut_tac
  ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
  term (proof, goal)
 =
  let module C = Cic in
   let curi,metasenv,pbo,pty = proof in
   let metano,context,ty = CicUtil.lookup_meta goal metasenv in
    let newmeta1 = new_meta_of_proof ~proof in
    let newmeta2 = newmeta1 + 1 in
    let fresh_name =
     mk_fresh_name_callback metasenv context (Cic.Name "Hcut") ~typ:term in
    let context_for_newmeta1 =
     (Some (fresh_name,C.Decl term))::context in
    let irl1 =
     CicMkImplicit.identity_relocation_list_for_metavariable
      context_for_newmeta1
    in
    let irl2 =
      CicMkImplicit.identity_relocation_list_for_metavariable context
    in
     let newmeta1ty = CicSubstitution.lift 1 ty in
     let bo' =
      C.Appl
       [C.Lambda (fresh_name,term,C.Meta (newmeta1,irl1)) ;
        C.Meta (newmeta2,irl2)]
     in
      let (newproof, _) =
       subst_meta_in_proof proof metano bo'
        [newmeta2,context,term; newmeta1,context_for_newmeta1,newmeta1ty];
      in
       (newproof, [newmeta1 ; newmeta2])
 in
  mk_tactic (cut_tac ~mk_fresh_name_callback term)

let letin_tac ?(mk_fresh_name_callback=FreshNamesGenerator.mk_fresh_name ~subst:[]) term =
 let letin_tac
  ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
  term (proof, goal)
 =
  let module C = Cic in
   let curi,metasenv,pbo,pty = proof in
   let metano,context,ty = CicUtil.lookup_meta goal metasenv in
    let _,_ = (* TASSI: FIXME *)
      CicTypeChecker.type_of_aux' metasenv context term CicUniv.empty_ugraph in
     let newmeta = new_meta_of_proof ~proof in
     let fresh_name =
      mk_fresh_name_callback metasenv context (Cic.Name "Hletin") ~typ:term in
     let context_for_newmeta =
      (Some (fresh_name,C.Def (term,None)))::context in
     let irl =
      CicMkImplicit.identity_relocation_list_for_metavariable
       context_for_newmeta
     in
      let newmetaty = CicSubstitution.lift 1 ty in
      let bo' = C.LetIn (fresh_name,term,C.Meta (newmeta,irl)) in
       let (newproof, _) =
         subst_meta_in_proof
           proof metano bo'[newmeta,context_for_newmeta,newmetaty]
       in
        (newproof, [newmeta])
 in
  mk_tactic (letin_tac ~mk_fresh_name_callback term)

  (** functional part of the "exact" tactic *)
let exact_tac ~term =
 let exact_tac ~term (proof, goal) =
  (* Assumption: the term bo must be closed in the current context *)
  let (_,metasenv,_,_) = proof in
  let metano,context,ty = CicUtil.lookup_meta goal metasenv in
  let module T = CicTypeChecker in
  let module R = CicReduction in
  let ty_term,u = T.type_of_aux' metasenv context term CicUniv.empty_ugraph in
  let b,_ = R.are_convertible context ty_term ty u in (* TASSI: FIXME *)
  if b then
   begin
    let (newproof, metasenv') =
      subst_meta_in_proof proof metano term [] in
    (newproof, [])
   end
  else
   raise (Fail (lazy "The type of the provided term is not the one expected."))
 in
  mk_tactic (exact_tac ~term)

(* not really "primitive" tactics .... *)
let elim_tac ~term = 
 let elim_tac ~term (proof, goal) =
  let module T = CicTypeChecker in
  let module U = UriManager in
  let module R = CicReduction in
  let module C = Cic in
   let (curi,metasenv,proofbo,proofty) = proof in
   let metano,context,ty = CicUtil.lookup_meta goal metasenv in
    let termty,_ = T.type_of_aux' metasenv context term CicUniv.empty_ugraph in
    let (termty,metasenv',arguments,fresh_meta) =
     ProofEngineHelpers.saturate_term
      (ProofEngineHelpers.new_meta_of_proof proof) metasenv context termty 0 in
    let term = if arguments = [] then term else Cic.Appl (term::arguments) in
    let uri,exp_named_subst,typeno,args =
     match termty with
        C.MutInd (uri,typeno,exp_named_subst) -> (uri,exp_named_subst,typeno,[])
      | C.Appl ((C.MutInd (uri,typeno,exp_named_subst))::args) ->
          (uri,exp_named_subst,typeno,args)
      | _ -> raise NotAnInductiveTypeToEliminate
    in
     let eliminator_uri =
      let buri = U.buri_of_uri uri in
      let name = 
        let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
       match o with
          C.InductiveDefinition (tys,_,_,_) ->
           let (name,_,_,_) = List.nth tys typeno in
            name
        | _ -> assert false
      in
      let ty_ty,_ = T.type_of_aux' metasenv' context ty CicUniv.empty_ugraph in
      let ext =
       match ty_ty with
          C.Sort C.Prop -> "_ind"
        | C.Sort C.Set  -> "_rec"
        | C.Sort C.CProp -> "_rec"
        | C.Sort (C.Type _)-> "_rect" 
        | C.Meta (_,_) -> raise TheTypeOfTheCurrentGoalIsAMetaICannotChooseTheRightElimiantionPrinciple
        | _ -> assert false
      in
       U.uri_of_string (buri ^ "/" ^ name ^ ext ^ ".con")
     in
      let eliminator_ref = C.Const (eliminator_uri,exp_named_subst) in
       let ety,_ = 
         T.type_of_aux' metasenv' context eliminator_ref CicUniv.empty_ugraph in
        let rec find_args_no =
         function
            C.Prod (_,_,t) -> 1 + find_args_no t
          | C.Cast (s,_) -> find_args_no s
          | C.LetIn (_,_,t) -> 0 + find_args_no t
          | _ -> 0
        in
         let args_no = find_args_no ety in
         let term_to_refine =
          let rec make_tl base_case =
           function
              0 -> [base_case]
            | n -> (C.Implicit None)::(make_tl base_case (n - 1))
          in
           C.Appl (eliminator_ref :: make_tl term (args_no - 1))
         in
          let refined_term,_,metasenv'',_ = 
           CicRefine.type_of_aux' metasenv' context term_to_refine
             CicUniv.empty_ugraph
          in
           let new_goals =
            ProofEngineHelpers.compare_metasenvs
             ~oldmetasenv:metasenv ~newmetasenv:metasenv''
           in
           let proof' = curi,metasenv'',proofbo,proofty in
            let proof'', new_goals' =
             apply_tactic (apply_tac ~term:refined_term) (proof',goal)
            in
             (* The apply_tactic can have closed some of the new_goals *)
             let patched_new_goals =
              let (_,metasenv''',_,_) = proof'' in
               List.filter
                (function i -> List.exists (function (j,_,_) -> j=i) metasenv'''
                ) new_goals @ new_goals'
             in
              proof'', patched_new_goals
 in
  mk_tactic (elim_tac ~term)
;;

let elim_intros_tac ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[]) 
                    ?depth ?using what =
 Tacticals.then_ ~start:(elim_tac ~term:what)
  ~continuation:(intros_tac ~mk_fresh_name_callback ?howmany:depth ())
;;

(* The simplification is performed only on the conclusion *)
let elim_intros_simpl_tac ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
                          ?depth ?using what =
 Tacticals.then_ ~start:(elim_tac ~term:what)
  ~continuation:
   (Tacticals.thens
     ~start:(intros_tac ~mk_fresh_name_callback ?howmany:depth ())
     ~continuations:
       [ReductionTactics.simpl_tac
         ~pattern:(ProofEngineTypes.conclusion_pattern None)])
;;