components/acic_content/acic2astMatcher.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 module Ast = CicNotationPt
  29 module Util = CicNotationUtil
  30
  31 module Matcher32 =
  32 struct
  33   module Pattern32 =
  34   struct
  35     type cic_mask_t =
  36       Blob
  37     | Uri of UriManager.uri
  38     | Appl of cic_mask_t list
  39
  40     let uri_of_term t = CicUtil.uri_of_term (Deannotate.deannotate_term t)
  41
  42     let mask_of_cic = function
  43       | Cic.AAppl (_, tl) -> Appl (List.map (fun _ -> Blob) tl), tl
  44       | Cic.AConst (_, _, [])
  45       | Cic.AVar (_, _, [])
  46       | Cic.AMutInd (_, _, _, [])
  47       | Cic.AMutConstruct (_, _, _, _, []) as t -> Uri (uri_of_term t), []
  48       | _ -> Blob, []
  49
  50     let tag_of_term t =
  51       let mask, tl = mask_of_cic t in
  52       Hashtbl.hash mask, tl
  53
  54     let mask_of_appl_pattern = function
  55       | Ast.UriPattern uri -> Uri uri, []
  56       | Ast.ImplicitPattern
  57       | Ast.VarPattern _ -> Blob, []
  58       | Ast.ApplPattern pl -> Appl (List.map (fun _ -> Blob) pl), pl
  59
  60     let tag_of_pattern p =
  61       let mask, pl = mask_of_appl_pattern p in
  62       Hashtbl.hash mask, pl
  63
  64     type pattern_t = Ast.cic_appl_pattern
  65     type term_t = Cic.annterm
  66
  67     let string_of_pattern = CicNotationPp.pp_cic_appl_pattern
  68     let string_of_term t = CicPp.ppterm (Deannotate.deannotate_term t)
  69
  70     let classify = function
  71       | Ast.ImplicitPattern
  72       | Ast.VarPattern _ -> PatternMatcher.Variable
  73       | Ast.UriPattern _
  74       | Ast.ApplPattern _ -> PatternMatcher.Constructor
  75   end
  76
  77   module M = PatternMatcher.Matcher (Pattern32)
  78
  79   let compiler rows =
  80     let match_cb rows =
  81       let pl, pid = try List.hd rows with Not_found -> assert false in
  82       (fun matched_terms constructors ->
  83         let env =
  84           try
  85             List.map2
  86               (fun p t ->
  87                 match p with
  88                 | Ast.ImplicitPattern -> Util.fresh_name (), t
  89                 | Ast.VarPattern name -> name, t
  90                 | _ -> assert false)
  91               pl matched_terms
  92           with Invalid_argument _ -> assert false
  93         in
  94         Some (env, constructors, pid))
  95     in
  96     M.compiler rows match_cb (fun () -> None)
  97 end
  98