(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module U  = NUri
module C  = Cps
module S  = Share
module L  = Log
module G  = Options
module H  = Hierarchy
module N  = Layer
module E  = Entity
module B  = Brg
module BE = BrgEnvironment
module BS = BrgSubstitution
module BR = BrgReduction

IFDEF TYPE THEN

(* Internal functions *******************************************************)

let level = 4

let message1 st1 m t1 =
   L.et_items1 "In the environment" m st1 t1

let log1 st s m t =
   let s =  s ^ " the term" in
   L.log st BR.specs (pred level) (message1 s m t) 

let error1 err s m t =
   err (message1 s m t)

let message3 m t1 t2 ?mu t3 =    
   let sm, st1, st2 = "In the environment", "the term", "is of type" in
   match mu with
      | Some mu ->
         let smu, st3 = "but in the environment", "it must be of type" in
         L.et_items3 sm m st1 t1 st2 t2 ~sc3:smu ~c3:mu st3 t3
      | None    ->
         let st3 = "but it must be of type" in
         L.et_items3 sm m st1 t1 st2 t2 st3 t3
   
let error3 err m t1 t2 ?mu t3 =
   err (message3 m t1 t2 ?mu t3)

let zero = Some 0

let assert_convertibility err f st m u w v =
   if BR.are_convertible st m zero u m zero w then f () else
   error3 err m v w u

let assert_applicability err f st m a u w v =
   let mode = if a.E.a_rest then zero else None in
   match BR.xwhd st m mode u with 
      | _, B.Sort _                            ->
         error1 err "not a function type" m u
      | mu, B.Bind (_, B.Abst (true, n, u), _) -> 
         if !G.cc && not (N.assert_not_zero st n) then error1 err "not a function type" m u else 
         if BR.are_convertible st mu zero u m zero w then f () else
	 error3 err m v w ~mu u
      | _                                      -> assert false (**)

let rec b_type_of err f st m z =
IFDEF TRACE THEN
   if !G.ct >= level then log1 st "Now checking" m z
ELSE () END;
   match z with
   | B.Sort k                        ->
      let k = H.apply k in f z (B.Sort k) 
   | B.LRef (_, i)                   ->
      begin match BR.get m i with
         | B.Abst (_, _, w)       ->
	    f z (BS.lift (succ i) (0) w)
	 | B.Abbr (B.Cast (w, _)) -> 
	    f z (BS.lift (succ i) (0) w)
	 | B.Abbr _               -> assert false
	 | B.Void                 -> 
	    error1 err "reference to excluded variable" m z
      end
   | B.GRef (_, u)                   ->
      begin match BE.get_entity u with
         | _, _, _, E.Abst (_, w)             -> f z w
	 | _, _, _, E.Abbr (_, B.Cast (w, _)) -> f z w
	 | _, _, _, E.Abbr _                  -> assert false
	 | _, _, _, E.Void                    ->
            error1 err "reference to unknown entry" m z
      end
   | B.Bind (y, B.Abbr v, t)         ->
      let f rv rt tt =
         f (S.sh2 v rv t rt z (B.bind_abbr y)) (B.bind_abbr y rv tt)
      in
      let f rv m = b_type_of err (f rv) st m t in
      let f rv = f rv (BR.push m y (B.abbr rv)) in
      let f rv vv = match rv with 
	 | B.Cast _ -> f rv
         | _        -> f (B.Cast (vv, rv))
      in
      type_of err f st m v
   | B.Bind (y, B.Abst (r, n, u), t) ->
      let f ru rt tt =
	 f (S.sh2 u ru t rt z (B.bind_abst r n y)) (B.bind_abst r (N.minus st n 1) y ru tt)
      in
      let f ru m = b_type_of err (f ru) st m t in
      let f ru _ = f ru (BR.push m y (B.abst r n ru)) in
      type_of err f st m u
   | B.Bind (y, B.Void, t)           ->
      let f rt tt = 
         f (S.sh1 t rt z (B.bind_void y)) (B.bind_void y tt)
      in
      b_type_of err f st (BR.push m y B.Void) t
   | B.Appl (a, v, t)                ->
      let f rv vv rt tt = 
         let f _ = f (S.sh2 v rv t rt z (B.appl a)) (B.appl a rv tt) in
         assert_applicability err f st m a tt vv rv
      in
      let f rv vv = b_type_of err (f rv vv) st m t in
      type_of err f st m v
   | B.Cast (u, t)                   ->
      let f ru rt tt =  
	 let f _ = f (S.sh2 u ru t rt z (B.cast)) ru in
         assert_convertibility err f st m ru tt rt
      in
      let f ru _ = b_type_of err (f ru) st m t in
      type_of err f st m u

(* Interface functions ******************************************************)

and type_of err f st m t = b_type_of err f st m t

END