(* Copyright (C) 2002, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)


(* TODO se ce n'e' piu' di una, prende la prima che trova... sarebbe meglio
chiedere: find dovrebbe restituire una lista di hyp (?) da passare all'utonto con una
funzione di callback che restituisce la (sola) hyp da applicare *)

let assumption_tac =
 let module PET = ProofEngineTypes in
 let assumption_tac status =
  let (proof, goal) = status in
  let module C = Cic in
  let module R = CicReduction in
  let module S = CicSubstitution in
  let module PT = PrimitiveTactics in
  let _,metasenv,_,_ = proof in
  let _,context,ty = CicUtil.lookup_meta goal metasenv in
  let rec find n = function 
      hd::tl -> 
        (match hd with
             (Some (_, C.Decl t)) when
               fst (R.are_convertible context (S.lift n t) ty 
		       CicUniv.empty_ugraph) -> n
           | (Some (_, C.Def (_,Some ty'))) when
               fst (R.are_convertible context (S.lift n ty') ty
                       CicUniv.empty_ugraph) -> n
           | (Some (_, C.Def (t,None))) ->
	       let ty_t, u = (* TASSI: FIXME *)
		 CicTypeChecker.type_of_aux' metasenv context (S.lift n t) 
		   CicUniv.empty_ugraph in
	       let b,_ = R.are_convertible context ty_t ty u in
		 if b then n else find (n+1) tl
           | _ -> find (n+1) tl
         )
      | [] -> raise (PET.Fail "Assumption: No such assumption")
     in PET.apply_tactic (PT.apply_tac ~term:(C.Rel (find 1 context))) status
 in
  PET.mk_tactic assumption_tac
;;

(* ANCORA DA DEBUGGARE *)

exception AllSelectedTermsMustBeConvertible;;
exception CannotGeneralizeInHypotheses;;

(* serve una funzione che cerchi nel ty dal basso a partire da term, i lambda
e li aggiunga nel context, poi si conta la lunghezza di questo nuovo
contesto e si lifta di tot... COSA SIGNIFICA TUTTO CIO'?????? *)

let generalize_tac 
 ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
 ~term pattern
 =
  let module PET = ProofEngineTypes in
  let generalize_tac mk_fresh_name_callback ~term (hyps_pat,concl_pat) status =
   if hyps_pat <> [] then raise CannotGeneralizeInHypotheses ;
   let (proof, goal) = status in
   let module C = Cic in
   let module P = PrimitiveTactics in
   let module T = Tacticals in
    let _,metasenv,_,_ = proof in
    let _,context,ty = CicUtil.lookup_meta goal metasenv in
    let terms =
     let path =
      match concl_pat with
         None -> Cic.Implicit (Some `Hole)
       | Some path -> path in
     let roots = ProofEngineHelpers.select ~term:ty ~pattern:path in
      List.fold_left
       (fun acc (i, r) -> 
         ProofEngineHelpers.find_subterms
          ~eq:ProofEngineReduction.alpha_equivalence ~wanted:term r @ acc
       ) [] roots
    in
     let typ =
      let typ,u =
       CicTypeChecker.type_of_aux' metasenv context term CicUniv.empty_ugraph in
      (* We need to check that all the convertibility of all the terms *)
      ignore (
       (* TASSI: FIXME *)
       List.fold_left
        (fun u t ->
          let b,u1 = CicReduction.are_convertible context term t u in 
           if not b then 
            raise AllSelectedTermsMustBeConvertible
           else
            u1
        ) u terms) ;
       typ
     in
      PET.apply_tactic 
      (T.thens 
       ~start:
         (P.cut_tac 
          (C.Prod(
            (mk_fresh_name_callback metasenv context C.Anonymous ~typ:typ), 
            typ,
            (ProofEngineReduction.replace_lifting_csc 1
              ~equality:(==) 
              ~what:terms
              ~with_what:(List.map (function _ -> C.Rel 1) terms)
              ~where:ty)
          )))
       ~continuations:
         [(P.apply_tac ~term:(C.Appl [C.Rel 1; CicSubstitution.lift 1 term])) ;
           T.id_tac])
       status
 in
  PET.mk_tactic (generalize_tac mk_fresh_name_callback ~term pattern)
;;

let set_goal n =
  ProofEngineTypes.mk_tactic
    (fun (proof, goal) ->
       let (_, metasenv, _, _) = proof in
       if CicUtil.exists_meta n metasenv then
         (proof, [n])
       else
         raise (ProofEngineTypes.Fail ("no such meta: " ^ string_of_int n)))