branch for universe

[helm.git] / components / ng_kernel / nCicUtils.ml

diff --git a/components/ng_kernel/nCicUtils.ml b/components/ng_kernel/nCicUtils.ml
new file mode 100644 (file)
index 0000000..1d43c2c
--- /dev/null
+++ b/components/ng_kernel/nCicUtils.ml
@@ -0,0 +1,106 @@
+(*
+    ||M||  This file is part of HELM, an Hypertextual, Electronic        
+    ||A||  Library of Mathematics, developed at the Computer Science     
+    ||T||  Department, University of Bologna, Italy.                     
+    ||I||                                                                
+    ||T||  HELM is free software; you can redistribute it and/or         
+    ||A||  modify it under the terms of the GNU General Public License   
+    \   /  version 2 or (at your option) any later version.      
+     \ /   This software is distributed as is, NO WARRANTY.     
+      V_______________________________________________________________ *)
+
+(* $Id: nCicSubstitution.ml 8135 2008-02-13 15:35:43Z tassi $ *)
+
+exception Subst_not_found of int
+exception Meta_not_found of int
+
+let expand_local_context = function
+  | NCic.Irl len -> 
+      let rec aux acc = function 
+        | 0 -> acc
+        | n -> aux (NCic.Rel n::acc) (n-1)
+      in
+       aux [] len
+  | NCic.Ctx lctx -> lctx
+;;
+
+let lookup_subst n subst =
+  try
+    List.assoc n subst
+  with Not_found -> raise (Subst_not_found n)
+;;
+
+let lookup_meta index metasenv =
+  try
+    List.find (fun (index', _, _, _) -> index = index') metasenv
+  with Not_found -> raise (Meta_not_found index)
+;;
+
+let fold g k f acc = function
+ | NCic.Meta _ -> assert false
+ | NCic.Implicit _
+ | NCic.Sort _
+ | NCic.Const _
+ | NCic.Rel _ -> acc
+ | NCic.Appl [] | NCic.Appl [_] -> assert false
+ | NCic.Appl l -> List.fold_left (f k) acc l
+ | NCic.Prod (n,s,t)
+ | NCic.Lambda (n,s,t) -> f (g (n,NCic.Decl s) k) (f k acc s) t
+ | NCic.LetIn (n,ty,t,bo) -> f (g (n,NCic.Def (t,ty)) k) (f k (f k acc ty) t) bo
+ | NCic.Match (_,oty,t,pl) -> List.fold_left (f k) (f k (f k acc oty) t) pl
+;;
+
+let sharing_map f l =
+  let unchanged = ref true in
+  let rec aux b = function
+    | [] as t -> unchanged := b; t
+    | he::tl ->
+        let he1 = f he in
+        he1 :: aux (b && he1 == he) tl
+  in
+  let l1 = aux true l in
+  if !unchanged then l else l1
+;;
+        
+let map g k f = function
+ | NCic.Meta _ -> assert false
+ | NCic.Implicit _
+ | NCic.Sort _
+ | NCic.Const _
+ | NCic.Rel _ as t -> t
+ | NCic.Appl [] | NCic.Appl [_] -> assert false
+ | NCic.Appl l as orig ->
+    (match sharing_map (f k) l with
+      | NCic.Appl l :: tl -> NCic.Appl (l@tl)
+      | l1 when l == l1 -> orig
+      | l1 -> NCic.Appl l1)
+ | NCic.Prod (n,s,t) as orig ->
+     let s1 = f k s in let t1 = f (g (n,NCic.Decl s) k) t in
+     if t1 == t && s1 == s then orig else NCic.Prod (n,s1,t1)
+ | NCic.Lambda (n,s,t) as orig -> 
+     let s1 = f k s in let t1 = f (g (n,NCic.Decl s) k) t in
+     if t1 == t && s1 == s then orig else NCic.Lambda (n,s1,t1)
+ | NCic.LetIn (n,ty,t,b) as orig -> 
+     let ty1 = f k ty in let t1 = f k t in
+     let b1 = f (g (n,NCic.Def (t,ty)) k) b in
+     if ty1 == ty && t1 == t && b1 == b then orig else NCic.LetIn (n,ty1,t1,b1)
+ | NCic.Match (r,oty,t,pl) as orig -> 
+     let oty1 = f k oty in let t1 = f k t in let pl1 = sharing_map (f k) pl in
+     if oty1 == oty && t1 == t && pl1 == pl then orig 
+     else NCic.Match(r,oty1,t1,pl1)
+;;
+
+exception NotClosed
+
+let is_closed t = 
+  try
+    let rec aux k _ = function
+      | NCic.Rel n when n > k -> raise NotClosed
+      | NCic.Meta (_, (s, NCic.Irl n)) when not (n+s <= k) -> raise NotClosed
+      | NCic.Meta (_, (s, NCic.Ctx l)) -> List.iter (aux (k+s) ()) l 
+      | _ -> fold (fun _ k -> k + 1) k aux () t
+    in 
+      aux 0 () t; true
+  with NotClosed -> false
+;;
+