(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

(* kernel version: basic, relative, global *)
(* note          : ufficial basic \lambda\delta version 3 *) 

module N = Layer
module E = Entity

type uri = E.uri
type n_attrs = E.node_attrs
type b_attrs = E.bind_attrs

(* x-reduced abstractions are output by RTM only *)
type bind = Void                          (*                         *)
          | Abst of bool * N.layer * term (* x-reduced?, layer, type *)
          | Abbr of term                  (* body                    *)

and term = Sort of int                    (* hierarchy index *)
         | LRef of n_attrs * int          (* attrs, position index *)
         | GRef of n_attrs * uri          (* attrs, reference *)
         | Cast of term * term            (* type, term *)
         | Appl of bool * term * term     (* extended?, argument, function *)
         | Bind of b_attrs * bind * term  (* attrs, binder, scope *)

type entity = term E.entity (* attrs, uri, binder *)

type lenv = Null
(* Cons: tail, relative local environment, attrs, binder *) 
          | Cons of lenv * lenv * n_attrs * b_attrs * bind 

type manager = (N.status -> entity -> bool) * (unit -> unit)

(* Currified constructors ***************************************************)

let abst r n w = Abst (r, n, w)

let abbr v = Abbr v

let lref a i = LRef (a, i)

let gref a u = GRef (a, u)

let cast u t = Cast (u, t)

let appl x u t = Appl (x, u, t)

let bind y b t = Bind (y, b, t)

let bind_abst r n y u t = Bind (y, Abst (r, n, u), t)

let bind_abbr y u t = Bind (y, Abbr u, t)

let bind_void y t = Bind (y, Void, t)

(* local environment handling functions *************************************)

let empty = Null

let push e c a y b = Cons (e, c, a, y, b)

let rec get e i = match e with
   | Null                            -> empty, empty, E.empty_node, E.empty_bind, Void
   | Cons (e, c, a, y, b) when i = 0 -> e, c, a, y, b
   | Cons (e, _, _, _, _)            -> get e (pred i)

(* used in BrgOutput.pp_lenv *)
let rec fold_right f map e x = match e with   
   | Null                 -> f x
   | Cons (e, c, a, y, b) -> fold_right (map f c a y b) map e x

let rec mem err f e y0 = match e with
   | Null                 -> err ()
   | Cons (e, _, _, y, _) ->
      if y.E.b_name = y0.E.b_name then f () else mem err f e y0