(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

(* kernel version: complete, relative, global *)
(* note          : fragment of complete \lambda\delta serving as abstract layer *) 

module C = Cps
module N = Layer
module E = Entity

type uri = E.uri
type id = E.id
type n_attrs = E.node_attrs
type a_attrs = E.appl_attrs
type b_attrs = E.bind_attrs


type bind = Abst of bool * N.layer * term           (* x-reduced?, layer, type *)
          | Abbr of term                            (* body *)
          | Void                                    (* *)

and term = TSort of int                             (* hierarchy index *)
         | TLRef of n_attrs * int                   (* attrs, position indexe *)
         | TGRef of n_attrs * uri                   (* attrs, reference *)
         | TCast of term * term                     (* domain, element *)
         | TAppl of a_attrs * term * term           (* attrs, argument, function *)
	 | TBind of b_attrs * bind * term           (* attrs, binder, scope *)
	 | TProj of lenv * term                     (* closure, member *)

and lenv = ESort                                    (* top *)
         | EBind of lenv * n_attrs * b_attrs * bind (* environment, attrs, binder *)
         | EAppl of lenv * a_attrs * term           (* environment, attrs, argument *)
         | EProj of lenv * lenv                     (* environment, closure *)

type entity = term E.entity

(* helpers ******************************************************************)

let empty_lenv = ESort

let push_bind f a y b lenv = f (EBind (lenv, a, y, b))

let push_appl f a t lenv = f (EAppl (lenv, a, t))

let push_proj f e lenv = f (EProj (lenv, e))

let add_bind f y b t = f (TBind (y, b, t))

let add_appl f a v t = f (TAppl (a, v, t))

let add_proj f e t = f (TProj (e, t))

let rec shift f c t = match c with
   | ESort              -> f t
   | EBind (e, _, a, b) -> add_bind (shift f e) a b t
   | EAppl (e, a, v)    -> add_appl (shift f e) a v t
   | EProj (e, d)       -> add_proj (shift f e) d t

let rec append f c = function
   | ESort              -> f c
   | EBind (e, y, a, b) -> append (push_bind f y a b) c e
   | EAppl (e, a, t)    -> append (push_appl f a t) c e
   | EProj (e, d)       -> append (push_proj f d) c e

let resolve_lref err f id lenv =
   let rec aux i = function
     | ESort                -> err ()
     | EAppl (tl, _, _)     -> aux i tl
     | EBind (tl, y, a, _)  ->
        let f id0 _ = if id0 = id then f y a i else aux (succ i) tl in
        let err () = aux (succ i) tl in
        E.name err f a
     | EProj (tl, d)        -> append (aux i) tl d
   in
   aux 0 lenv

let rec get_name err f i = function
   | ESort                         -> err i
   | EAppl (tl, _, _)              -> get_name err f i tl
   | EBind (_, _, a, _) when i = 0 -> 
      let err () = err i in
      E.name err f a
   | EBind (tl, _, _, _)           -> get_name err f (pred i) tl
   | EProj (tl, e)                 ->
      let err i = get_name err f i tl in 
      get_name err f i e

let rec get e i = match e with 
   | ESort                         -> ESort, E.empty_node, E.empty_bind, Void
   | EBind (e, y, a, b) when i = 0 -> e, y, a, b
   | EBind (e, _, _, _)            -> get e (pred i)
   | EAppl (e, _, _)               -> get e i
   | EProj (e, d)                  -> get (append C.start e d) i

let rec sub_list_strict f e l = match e, l with
   | _, []                            -> f e
   | EBind (e, _, _, Abst _), _ :: tl -> sub_list_strict f e tl
   | _                                -> assert false

let rec fold_names f map x = function
   | ESort                                     -> f x
   | EBind (e, _, {E.b_name = Some n}, Abst _) -> fold_names f map (map x n) e
   | _                                         -> assert false

let rec mem err f e a0 = match e with
   | ESort              -> err ()
   | EBind (e, _, a, _) ->
      if a.E.b_name = a0.E.b_name then f () else mem err f e a0
   | EAppl (e, _, _)    -> mem err f e a0
   | EProj (e, d)       -> 
      let err () = mem err f e a0 in mem err f d a0

let set_layer f n0 e =
   let rec aux f = function
      | ESort                           -> f ESort
      | EBind (e, y, a, Abst (r, n, w)) -> aux (push_bind f y a (Abst (r, n0, w))) e
      | EBind (e, y, a, b)              -> aux (push_bind f y a b) e
      | EAppl (e, a, v)                 -> aux (push_appl f a v) e
      | EProj (e, d)                    -> let f d = aux (push_proj f d) e in aux f d
   in
   aux f e

let set_attrs f a0 e =
   let rec aux f = function
      | ESort              -> f ESort
      | EBind (e, y, a, b) -> 
         let a = E.compose a a0 in
         aux (push_bind f y a b) e
      | EAppl (e, a, v)    ->
         aux (push_appl f a v) e
      | EProj (e, d)       ->
         let f d = aux (push_proj f d) e in
         aux f d
   in
   aux f e