(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module U  = NUri
module C  = Cps
module W  = Share
module L  = Log
module E  = Entity
module H  = Hierarchy
module S  = Status
module Z  = Bag
module ZO = BagOutput
module ZE = BagEnvironment
module ZR = BagReduction

exception TypeError of Z.message

(* Internal functions *******************************************************)

let level = 4

let log1 s c t =
   let sc, st = s ^ " in the envireonment", "the term" in
   L.log ZO.specs level (L.et_items1 sc c st t)

let error1 st c t =
   let sc = "In the envireonment" in
   raise (TypeError (L.et_items1 sc c st t))

let error3 c t1 t2 t3 =
   let sc, st1, st2, st3 = 
      "In the envireonment", "the term", "is of type", "but must be of type"
   in
   raise (TypeError (L.et_items3 sc c st1 t1 st2 t2 st3 t3))

let mk_gref u l =
   let map t v = Z.Appl (v, t) in
   List.fold_left map (Z.GRef u) l

(* Interface functions ******************************************************)

let rec b_type_of f st c x = 
(*   L.warn "Entering T.b_type_of"; *)
   log1 "Now checking" c x;
   match x with
   | Z.Sort h                    ->
      let h = H.apply h in f x (Z.Sort h) 
   | Z.LRef i                    ->
      let err () = error1 "variable not found" c x in
      let f _ = function
         | Z.Abst w               -> f x w
	 | Z.Abbr (Z.Cast (w, v)) -> f x w
	 | Z.Abbr _               -> assert false
	 | Z.Void                 -> error1 "reference to excluded variable" c x	 
      in
      Z.get err f c i
   | Z.GRef uri                  ->
      let f = function
         | _, _, E.Abst (_, w)          -> f x w
	 | _, _, E.Abbr (Z.Cast (w, v)) -> f x w
	 | _, _, E.Abbr _               -> assert false
	 | _, _, E.Void                 -> assert false
      in
      ZE.get_entity f uri   
   | Z.Bind (a, l, Z.Abbr v, t) ->
      let f xv xt tt =
         f (W.sh2 v xv t xt x (Z.bind_abbr a l)) (Z.bind_abbr a l xv tt)
      in
      let f xv cc = b_type_of (f xv) st cc t in
      let f xv = Z.push "type abbr" (f xv) c a l (Z.Abbr xv) in
      let f xv vv = match xv with 
	 | Z.Cast _ -> f xv
         | _        -> f (Z.Cast (vv, xv))
      in
      type_of f st c v
   | Z.Bind (a, l, Z.Abst u, t) ->
      let f xu xt tt =
	 f (W.sh2 u xu t xt x (Z.bind_abst a l)) (Z.bind_abst a l xu tt)
      in
      let f xu cc = b_type_of (f xu) st cc t in
      let f xu _ = Z.push "type abst" (f xu) c a l (Z.Abst xu) in
      type_of f st c u
   | Z.Bind (a, l, Z.Void, t)   ->
      let f xt tt = 
         f (W.sh1 t xt x (Z.bind a l Z.Void)) (Z.bind a l Z.Void tt)
      in
      let f cc = b_type_of f st cc t in
      Z.push "type void" f c a l Z.Void   
   | Z.Appl (v, t)            ->
      let f xv vv xt tt = function
	 | ZR.Abst w                             -> 
            L.box (succ level);
	    L.log ZO.specs (succ level) (L.t_items1 "Just scanned" c w);
	    L.unbox (succ level);
	    let f a =                
(*	       L.warn (Printf.sprintf "Convertible: %b" a); *)
	       if a then f (W.sh2 v xv t xt x Z.appl) (Z.appl xv tt)
	       else error3 c xv vv w
	    in
	    ZR.are_convertible f ~si:st.S.si c w vv
	 | _                                    -> 
	    error1 "not a function" c xt
      in
      let f xv vv xt tt = ZR.ho_whd (f xv vv xt tt) c tt in
      let f xv vv = b_type_of (f xv vv) st c t in
      type_of f st c v
   | Z.Cast (u, t)            ->
      let f xu xt tt a =  
         (* L.warn (Printf.sprintf "Convertible: %b" a); *)
	 if a then f (W.sh2 u xu t xt x Z.cast) xu else error3 c xt tt xu
      in
      let f xu xt tt = ZR.are_convertible (f xu xt tt) ~si:st.S.si c xu tt in
      let f xu _ = b_type_of (f xu) st c t in
      type_of f st c u

and type_of f st c x =
   let f t u = L.unbox level; f t u in
   L.box level; b_type_of f st c x