(* Copyright (C) 2000, HELM Team.
 * 
 * This file is part of HELM, an Hypertextual, Electronic
 * Library of Mathematics, developed at the Computer Science
 * Department, University of Bologna, Italy.
 * 
 * HELM is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 * 
 * HELM is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HELM; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
 * MA  02111-1307, USA.
 * 
 * For details, see the HELM World-Wide-Web page,
 * http://cs.unibo.it/helm/.
 *)

(*
 * "cic:/a/b/c.con" => ("cic:/a/b/c.con", id )
 * "cic:/a/b/c.ind#xpointer(1/1)" => ("cic:/a/b/c.con#xpointer(1/1)", id)
 * "cic:/a/b/c.ind#xpointer(1/1/1)" => ("cic:/a/b/c.con#xpointer(1/1/1)", id)
 *)

let fresh_id =
 let id = ref 0 in
  function () ->
    incr id;
    !id

(* (uriwithxpointer, uniqueid) 
 * where uniqueid is used to build a set of uri *)
type uri = string * int;;

let eq uri1 uri2 =
  uri1 == uri2 
;;

let string_of_uri (uri,_) =
 uri

let name_of_uri (uri, _) = 
  let xpointer_offset = 
    try String.rindex uri '#' with Not_found -> String.length uri - 1
  in
  let index1 = String.rindex_from uri xpointer_offset '/' + 1 in
  let index2 = String.rindex uri '.' in
  String.sub uri index1 (index2 - index1)
  
let buri_of_uri (uri,_) = 
  let index = String.rindex uri '/' in
  String.sub uri 0 index

module OrderedStrings =
 struct
  type t = string
  let compare (s1 : t) (s2 : t) = compare s1 s2
 end
;;

module MapStringsToUri = Map.Make(OrderedStrings);;

(* Invariant: the map is the identity function,
 *  i.e. 
 *    let str' = (MapStringsToUri.find str !set_of_uri) in
 *    str' == (MapStringsToUri.find str' !set_of_uri)
 *)
let set_of_uri = ref MapStringsToUri.empty;;

(* hash conses an uri *)
let uri_of_string suri =
  try
    MapStringsToUri.find suri !set_of_uri
  with Not_found -> 
    let new_uri = suri, fresh_id () in
    set_of_uri := MapStringsToUri.add suri new_uri !set_of_uri;
    new_uri

exception IllFormedUri of string;;

let strip_xpointer ((uri,_) as olduri) =
  try 
    let index = String.rindex uri '#' in
    let no_xpointer = String.sub uri 0 index in
    uri_of_string no_xpointer
  with
    Not_found -> olduri

let clear_suffix uri ?(pat2="") pat1 =
  try
    let index = String.rindex uri '.' in
    let index' = index + 1 in 
    let suffix = String.sub uri index' (String.length uri - index') in
    if pat1 = suffix || pat2 = suffix then
      String.sub uri 0 index
    else
      uri
  with
    Not_found -> assert false

let has_suffix uri pat =
  try
    let index = String.rindex uri '.' + 1 in
    let suffix = String.sub uri index (String.length uri - index) in
    pat = suffix 
  with
    Not_found -> assert false

let _types = "types"
let _dottypes = ".types"
let _ann = "ann"
let _dotann = ".ann"
let _var = "var"
let _dotbody = ".body"
let _con = "con"
let _xpointer = "#xpointer(1/"
 
let cicuri_of_uri (uri, _) = uri_of_string (clear_suffix uri ~pat2:_types _ann)

let annuri_of_uri (uri , _) = uri_of_string ((clear_suffix uri _ann) ^ _dotann)

let uri_is_annuri (uri, _) = has_suffix uri _ann

let uri_is_var (uri, _) = has_suffix uri _var

let uri_is_con (uri, _) = has_suffix uri _con

let bodyuri_of_uri (uri, _) =
  if has_suffix uri _con then
    Some (uri_of_string (uri ^ _dotbody))
  else
    None
;;

let innertypesuri_of_uri (uri, _) =
  uri_of_string ((clear_suffix uri _types) ^ _dottypes)
;;

let uri_of_uriref (uri, _) typeno consno =
  let typeno = typeno + 1 in
  let suri =
    match consno with
    | None -> Printf.sprintf "%s%s%d)" uri _xpointer typeno
    | Some n -> Printf.sprintf "%s%s%d/%d)" uri _xpointer typeno n
  in
  uri_of_string suri

let compare (_,id1) (_,id2) = id1 - id2

module OrderedUri =
struct
  type t = uri
  let compare = compare (* the one above, not Pervasives.compare *)
end

module UriSet = Set.Make (OrderedUri)