(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module U  = NUri
module C  = Cps
module S  = Share
module L  = Log
module G  = Options
module H  = Hierarchy
module N  = Layer
module E  = Entity
module B  = Brg
module BE = BrgEnvironment
module BS = BrgSubstitution
module BR = BrgReduction

(* Internal functions *******************************************************)

let level = 4

let message1 st1 m t1 =
   L.et_items1 "In the environment" m st1 t1

let log1 st s m t =
   let s =  s ^ " the term" in
   L.log st BR.specs (pred level) (message1 s m t) 

let error1 err s m t =
   err (message1 s m t)

let message3 m t1 t2 ?mu t3 =    
   let sm, st1, st2 = "In the environment", "the term", "is of type" in
   match mu with
      | Some mu ->
         let smu, st3 = "but in the environment", "it must be of type" in
         L.et_items3 sm m st1 t1 st2 t2 ~sc3:smu ~c3:mu st3 t3
      | None    ->
         let st3 = "but it must be of type" in
         L.et_items3 sm m st1 t1 st2 t2 st3 t3
   
let error3 err m t1 t2 ?mu t3 =
   err (message3 m t1 t2 ?mu t3)

let zero = Some 0

let assert_convertibility err f st m u w v =
   if BR.are_convertible st m zero u m zero w then f () else
   error3 err m v w u

let assert_applicability err f st m x u w v =
   let mode = if x then None else zero in
   match BR.xwhd st m mode u with 
      | _, B.Sort _                            ->
         error1 err "not a function type" m u
      | mu, B.Bind (_, B.Abst (true, n, u), _) -> 
         if !G.cc && not (N.assert_not_zero st n) then error1 err "not a function type" m u else 
         if BR.are_convertible st mu zero u m zero w then f () else
	 error3 err m v w ~mu u
      | _                                      -> assert false (**)

let rec b_type_of err f st m y =
   if !G.ct >= level then log1 st "Now checking" m y;
   match y with
   | B.Sort (a, h)                   ->
      let h = H.apply h in f y (B.Sort (a, h)) 
   | B.LRef (_, i)                   ->
      begin match BR.get m i with
         | B.Abst (_, _, w)          ->
	    f y (BS.lift (succ i) (0) w)
	 | B.Abbr (B.Cast (_, w, _)) -> 
	    f y (BS.lift (succ i) (0) w)
	 | B.Abbr _                  -> assert false
	 | B.Void                    -> 
	    error1 err "reference to excluded variable" m y
      end
   | B.GRef (_, uri)                 ->
      begin match BE.get_entity uri with
         | _, _, _, E.Abst w                  -> f y w
	 | _, _, _, E.Abbr (B.Cast (_, w, _)) -> f y w
	 | _, _, _, E.Abbr _                  -> assert false
	 | _, _, _, E.Void                    ->
            error1 err "reference to unknown entry" m y
      end
   | B.Bind (a, B.Abbr v, t)         ->
      let f rv rt tt =
         f (S.sh2 v rv t rt y (B.bind_abbr a)) (B.bind_abbr a rv tt)
      in
      let f rv m = b_type_of err (f rv) st m t in
      let f rv = f rv (BR.push m a (B.abbr rv)) in
      let f rv vv = match rv with 
	 | B.Cast _ -> f rv
         | _        -> f (B.Cast (E.empty_node, vv, rv))
      in
      type_of err f st m v
   | B.Bind (a, B.Abst (r, n, u), t) ->
      let f ru rt tt =
	 f (S.sh2 u ru t rt y (B.bind_abst r n a)) (B.bind_abst r (N.minus st n 1) a ru tt)
      in
      let f ru m = b_type_of err (f ru) st m t in
      let f ru _ = f ru (BR.push m a (B.abst r n ru)) in
      type_of err f st m u
   | B.Bind (a, B.Void, t)           ->
      let f rt tt = 
         f (S.sh1 t rt y (B.bind_void a)) (B.bind_void a tt)
      in
      b_type_of err f st (BR.push m a B.Void) t
   | B.Appl (a, x, v, t)             ->
      let f rv vv rt tt = 
         let f _ = f (S.sh2 v rv t rt y (B.appl a x)) (B.appl a x rv tt) in
         assert_applicability err f st m x tt vv rv
      in
      let f rv vv = b_type_of err (f rv vv) st m t in
      type_of err f st m v
   | B.Cast (a, u, t)                ->
      let f ru rt tt =  
	 let f _ = f (S.sh2 u ru t rt y (B.cast a)) ru in
         assert_convertibility err f st m ru tt rt
      in
      let f ru _ = b_type_of err (f ru) st m t in
      type_of err f st m u

(* Interface functions ******************************************************)

and type_of err f st m t = b_type_of err f st m t