(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module P  = Printf

module U  = NUri
module C  = Cps
module L  = Log
module G  = Options
module H  = Hierarchy
module N  = Level
module E  = Entity
module XD = XmlCrg
module B  = Brg
module BD = BrgCrg

(* nodes count **************************************************************)

type counters = {
   eabsts: int;
   eabbrs: int;
   evoids: int;
   tsorts: int;
   tlrefs: int;
   tgrefs: int;
   tcasts: int;
   tappls: int;
   tabsts: int;
   tabbrs: int;
   tvoids: int;
   uris  : B.uri list;
   nodes : int;
   xnodes: int
}

let level = 2

let initial_counters = {
   eabsts = 0; eabbrs = 0; evoids = 0; 
   tsorts = 0; tlrefs = 0; tgrefs = 0; tcasts = 0; tappls = 0;
   tabsts = 0; tabbrs = 0; tvoids = 0;
   uris = []; nodes = 0; xnodes = 0
}

let rec count_term_binder f c e = function
   | B.Abst (_, w) ->
      let c = {c with tabsts = succ c.tabsts; nodes = succ c.nodes} in
      count_term f c e w
   | B.Abbr v      -> 
      let c = {c with tabbrs = succ c.tabbrs; xnodes = succ c.xnodes} in
      count_term f c e v
   | B.Void        ->
      let c = {c with tvoids = succ c.tvoids; xnodes = succ c.xnodes} in   
      f c

and count_term f c e = function
   | B.Sort _         -> 
      f {c with tsorts = succ c.tsorts; nodes = succ c.nodes}
   | B.LRef (_, i)    -> 
      begin match B.get e i with
	 | _, _, _, B.Abst _
	 | _, _, _, B.Void   ->
	    f {c with tlrefs = succ c.tlrefs; nodes = succ c.nodes}
	 | _, _, _, B.Abbr _ ->
	    f {c with tlrefs = succ c.tlrefs; xnodes = succ c.xnodes}
      end      
   | B.GRef (_, u)    -> 
      let c =    
	 if Cps.list_mem ~eq:U.eq u c.uris
	 then {c with nodes = succ c.nodes}
	 else {c with xnodes = succ c.xnodes}
      in
      f {c with tgrefs = succ c.tgrefs}
   | B.Cast (_, v, t) -> 
      let c = {c with tcasts = succ c.tcasts} in
      let f c = count_term f c e t in
      count_term f c e v
   | B.Appl (_, v, t) -> 
      let c = {c with tappls = succ c.tappls; nodes = succ c.nodes} in
      let f c = count_term f c e t in
      count_term f c e v
   | B.Bind (a, b, t) -> 
      let f c = count_term f c (B.push e B.empty a b) t in
      count_term_binder f c e b

let count_entity f c = function
   | _, _, u, E.Abst w -> 
      let c = {c with
         eabsts = succ c.eabsts; nodes = succ c.nodes; uris = u :: c.uris
      } in
      count_term f c B.empty w
   | _, _, _, E.Abbr v ->  
      let c = {c with eabbrs = succ c.eabbrs; xnodes = succ c.xnodes} in
      count_term f c B.empty v
   | _, _, _, E.Void   -> assert false

let print_counters f c =
   let terms =
      c.tsorts + c.tgrefs + c.tgrefs + c.tcasts + c.tappls + c.tabsts +
      c.tabbrs
   in
   let items = c.eabsts + c.eabbrs in
   let nodes = c.nodes + c.xnodes in
   L.warn level (P.sprintf "Kernel representation summary (basic_rg)");
   L.warn level (P.sprintf "  Total entry items:        %7u" items);
   L.warn level (P.sprintf "    Declaration items:      %7u" c.eabsts);
   L.warn level (P.sprintf "    Definition items:       %7u" c.eabbrs);
   L.warn level (P.sprintf "  Total term items:         %7u" terms);
   L.warn level (P.sprintf "    Sort items:             %7u" c.tsorts);
   L.warn level (P.sprintf "    Local reference items:  %7u" c.tlrefs);
   L.warn level (P.sprintf "    Global reference items: %7u" c.tgrefs);
   L.warn level (P.sprintf "    Explicit Cast items:    %7u" c.tcasts);
   L.warn level (P.sprintf "    Application items:      %7u" c.tappls);
   L.warn level (P.sprintf "    Abstraction items:      %7u" c.tabsts);
   L.warn level (P.sprintf "    Abbreviation items:     %7u" c.tabbrs);
   L.warn level (P.sprintf "  Global Int. Complexity:   %7u" c.nodes);
   L.warn level (P.sprintf "    + Abbreviation nodes:   %7u" nodes);
   f ()

(* supplementary annotation *************************************************)

let rec does_not_occur f n r = function
   | B.Null              -> f true
   | B.Cons (e, _, a, _) ->
      let f n1 r1 =
         if n1 = n && r1 = r then f false else does_not_occur f n r e
      in
      E.name C.err f a 

let rename f e a =
   let rec aux f e n r =
      let f = function
         | true  -> f n r
	 | false -> aux f e (n ^ "_") r
      in
      does_not_occur f n r e
   in
   let f n0 r0 =
      let f n r = if n = n0 && r = r0 then f a else f {a with E.n_name = Some (n, r)} in
      aux f e n0 r0 
   in
   E.name C.err f a

(* lenv/term pretty printing ************************************************)

let name err och a =
   let f n = function 
      | true  -> P.fprintf och "%s" n
      | false -> P.fprintf och "-%s" n
   in      
   E.name err f a

let pp_level st och n =
   P.fprintf och "%s" (N.to_string st n)

let rec pp_term st e och = function
   | B.Sort (_, h)           -> 
      let err _ = P.fprintf och "*%u" h in
      let f s = P.fprintf och "%s" s in
      H.string_of_sort err f h 
   | B.LRef (_, i)           -> 
      let err _ = P.fprintf och "#%u" i in
      if !G.indexes then err () else      
      let _, _, a, b = B.get e i in
      P.fprintf och "%a" (name err) a
   | B.GRef (_, s)           ->
      P.fprintf och "$%s" (U.string_of_uri s)
   | B.Cast (_, u, t)        ->
      P.fprintf och "{%a}.%a" (pp_term st e) u (pp_term st e) t
   | B.Appl (_, v, t)        ->
      P.fprintf och "(%a).%a" (pp_term st e) v (pp_term st e) t
   | B.Bind (a, B.Abst (n, w), t) ->
      let f a =
         let ee = B.push e B.empty a (B.abst n w) in
	 P.fprintf och "%a[%a:%a].%a" (pp_level st) n (name C.err) a (pp_term st e) w (pp_term st ee) t
      in
      rename f e a
   | B.Bind (a, B.Abbr v, t) ->
      let f a = 
         let ee = B.push e B.empty a (B.abbr v) in
	 P.fprintf och "[%a=%a].%a" (name C.err) a (pp_term st e) v (pp_term st ee) t
      in
      rename f e a
   | B.Bind (a, B.Void, t)   ->
      let f a = 
         let ee = B.push e B.empty a B.Void in
         P.fprintf och "[%a].%a" (name C.err) a (pp_term st ee) t
      in
      rename f e a

let pp_lenv st och e =
   let pp_entry f e c a b x = f x (* match b with
      | B.Abst (a, w) -> 
         let f a = P.fprintf och "%a : %a\n" (name C.err) a (pp_term st e) w; f a in
         rename f x a
      | B.Abbr (a, v) -> 
         let f a = P.fprintf och "%a = %a\n" (name C.err) a (pp_term st e) v; f a in
	 rename f c a
      | B.Void a      -> 
         let f a = P.fprintf och "%a\n" (name C.err) a; f a in
	 rename f c a
*)   in
   let e = B.empty in
   if e = B.empty then P.fprintf och "%s\n" "not shown" else
   B.fold_right ignore pp_entry e B.empty

let specs = {
   L.pp_term = pp_term; L.pp_lenv = pp_lenv
}

(* term xml printing ********************************************************)

let export_term st =
   BD.crg_of_brg (XD.export_term st)