components/acic_procedural/acic2Procedural.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module I    = CicInspect
  28 module S    = CicSubstitution
  29 module TC   = CicTypeChecker
  30 module Un   = CicUniv
  31 module UM   = UriManager
  32 module Obj  = LibraryObjects
  33 module HObj = HelmLibraryObjects
  34 module A    = Cic2acic
  35 module Ut   = CicUtil
  36 module E    = CicEnvironment
  37 module Pp   = CicPp
  38 module PEH  = ProofEngineHelpers
  39 module HEL  = HExtlib
  40 module DTI  = DoubleTypeInference
  41
  42 module Cl   = ProceduralClassify
  43 module T    = ProceduralTypes
  44 module Cn   = ProceduralConversion
  45 module H    = ProceduralHelpers
  46
  47 type status = {
  48    sorts : (C.id, A.sort_kind) Hashtbl.t;
  49    types : (C.id, A.anntypes) Hashtbl.t;
  50    prefix: string;
  51    max_depth: int option;
  52    depth: int;
  53    context: C.context;
  54    intros: string option list;
  55    clears: string list;
  56    clears_note: string;
  57    case: int list;
  58    skip_thm_and_qed : bool;
  59 }
  60
  61 (* helpers ******************************************************************)
  62
  63 let split2_last l1 l2 =
  64 try
  65    let n = pred (List.length l1) in
  66    let before1, after1 = HEL.split_nth n l1 in
  67    let before2, after2 = HEL.split_nth n l2 in
  68    before1, before2, List.hd after1, List.hd after2
  69 with Invalid_argument _ -> failwith "A2P.split2_last"
  70
  71 let string_of_head = function
  72    | C.ASort _         -> "sort"
  73    | C.AConst _        -> "const"
  74    | C.AMutInd _       -> "mutind"
  75    | C.AMutConstruct _ -> "mutconstruct"
  76    | C.AVar _          -> "var"
  77    | C.ARel _          -> "rel"
  78    | C.AProd _         -> "prod"
  79    | C.ALambda _       -> "lambda"
  80    | C.ALetIn _        -> "letin"
  81    | C.AFix _          -> "fix"
  82    | C.ACoFix _        -> "cofix"
  83    | C.AAppl _         -> "appl"
  84    | C.ACast _         -> "cast"
  85    | C.AMutCase _      -> "mutcase"
  86    | C.AMeta _         -> "meta"
  87    | C.AImplicit _     -> "implict"
  88
  89 let clear st = {st with intros = []}
  90
  91 let next st = {(clear st) with depth = succ st.depth}
  92
  93 let add st entry intro =
  94    {st with context = entry :: st.context; intros = intro :: st.intros}
  95
  96 let push st = {st with case = 1 :: st.case}
  97
  98 let inc st =
  99    {st with case = match st.case with
 100       | []       -> assert false
 101       | hd :: tl -> succ hd :: tl
 102    }
 103
 104 let case st str =
 105    let case = String.concat "." (List.rev_map string_of_int st.case) in
 106    Printf.sprintf "case %s: %s" case str
 107
 108 let test_depth st =
 109 try
 110    let msg = Printf.sprintf "Depth %u: " st.depth in
 111    match st.max_depth with
 112       | None   -> true, ""
 113       | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
 114 with Invalid_argument _ -> failwith "A2P.test_depth"
 115
 116 let is_rewrite_right = function
 117    | C.AConst (_, uri, []) ->
 118       UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
 119    | _                     -> false
 120
 121 let is_rewrite_left = function
 122    | C.AConst (_, uri, []) ->
 123       UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
 124    | _                     -> false
 125
 126 let is_fwd_rewrite_right hd tl =
 127    if is_rewrite_right hd then match List.nth tl 3 with
 128       | C.ARel _ -> true
 129       | _        -> false
 130    else false
 131
 132 let is_fwd_rewrite_left hd tl =
 133    if is_rewrite_left hd then match List.nth tl 3 with
 134       | C.ARel _ -> true
 135       | _        -> false
 136    else false
 137
 138 let get_inner_types st v =
 139 try
 140    let id = Ut.id_of_annterm v in
 141    try match Hashtbl.find st.types id with
 142       | {A.annsynthesized = st; A.annexpected = Some et} -> Some (st, et)
 143       | {A.annsynthesized = st; A.annexpected = None}    -> Some (st, st)
 144    with Not_found -> None
 145 with Invalid_argument _ -> failwith "A2P.get_inner_types"
 146 (*
 147 let get_inner_sort st v =
 148 try
 149    let id = Ut.id_of_annterm v in
 150    try Hashtbl.find st.sorts id
 151    with Not_found -> `Type (CicUniv.fresh())
 152 with Invalid_argument _ -> failwith "A2P.get_sort"
 153 *)
 154 let get_type msg st bo =
 155 try
 156    let ty, _ = TC.type_of_aux' [] st.context (H.cic bo) Un.oblivion_ugraph in
 157    ty
 158 with e -> failwith (msg ^ ": " ^ Printexc.to_string e)
 159
 160 let get_entry st id =
 161    let rec aux = function
 162       | []                                        -> assert false
 163       | Some (C.Name name, e) :: _ when name = id -> e
 164       | _ :: tl                                   -> aux tl
 165    in
 166    aux st.context
 167
 168 let get_ind_names uri tno =
 169 try
 170    let ts = match E.get_obj Un.oblivion_ugraph uri with
 171       | C.InductiveDefinition (ts, _, _, _), _ -> ts
 172       | _                                      -> assert false
 173    in
 174    match List.nth ts tno with
 175       | (_, _, _, cs) -> List.map fst cs
 176 with Invalid_argument _ -> failwith "A2P.get_ind_names"
 177
 178 (* proof construction *******************************************************)
 179
 180 let used_premise = C.Name "USED"
 181
 182 let mk_exp_args hd tl classes synth =
 183    let meta id = C.AImplicit (id, None) in
 184    let map v (cl, b) =
 185       if I.overlaps synth cl && b then v else meta ""
 186    in
 187    let rec aux = function
 188       | [] -> []
 189       | hd :: tl -> if hd = meta "" then aux tl else List.rev (hd :: tl)
 190    in
 191    let args = T.list_rev_map2 map tl classes in
 192    let args = aux args in
 193    if args = [] then hd else C.AAppl ("", hd :: args)
 194
 195 let mk_convert st ?name sty ety note =
 196    let e = Cn.hole "" in
 197    let csty, cety = H.cic sty, H.cic ety in
 198    let _note = Printf.sprintf "%s\nSINTH: %s\nEXP: %s"
 199       note (Pp.ppterm csty) (Pp.ppterm cety)
 200    in
 201    assert (Ut.is_sober csty);
 202    assert (Ut.is_sober cety);
 203    if Ut.alpha_equivalence csty cety then [(* T.Note note *)] else
 204    let sty, ety = H.acic_bc st.context sty, H.acic_bc st.context ety in
 205    match name with
 206       | None         -> [T.Change (sty, ety, None, e, ""(*note*))]
 207       | Some (id, i) ->
 208          begin match get_entry st id with
 209             | C.Def _  -> assert false (* [T.ClearBody (id, note)] *)
 210             | C.Decl _ -> [T.Change (ety, sty, Some (id, Some id), e, "" (* note *))]
 211          end
 212
 213 let convert st ?name v =
 214    match get_inner_types st v with
 215       | None            -> [(*T.Note "NORMAL: NO INNER TYPES"*)]
 216       | Some (sty, ety) -> mk_convert st ?name sty ety "NORMAL"
 217
 218 let convert_elim st ?name t v pattern =
 219    match t, get_inner_types st t, get_inner_types st v with
 220       | _, None, _
 221       | _, _, None                                            -> [(* T.Note "ELIM: NO INNER TYPES"*)]
 222       | C.AAppl (_, hd :: tl), Some (tsty, _), Some (vsty, _) ->
 223          let where = List.hd (List.rev tl) in
 224          let cty = Cn.elim_inferred_type
 225              st.context (H.cic vsty) (H.cic where) (H.cic hd) (H.cic pattern)
 226          in
 227          mk_convert st ?name (Cn.fake_annotate "" st.context cty) tsty "ELIM"
 228       | _, Some _, Some _                                     -> assert false
 229
 230 let get_intro = function
 231    | C.Anonymous -> None
 232    | C.Name s    -> Some s
 233
 234 let mk_intros st what script =
 235    let intros st script =
 236       if st.intros = [] then script else
 237       let count = List.length st.intros in
 238       T.Intros (Some count, List.rev st.intros, "") :: script
 239    in
 240    let clears st script =
 241       if true (* st.clears = [] *) then script else T.Clear (st.clears, st.clears_note) :: script
 242    in
 243    intros st (clears st (convert st what @ script))
 244
 245 let mk_arg st = function
 246    | C.ARel (_, _, i, name) as what -> convert st ~name:(name, i) what
 247    | _                              -> []
 248
 249 let mk_fwd_rewrite st dtext name tl direction t =
 250    assert (List.length tl = 6);
 251    let what, where, predicate = List.nth tl 5, List.nth tl 3, List.nth tl 2 in
 252    let e = Cn.mk_pattern 1 predicate in
 253    match where with
 254       | C.ARel (_, _, i, premise) as v ->
 255          let where = Some (premise, name) in
 256 (*         let _script = convert_elim st ~name:(premise, i) t v e in *)
 257          let script = mk_arg st what @ mk_arg st v (* @ script *) in
 258          let st = {st with context = Cn.clear st.context premise} in
 259          st, T.Rewrite (direction, what, where, e, dtext) :: script
 260       | _                         -> assert false
 261
 262 let mk_rewrite st dtext where qs tl direction t =
 263    assert (List.length tl = 5);
 264    let predicate = List.nth tl 2 in
 265    let e = Cn.mk_pattern 1 predicate in
 266    let script = [] (* convert_elim st t t e *) in
 267    script @ [T.Rewrite (direction, where, None, e, dtext); T.Branch (qs, "")]
 268
 269 let rec proc_lambda st name v t =
 270    let dno = DTI.does_not_occur 1 (H.cic t) in
 271    let dno = dno && match get_inner_types st t with
 272       | None          -> false
 273       | Some (it, et) ->
 274          DTI.does_not_occur 1 (H.cic it) && DTI.does_not_occur 1 (H.cic et)
 275    in
 276    let name = match dno, name with
 277       | true, _            -> C.Anonymous
 278       | false, C.Anonymous -> H.mk_fresh_name st.context used_premise
 279       | false, name        -> name
 280    in
 281    let entry = Some (name, C.Decl (H.cic v)) in
 282    let intro = get_intro name in
 283    proc_proof (add st entry intro) t
 284
 285 and proc_letin st what name v w t =
 286    let intro = get_intro name in
 287    let proceed, dtext = test_depth st in
 288    let script = if proceed then
 289       let st, hyp, rqv = match get_inner_types st v with
 290          | Some (ity, _) ->
 291             let st, rqv = match v with
 292                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_right hd tl ->
 293                   mk_fwd_rewrite st dtext intro tl true v
 294                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_left hd tl  ->
 295                   mk_fwd_rewrite st dtext intro tl false v
 296                | v                                                     ->
 297                   let qs = [proc_proof (next st) v; [T.Id ""]] in
 298                   let ity = H.acic_bc st.context ity in
 299                   st, [T.Branch (qs, ""); T.Cut (intro, ity, dtext)]
 300             in
 301             st, C.Decl (H.cic ity), rqv
 302          | None          ->
 303             st, C.Def (H.cic v, H.cic w), [T.LetIn (intro, v, dtext)]
 304       in
 305       let entry = Some (name, hyp) in
 306       let qt = proc_proof (next (add st entry intro)) t in
 307       List.rev_append rqv qt
 308    else
 309       [T.Apply (what, dtext)]
 310    in
 311    mk_intros st what script
 312
 313 and proc_rel st what =
 314    let _, dtext = test_depth st in
 315    let text = "assumption" in
 316    let script = [T.Apply (what, dtext ^ text)] in
 317    mk_intros st what script
 318
 319 and proc_mutconstruct st what =
 320    let _, dtext = test_depth st in
 321    let script = [T.Apply (what, dtext)] in
 322    mk_intros st what script
 323
 324 and proc_const st what =
 325    let _, dtext = test_depth st in
 326    let script = [T.Apply (what, dtext)] in
 327    mk_intros st what script
 328
 329 and proc_appl st what hd tl =
 330    let proceed, dtext = test_depth st in
 331    let script = if proceed then
 332       let ty = get_type "TC2" st hd in
 333       let classes, rc = Cl.classify st.context ty in
 334       let goal_arity = match get_inner_types st what with
 335          | None          -> 0
 336          | Some (ity, _) -> snd (PEH.split_with_whd (st.context, H.cic ity))
 337       in
 338       let parsno, argsno = List.length classes, List.length tl in
 339       let decurry = parsno - argsno in
 340       let diff = goal_arity - decurry in
 341       if diff < 0 then failwith (Printf.sprintf "NOT TOTAL: %i %s |--- %s" diff (Pp.ppcontext st.context) (Pp.ppterm (H.cic hd)));
 342       let rec mk_synth a n =
 343          if n < 0 then a else mk_synth (I.S.add n a) (pred n)
 344       in
 345       let synth = mk_synth I.S.empty decurry in
 346       let text = "" (* Printf.sprintf "%u %s" parsno (Cl.to_string h) *) in
 347       let script = List.rev (mk_arg st hd) in
 348       match rc with
 349          | Some (i, j, uri, tyno) ->
 350             let classes, tl, _, where = split2_last classes tl in
 351             let script = List.rev (mk_arg st where) @ script in
 352             let synth = I.S.add 1 synth in
 353             let names = get_ind_names uri tyno in
 354             let qs = proc_bkd_proofs (next st) synth names classes tl in
 355             if is_rewrite_right hd then
 356                script @ mk_rewrite st dtext where qs tl false what
 357             else if is_rewrite_left hd then
 358                script @ mk_rewrite st dtext where qs tl true what
 359             else
 360                let predicate = List.nth tl (parsno - i) in
 361                let e = Cn.mk_pattern j predicate in
 362                let using = Some hd in
 363                (* convert_elim st what what e @ *) script @
 364                [T.Elim (where, using, e, dtext ^ text); T.Branch (qs, "")]
 365          | None        ->
 366             let qs = proc_bkd_proofs (next st) synth [] classes tl in
 367             let hd = mk_exp_args hd tl classes synth in
 368             script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 369    else
 370       [T.Apply (what, dtext)]
 371    in
 372    mk_intros st what script
 373
 374 and proc_other st what =
 375    let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head what) in
 376    let script = [T.Note text] in
 377    mk_intros st what script
 378
 379 and proc_proof st t =
 380    let f st =
 381       let xtypes, note = match get_inner_types st t with
 382          | Some (it, et) -> Some (H.cic it, H.cic et),
 383           (Printf.sprintf "\nInferred: %s\nExpected: %s"
 384           (Pp.ppterm (H.cic it)) (Pp.ppterm (H.cic et)))
 385          | None          -> None, "\nNo types"
 386       in
 387       let context, clears = Cn.get_clears st.context (H.cic t) xtypes in
 388       let note = Pp.ppcontext st.context ^ note in
 389       {st with context = context; clears = clears; clears_note = note; }
 390    in
 391    match t with
 392       | C.ALambda (_, name, w, t)           -> proc_lambda st name w t
 393       | C.ALetIn (_, name, v, w, t) as what -> proc_letin (f st) what name v w t
 394       | C.ARel _ as what                    -> proc_rel (f st) what
 395       | C.AMutConstruct _ as what           -> proc_mutconstruct (f st) what
 396       | C.AConst _ as what                  -> proc_const (f st) what
 397       | C.AAppl (_, hd :: tl) as what       -> proc_appl (f st) what hd tl
 398       | what                                -> proc_other (f st) what
 399
 400 and proc_bkd_proofs st synth names classes ts =
 401 try
 402    let get_note =
 403       let names = ref (names, push st) in
 404       fun f ->
 405          match !names with
 406             | [], st       -> fun _ -> f st
 407             | "" :: tl, st -> names := tl, st; fun _ -> f st
 408             | hd :: tl, st ->
 409                let note = case st hd in
 410                names := tl, inc st;
 411                fun b -> if b then T.Note note :: f st else f st
 412    in
 413    let _, dtext = test_depth st in
 414    let aux (inv, _) v =
 415       if I.overlaps synth inv then None else
 416       if I.S.is_empty inv then Some (get_note (fun st -> proc_proof st v)) else
 417       Some (fun _ -> [T.Apply (v, dtext ^ "dependent")])
 418    in
 419    let ps = T.list_map2_filter aux classes ts in
 420    let b = List.length ps > 1 in
 421    List.rev_map (fun f -> f b) ps
 422
 423 with Invalid_argument s -> failwith ("A2P.proc_bkd_proofs: " ^ s)
 424
 425 (* object costruction *******************************************************)
 426
 427 let is_theorem pars =
 428    pars = [] ||
 429    List.mem (`Flavour `Theorem) pars || List.mem (`Flavour `Fact) pars ||
 430    List.mem (`Flavour `Remark) pars || List.mem (`Flavour `Lemma) pars
 431
 432 let proc_obj st = function
 433    | C.AConstant (_, _, s, Some v, t, [], pars) when is_theorem pars ->
 434       let ast = proc_proof st v in
 435       let steps, nodes = T.count_steps 0 ast, T.count_nodes 0 ast in
 436       let text = Printf.sprintf "tactics: %u\nnodes: %u" steps nodes in
 437       if st.skip_thm_and_qed then ast
 438       else T.Theorem (Some s, t, "") :: ast @ [T.Qed text]
 439    | _                                                               ->
 440       failwith "not a theorem"
 441
 442 (* interface functions ******************************************************)
 443
 444 let acic2procedural ~ids_to_inner_sorts ~ids_to_inner_types ?depth
 445 ?(skip_thm_and_qed=false) prefix aobj =
 446    let st = {
 447       sorts       = ids_to_inner_sorts;
 448       types       = ids_to_inner_types;
 449       prefix      = prefix;
 450       max_depth   = depth;
 451       depth       = 0;
 452       context     = [];
 453       intros      = [];
 454       clears      = [];
 455       clears_note = "";
 456       case        = [];
 457       skip_thm_and_qed = skip_thm_and_qed;
 458    } in
 459    HLog.debug "Procedural: level 2 transformation";
 460    let steps = proc_obj st aobj in
 461    HLog.debug "Procedural: grafite rendering";
 462    List.rev (T.render_steps [] steps)