(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module U = NUri
module C = Cps
module S = Share
module L = Log
module Y = Entity
module H = Hierarchy
module B = Bag
module O = BagOutput
module E = BagEnvironment
module R = BagReduction

exception TypeError of B.message

(* Internal functions *******************************************************)

let level = 4

let log1 s c t =
   let sc, st = s ^ " in the envireonment", "the term" in
   L.log O.specs level (L.et_items1 sc c st t)

let error1 st c t =
   let sc = "In the envireonment" in
   raise (TypeError (L.et_items1 sc c st t))

let error3 c t1 t2 t3 =
   let sc, st1, st2, st3 = 
      "In the envireonment", "the term", "is of type", "but must be of type"
   in
   raise (TypeError (L.et_items3 sc c st1 t1 st2 t2 st3 t3))

let mk_gref u l =
   let map t v = B.Appl (v, t) in
   List.fold_left map (B.GRef u) l

(* Interface functions ******************************************************)

let rec b_type_of f ~si g c x = 
(*   L.warn "Entering T.b_type_of"; *)
   log1 "Now checking" c x;
   match x with
   | B.Sort h                    ->
      let h = H.apply g h in f x (B.Sort h) 
   | B.LRef i                    ->
      let f = function
         | Some (_, B.Abst w)               -> f x w
	 | Some (_, B.Abbr (B.Cast (w, v))) -> f x w
	 | Some (_, B.Abbr _)               -> assert false
	 | Some (_, B.Void)                 -> 
	    error1 "reference to excluded variable" c x
         | None                             ->
	    error1 "variable not found" c x	 
      in
      B.get f c i
   | B.GRef uri                  ->
      let f = function
         | _, _, Y.Abst w               -> f x w
	 | _, _, Y.Abbr (B.Cast (w, v)) -> f x w
	 | _, _, Y.Abbr _               -> assert false
	 | _, _, Y.Void                 -> assert false
      in
      E.get_entity f uri   
   | B.Bind (l, id, B.Abbr v, t) ->
      let f xv xt tt =
         f (S.sh2 v xv t xt x (B.bind_abbr l id)) (B.bind_abbr l id xv tt)
      in
      let f xv cc = b_type_of (f xv) ~si g cc t in
      let f xv = B.push "type abbr" (f xv) c l id (B.Abbr xv) in
      let f xv vv = match xv with 
	 | B.Cast _ -> f xv
         | _        -> f (B.Cast (vv, xv))
      in
      type_of f ~si g c v
   | B.Bind (l, id, B.Abst u, t) ->
      let f xu xt tt =
	 f (S.sh2 u xu t xt x (B.bind_abst l id)) (B.bind_abst l id xu tt)
      in
      let f xu cc = b_type_of (f xu) ~si g cc t in
      let f xu _ = B.push "type abst" (f xu) c l id (B.Abst xu) in
      type_of f ~si g c u
   | B.Bind (l, id, B.Void, t)   ->
      let f xt tt = 
         f (S.sh1 t xt x (B.bind l id B.Void)) (B.bind l id B.Void tt)
      in
      let f cc = b_type_of f ~si g cc t in
      B.push "type void" f c l id B.Void   
   | B.Appl (v, t)            ->
      let f xv vv xt tt = function
	 | R.Abst w                             -> 
            L.box (succ level);
	    L.log O.specs (succ level) (L.t_items1 "Just scanned" c w);
	    L.unbox (succ level);
	    let f a =                
(*	       L.warn (Printf.sprintf "Convertible: %b" a); *)
	       if a then f (S.sh2 v xv t xt x B.appl) (B.appl xv tt)
	       else error3 c xv vv w
	    in
	    R.are_convertible f ~si c w vv
	 | _                                    -> 
	    error1 "not a function" c xt
      in
      let f xv vv xt tt = R.ho_whd (f xv vv xt tt) c tt in
      let f xv vv = b_type_of (f xv vv) ~si g c t in
      type_of f ~si g c v
   | B.Cast (u, t)            ->
      let f xu xt tt a =  
         (* L.warn (Printf.sprintf "Convertible: %b" a); *)
	 if a then f (S.sh2 u xu t xt x B.cast) xu else error3 c xt tt xu
      in
      let f xu xt tt = R.are_convertible (f xu xt tt) ~si c xu tt in
      let f xu _ = b_type_of (f xu) ~si g c t in
      type_of f ~si g c u

and type_of f ?(si=false) g c x =
   let f t u = L.unbox level; f t u in
   L.box level; b_type_of f ~si g c x