(*
    ||M||  This file is part of HELM, an Hypertextual, Electronic        
    ||A||  Library of Mathematics, developed at the Computer Science     
    ||T||  Department, University of Bologna, Italy.                     
    ||I||                                                                
    ||T||  HELM is free software; you can redistribute it and/or         
    ||A||  modify it under the terms of the GNU General Public License   
    \   /  version 2 or (at your option) any later version.              
     \ /   This software is distributed as is, NO WARRANTY.              
      V_______________________________________________________________ *)

module P    = Printf
module U    = NUri
module C    = Cps
module L    = Log
module T    = Time
module H    = Hierarchy
module O    = Output
module Y    = Entity
module X    = Library
module AP   = AutProcess
module AO   = AutOutput
module DA   = CrgAut
module MA   = MetaAut
module MO   = MetaOutput
module ML   = MetaLibrary
module DO   = CrgOutput
module DBrg = CrgBrg
module MBrg = MetaBrg
module BrgO = BrgOutput
module BrgR = BrgReduction
module BrgU = BrgUntrusted
module MBag = MetaBag
module BagO = BagOutput
module BagT = BagType
module BagU = BagUntrusted

type status = {
   ast : AP.status;
   dst : DA.status;
   mst : MA.status;
   ac  : AO.counters;
   mc  : MO.counters;
   brgc: BrgO.counters;
   bagc: BagO.counters
}

let initial_status mk_uri cover = {
   ac   = AO.initial_counters;
   mc   = MO.initial_counters;
   brgc = BrgO.initial_counters;
   bagc = BagO.initial_counters;
   mst  = MA.initial_status ~cover ();
   dst  = DA.initial_status (mk_uri cover);
   ast  = AP.initial_status
}

let flush_all () = L.flush 0; L.flush_err ()

let bag_error s msg =
   L.error BagO.specs (L.Warn s :: L.Loc :: msg); flush_all () 

let brg_error s msg =
   L.error BrgR.specs (L.Warn s :: L.Loc :: msg); flush_all () 

let process_entity f st entity =
   let f ast = f {st with ast = ast} in
   AP.process_entity f st.ast entity

(* kernel related ***********************************************************)

type kernel = Brg | Bag

type kernel_entity = BrgEntity  of Brg.entity
                   | BagEntity  of Bag.entity
		   | CrgEntity  of Crg.entity
		   | MetaEntity of Meta.entity

let kernel = ref Brg

let print_counters st = match !kernel with
   | Brg -> BrgO.print_counters C.start st.brgc
   | Bag -> BagO.print_counters C.start st.bagc

let xlate_entity entity = match !kernel, entity with
   | Brg, CrgEntity e  -> 
      let f e = (BrgEntity e) in Y.xlate f DBrg.brg_of_crg e
   | Brg, MetaEntity e -> 
      let f e = (BrgEntity e) in Y.xlate f MBrg.brg_of_meta e
   | Bag, MetaEntity e -> 
      let f e = (BagEntity e) in Y.xlate f MBag.bag_of_meta e  
   | _, entity         -> entity

let pp_progress e =
   let f a u =
      let s = U.string_of_uri u in
      let err () = L.warn (P.sprintf "%s" s) in
      let f i = L.warn (P.sprintf "[%u] %s" i s) in
      Y.mark err f a
   in
   match e with
      | CrgEntity e -> Y.common f e
      | BrgEntity e -> Y.common f e
      | BagEntity e -> Y.common f e      
      | MetaEntity e -> Y.common f e

let count_entity st = function
   | MetaEntity e -> {st with mc = MO.count_entity C.start st.mc e} 
   | BrgEntity e  -> {st with brgc = BrgO.count_entity C.start st.brgc e}
   | BagEntity e  -> {st with bagc = BagO.count_entity C.start st.bagc e}
   | _            -> st

let export_entity si g moch = function
   | CrgEntity e  -> X.export_entity DO.export_term si g e
   | BrgEntity e  -> X.export_entity BrgO.export_term si g e
   | MetaEntity e ->
      begin match moch with
         | None     -> ()
         | Some och -> ML.write_entity C.start och e
      end
   | BagEntity _  -> ()

let type_check st si g k =
   let brg_err msg = brg_error "Type Error" msg; failwith "Interrupted" in
   let ok _ _ = st in
   match k with
      | BrgEntity entity -> BrgU.type_check brg_err ok ~si g entity
      | BagEntity entity -> BagU.type_check ok ~si g entity
      | CrgEntity _
      | MetaEntity _     -> st

(****************************************************************************)

let stage = ref 3
let moch = ref None
let meta = ref false
let progress = ref false
let preprocess = ref false
let use_cover = ref true
let si = ref false
let cc = ref false
let export = ref false
let graph = ref (H.graph_of_string C.err C.start "Z2")
let old = ref false

let process_2 st entity =
   let st = if !L.level > 2 then count_entity st entity else st in
   if !export then export_entity !si !graph !moch entity;
   if !stage > 2 then type_check st !si !graph entity else st
	    
let process_1 st entity = 
   if !progress then pp_progress entity;
   let st = if !L.level > 2 then count_entity st entity else st in
   if !export && !stage = 1 then export_entity !si !graph !moch entity;
   if !stage > 1 then process_2 st (xlate_entity entity) else st 

let process_0 st entity = 
   let f st entity =
      if !stage = 0 then st else
      let frr mst = {st with mst = mst} in
      let h mst e = process_1 {st with mst = mst} (MetaEntity e) in
      let err dst = {st with dst = dst} in
      let g dst e = process_1 {st with dst = dst} (CrgEntity e) in
      if !old then MA.meta_of_aut frr h st.mst entity else 
      DA.crg_of_aut err g st.dst entity
   in
   let st = 
      if !L.level > 2 then {st with ac = AO.count_entity C.start st.ac entity}
      else st
   in 
   if !preprocess then process_entity f st entity else f st entity

let rec process st = function
   | []           -> st
   | entity :: tl -> process (process_0 st entity) tl

(****************************************************************************)

let main =
try 
   let version_string = "Helena 0.8.1 M - October 2009" in
   let set_hierarchy s = 
      let err () = L.warn (P.sprintf "Unknown type hierarchy: %s" s) in
      let f g = graph := g in
      H.graph_of_string err f s
   in
   let set_kernel = function
      | "brg" -> kernel := Brg
      | "bag" -> kernel := Bag
      | s     -> L.warn (P.sprintf "Unknown kernel version: %s" s)
   in
   let set_summary i = L.level := i in
   let print_version () = L.warn (version_string ^ "\n"); exit 0 in
   let set_stage i = stage := i in
   let set_meta_file name =
      let f och = moch := Some och in
      ML.open_out f name
   in
   let close = function
      | None     -> ()
      | Some och -> ML.close_out C.start och
   in
   let read_file name =
      if !L.level > 0 then T.gmtime version_string;      
      if !L.level > 1 then
         L.warn (P.sprintf "Processing file: %s" name);
      if !L.level > 0 then T.utime_stamp "started";
      let base_name = Filename.chop_extension (Filename.basename name) in
      if !meta then set_meta_file base_name;
      let ich = open_in name in
      let lexbuf = Lexing.from_channel ich in
      let book = AutParser.book AutLexer.token lexbuf in
      close_in ich;
      if !L.level > 0 then T.utime_stamp "parsed";
      O.clear_reductions ();
      let mk_uri =
         if !stage < 2 then Crg.mk_uri else
	 match !kernel with
	    | Brg -> Brg.mk_uri
	    | Bag -> Bag.mk_uri
      in
      let cover = if !use_cover then base_name else "" in
      let st = process (initial_status mk_uri cover) book in
      if !L.level > 0 then T.utime_stamp "processed";
      if !L.level > 2 then begin
         AO.print_counters C.start st.ac;
         if !preprocess then AO.print_process_counters C.start st.ast;
         if !stage > 0 then MO.print_counters C.start st.mc;
         if !stage > 1 then print_counters st;
         if !stage > 2 then O.print_reductions ()
      end
   in
   let exit () =
      close !moch;
      if !L.level > 0 then T.utime_stamp "at exit";
      flush_all ()
   in
   let help = 
      "Usage: helena [ -Vcijmopux | -Ss <number> | -hk <string> ] <file> ...\n\n" ^
      "Summary levels: 0 just errors (default), 1 time stamps, 2 processed file names, \
       3 data information, 4 typing information, 5 reduction information\n\n" ^
       "Stages: 0 parsing, 1 to intermediate, 2 to untrusted, 3 to trusted (default)\n"
   in
   let help_S = "<number>  set summary level (see above)" in
   let help_V = " show version information" in   

   let help_c = " output conversion constraints" in
   let help_h = "<string>  set type hierarchy (default: Z2)" in
   let help_i = " show local references by index" in
   let help_j = " show URI of processed kernel objects" in
   let help_k = "<string>  set kernel version (default: brg)" in
   let help_m = " output intermediate representation (HAL)" in
   let help_o = " use old abstract language instead of crg" in   
   let help_p = " preprocess Automath source" in
   let help_r = " disable initial segment of URI hierarchy" in
   let help_s = "<number>  set translation stage (see above)" in
   let help_u = " activate sort inclusion" in
   let help_x = " export kernel entities (XML)" in
   L.box 0; L.box_err ();
   let _ = H.set_sorts ["Set"; "Prop"] 0 in
   at_exit exit;
   Arg.parse [
      ("-S", Arg.Int set_summary, help_S);
      ("-V", Arg.Unit print_version, help_V);
      ("-c", Arg.Set cc, help_c);
      ("-h", Arg.String set_hierarchy, help_h);
      ("-i", Arg.Set O.indexes, help_i);
      ("-j", Arg.Set progress, help_j);      
      ("-k", Arg.String set_kernel, help_k);
      ("-m", Arg.Set meta, help_m); 
      ("-o", Arg.Set old, help_o);      
      ("-p", Arg.Set preprocess, help_p);      
      ("-r", Arg.Clear use_cover, help_r);
      ("-s", Arg.Int set_stage, help_s);
      ("-u", Arg.Set si, help_u);
      ("-x", Arg.Set export, help_x)
   ] read_file help;
with BagT.TypeError msg -> bag_error "Type Error" msg