(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module P = Printf

module U = NUri
module C = Cps
module L = Log
module J = Marks
module N = Level
module E = Entity
module D = Crg

(* nodes count **************************************************************)

let level = 2

type counters = {
   eabsts: int;
   eabbrs: int;
   evoids: int;
   tsorts: int;
   tlrefs: int;
   tgrefs: int;
   tcasts: int;
   tappls: int;
   tabsts: int;
   tabbrs: int;
   tvoids: int;
   uris  : D.uri list;
   nodes : int;
   xnodes: int
}

let initial_counters = {
   eabsts = 0; eabbrs = 0; evoids = 0; 
   tsorts = 0; tlrefs = 0; tgrefs = 0; tcasts = 0; tappls = 0;
   tabsts = 0; tabbrs = 0; tvoids = 0;
   uris = []; nodes = 0; xnodes = 0
}

let rec count_term f c e = function
   | D.TSort _          -> 
      f {c with tsorts = succ c.tsorts; nodes = succ c.nodes}
   | D.TLRef (_, i)     -> 
      begin match D.get e i with
	 | _, _, D.Abbr _ ->
	    f {c with tlrefs = succ c.tlrefs; xnodes = succ c.xnodes}
	 | _              ->
	    f {c with tlrefs = succ c.tlrefs; nodes = succ c.nodes}
      end      
   | D.TGRef (_, u)     -> 
      let c =    
	 if C.list_mem ~eq:U.eq u c.uris
	 then {c with nodes = succ c.nodes}
	 else {c with xnodes = succ c.xnodes}
      in
      f {c with tgrefs = succ c.tgrefs}
   | D.TCast (_, v, t)  -> 
      let c = {c with tcasts = succ c.tcasts} in
      let f c = count_term f c e t in
      count_term f c e v
   | D.TAppl (_, v, t)  -> 
      let c = {c with tappls = succ c.tappls} in
      let f c = count_term f c e t in
      count_term f c e v
   | D.TProj (_, d, t)  ->
      D.shift (count_term f c e) d t
   | D.TBind (a, b, t)  -> 
      let f c e = count_term f c e t in
      count_binder f c e a b

and count_binder f c e a b = match b with
   | D.Abst (_, w) ->
      let c = {c with tabsts = succ c.tabsts; nodes = succ c.nodes} in
      let f c = D.push_bind (f c) a b e in
      count_term f c e w
   | D.Abbr v      -> 
      let c = {c with tabbrs = succ c.tabbrs; xnodes = succ c.xnodes} in
      let f c = D.push_bind (f c) a b e in
      count_term f c e v     
   | D.Void        ->
      let c = {c with tvoids = succ c.tvoids; xnodes = succ c.xnodes} in
      D.push_bind (f c) a b e

let count_entity f c = function
   | _, _, u, E.Abst w -> 
      let c = {c with
         eabsts = succ c.eabsts; nodes = succ c.nodes; uris = u :: c.uris
      } in
      count_term f c D.ESort w
   | _, _, _, E.Abbr v ->  
      let c = {c with eabbrs = succ c.eabbrs; xnodes = succ c.xnodes} in
      count_term f c D.ESort v
   | _, _, _, E.Void   -> assert false

let print_counters f c =
   let terms =
      c.tsorts + c.tgrefs + c.tgrefs + c.tcasts + c.tappls + c.tabsts +
      c.tabbrs
   in
   let items = c.eabsts + c.eabbrs in
   let nodes = c.nodes + c.xnodes in
   let marks = J.marks () in
   L.warn level (P.sprintf "Intermediate representation summary (complete_rg)");
   L.warn level (P.sprintf "  Total entry items:        %7u" items);
   L.warn level (P.sprintf "    Declaration items:      %7u" c.eabsts);
   L.warn level (P.sprintf "    Definition items:       %7u" c.eabbrs);
   L.warn level (P.sprintf "  Total term items:         %7u" terms);
   L.warn level (P.sprintf "    Sort items:             %7u" c.tsorts);
   L.warn level (P.sprintf "    Local reference items:  %7u" c.tlrefs);
   L.warn level (P.sprintf "    Global reference items: %7u" c.tgrefs);
   L.warn level (P.sprintf "    Explicit Cast items:    %7u" c.tcasts);
   L.warn level (P.sprintf "    Application items:      %7u" c.tappls);
   L.warn level (P.sprintf "    Abstraction items:      %7u" c.tabsts);
   L.warn level (P.sprintf "    Abbreviation items:     %7u" c.tabbrs);
   L.warn level (P.sprintf "  Ambiguous abstractions:   %7u" marks);   
   L.warn level (P.sprintf "  Global Int. Complexity:   %7u" c.nodes);
   L.warn level (P.sprintf "    + Abbreviation nodes:   %7u" nodes);
   f ()

(* term/environment pretty printer ******************************************)

let pp_attrs out a =
   let f s b = if b then out (P.sprintf "%s;" s) else out (P.sprintf "~%s;" s) in
   E.name ignore f a;
   let f i = out (P.sprintf "+%i;" i) in
   E.apix ignore f a

let rec pp_term out st = function
   | D.TSort (a, l)    -> pp_attrs out a; out (P.sprintf "*%u" l)
   | D.TLRef (a, i   ) -> pp_attrs out a; out (P.sprintf "#%u" i)
   | D.TGRef (a, u)    -> pp_attrs out a; out (P.sprintf "$")
   | D.TCast (a, x, y) -> pp_attrs out a; out "<"; pp_term out st x; out ">."; pp_term out st y
   | D.TAppl (a, x, y) -> pp_attrs out a; out "("; pp_term out st x; out ")."; pp_term out st y
   | D.TBind (a, x, y) -> pp_attrs out a; pp_bind out st x; out "."; pp_term out st y
   | D.TProj (a, x, y) -> pp_attrs out a; out "{"; pp_lenv out st x; out "}."; pp_term out st y

and pp_bind out st = function
   | D.Abst (n, x) ->
      out "[:"; pp_term out st x; out "]"; out (N.to_string st n)  
   | D.Abbr x      -> out "[="; pp_term out st x; out "]";
   | D.Void        -> out "[]"

and pp_lenv out st = function
   | D.ESort           -> ()
   | D.EBind (x, a, y) -> pp_lenv out st x; pp_attrs out a; pp_bind out st y
   | D.EAppl (x, a, y) -> pp_lenv out st x; out "("; pp_term out st y; out ")"
   | D.EProj (x, a, y) -> pp_lenv out st x; out "{"; pp_lenv out st y; out "}"