(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module P = Printf

module U = NUri
module C = Cps
module G = Options
module N = Level
module E = Entity
module B = Brg

(* Internal functions *******************************************************)

let ok = ref true

let width = 70

let out_preamble och =
   let ich = open_in !G.ma_preamble in
   let rec aux () = P.fprintf och "%s\n" (input_line ich); aux () in
   try aux () with End_of_file -> close_in ich

let out_top_comment och msg =
   let padding = width - String.length msg in
   let padding = if padding >= 0 then padding else 0 in
   P.fprintf och "(* %s %s*)\n\n" msg (String.make padding '*')

let out_comment och msg =
   P.fprintf och "(* %s *)\n" msg 

let out_include och src =
   P.fprintf och "include \"%s.ma\".\n\n" src

let out_uri och u =
   let str = U.string_of_uri u in
   let rec aux i =
     let c = str.[i] in
     if c = '.' then () else begin 
        output_char och (if c = '/' then '_' else c);
        aux (succ i)
     end
   in
   let rec strip i n = 
      if n <= 0 then succ i else
      strip (String.index_from str (succ i) '/') (pred n)
   in
   aux (strip 0 3)

let rename f e a = f a

let out_name och a =
   let f n = function 
      | true  -> P.fprintf och "%s" n
      | false -> C.err ()
   in
   E.name C.err f a

let rec out_term st p e och = function
   | B.Sort (_, h)           -> 
      let sort = if h = 0 then "Type[0]" else if h = 1 then "Prop" else assert false in
      P.fprintf och "%s" sort
   | B.LRef (_, i)           ->       
      let _, _, a, b = B.get e i in
      P.fprintf och "%a" out_name a
   | B.GRef (_, s)           ->
      P.fprintf och "%a" out_uri s
   | B.Cast (_, u, t)        ->
      P.fprintf och "(%a : %a)" (out_term st false e) t (out_term st false e) u 
   | B.Appl (_, v, t)        ->
      let pt = match t with B.Appl _ -> false | _ -> true in
      let op, cp = if p then "(", ")" else "", "" in
      P.fprintf och "%s%a %a%s" op (out_term st pt e) t (out_term st true e) v cp
   | B.Bind (a, B.Abst (n, w), t) ->
      let op, cp = if p then "(", ")" else "", "" in
      let f a =
         let ee = B.push e B.empty a (B.abst n w) in
	 let binder = match N.to_string st n with
            | "1" -> "Π"
            | "2" -> "λ"
            | _   -> ok := false; "?"
         in
         P.fprintf och "%s%s%a:%a.%a%s"
            op binder out_name a (out_term st false e) w (out_term st false ee) t cp
      in
      rename f e a
   | B.Bind (a, B.Abbr v, t) ->
      let op, cp = if p then "(", ")" else "", "" in
      let f a = 
         let ee = B.push e B.empty a (B.abbr v) in
	 P.fprintf och "%slet %a ≝ %a in %a%s"
            op out_name a (out_term st false e) v (out_term st false ee) t cp
      in
      rename f e a
   | B.Bind (a, B.Void, t)   -> C.err ()

(* Interface functions ******************************************************)

let open_out fname =
   let och = open_out (fname ^ ".ma") in
   out_preamble och;
   out_top_comment och (P.sprintf "This file is generated by %s: do not edit" G.version_string);
   out_include och "basics/pts";
   och

let output_entity st och (_, na, s, b) =
   let f i =
      out_comment och (P.sprintf "notion %u" i);
      match b with
         | E.Abbr t ->
            P.fprintf och "definition %a ≝ %a.\n\n%!" out_uri s (out_term st false B.empty) t; !ok
         | E.Abst t ->
            P.fprintf och "axiom %a : %a.\n\n%!" out_uri s (out_term st false B.empty) t; !ok
         | E.Void   -> C.err ()
   in
   E.apix C.err f na

let close_out och = close_out och