(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module C = Cps
module E = Entity
module J = Marks
module N = Level
module D = Crg
module B = Brg

(* internal functions: crg to brg term **************************************)

let rec xlate_term f = function
   | D.TSort (a, l)     -> f (B.Sort (a, l))
   | D.TGRef (a, n)     -> f (B.GRef (a, n))
   | D.TLRef (a, _, _)  -> let f i = f (B.LRef (a, i)) in E.apix C.err f a
   | D.TCast (a, u, t)  ->
      let f tt uu = f (B.Cast (a, uu, tt)) in
      let f tt = xlate_term (f tt) u in
      xlate_term f t 
   | D.TAppl (a, vs, t) ->
      let map f v tt = let f vv = f (B.Appl (a, vv, tt)) in xlate_term f v in
      let f tt = C.list_fold_right f map vs tt in
      xlate_term f t
   | D.TProj (_, e, t)  -> 
      xlate_term f (D.tshift e t)
   | D.TBind (a, b, t)  ->
      let f tt = f (xlate_bind tt a b) in xlate_term f t

and xlate_bind x a b =
   let f a ns = a, ns in
   let a, ns = E.get_names f a in 
   match b with
      | D.Abst (m, ws) ->
         let map x n w = 
	    let f ww = B.Bind (n :: J.new_mark () :: a, B.Abst (m, ww), x) in 
	    xlate_term f w
	 in
	 List.fold_left2 map x ns ws 
      | D.Abbr vs      ->
         let map x n v = 
	    let f vv = B.Bind (n :: a, B.Abbr vv, x) in 
	    xlate_term f v
	 in
	 List.fold_left2 map x ns vs
      | D.Void _       ->
         let map x n = B.Bind (n :: a, B.Void, x) in
	 List.fold_left map x ns

(* internal functions: brg to crg term **************************************)

let rec xlate_bk_term f = function
   | B.Sort (a, l)     -> f (D.TSort (a, l))
   | B.GRef (a, n)     -> f (D.TGRef (a, n))
   | B.LRef (a, i)     -> f (D.TLRef (a, i, 0))
   | B.Cast (a, u, t)  ->
      let f tt uu = f (D.TCast (a, uu, tt)) in
      let f tt = xlate_bk_term (f tt) u in
      xlate_bk_term f t 
   | B.Appl (a, u, t)  ->
      let f tt uu = f (D.TAppl (a, [uu], tt)) in
      let f tt = xlate_bk_term (f tt) u in
      xlate_bk_term f t 
   | B.Bind (a, b, t)  ->
      let f tt bb = f (D.TBind (a, bb, tt)) in
      let f tt = xlate_bk_bind (f tt) b in
      xlate_bk_term f t 

and xlate_bk_bind f = function
   | B.Abst (n, t) ->
      let f tt = f (D.Abst (n, [tt])) in
      xlate_bk_term f t
   | B.Abbr t      ->
      let f tt = f (D.Abbr [tt]) in
      xlate_bk_term f t
   | B.Void        -> f (D.Void 1)
   
(* interface functions ******************************************************)

let brg_of_crg f t = f (xlate_term C.start t)

let crg_of_brg = xlate_bk_term