components/acic_procedural/proceduralOptimizer.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module Pp   = CicPp
  28 module I    = CicInspect
  29 module S    = CicSubstitution
  30 module DTI  = DoubleTypeInference
  31 module HEL  = HExtlib
  32 module PEH  = ProofEngineHelpers
  33 module TC   = CicTypeChecker
  34 module Un   = CicUniv
  35
  36 module H    = ProceduralHelpers
  37 module Cl   = ProceduralClassify
  38
  39 (* term preprocessing: optomization 1 ***************************************)
  40
  41 let defined_premise = "DEFINED"
  42
  43 let get_type msg c bo =
  44 try
  45    let ty, _ = TC.type_of_aux' [] c bo Un.oblivion_ugraph in
  46    ty
  47 with e -> failwith (msg ^ ": " ^ Printexc.to_string e)
  48
  49 let define c v =
  50    let name = C.Name defined_premise in
  51    let ty = get_type "define" c v in
  52    C.LetIn (name, v, ty, C.Rel 1)
  53
  54 let clear_absts m =
  55    let rec aux k n = function
  56       | C.Lambda (s, v, t) when k > 0 ->
  57          C.Lambda (s, v, aux (pred k) n t)
  58       | C.Lambda (_, _, t) when n > 0 ->
  59          aux 0 (pred n) (S.lift (-1) t)
  60       | t                  when n > 0 ->
  61          Printf.eprintf "CicPPP clear_absts: %u %s\n" n (Pp.ppterm t);
  62          assert false
  63       | t                                 -> t
  64    in
  65    aux m
  66
  67 let rec add_abst k = function
  68    | C.Lambda (s, v, t) when k > 0 -> C.Lambda (s, v, add_abst (pred k) t)
  69    | t when k > 0 -> assert false
  70    | t -> C.Lambda (C.Anonymous, C.Implicit None, S.lift 1 t)
  71
  72 let rec opt1_letin g es c name v w t =
  73    let name = H.mk_fresh_name c name in
  74    let entry = Some (name, C.Def (v, w)) in
  75    let g t =
  76       if DTI.does_not_occur 1 t then begin
  77          let x = S.lift (-1) t in
  78          HLog.warn "Optimizer: remove 1"; opt1_proof g true c x
  79       end else
  80       let g = function
  81          | C.LetIn (nname, vv, ww, tt) when H.is_proof c v ->
  82             let eentry = Some (nname, C.Def (vv, ww)) in
  83             let ttw = get_type "opt1_letin 1" (eentry :: c) tt in
  84             let x = C.LetIn (nname, vv, ww,
  85              C.LetIn (name, tt, ttw, S.lift_from 2 1 t)) in
  86             HLog.warn "Optimizer: swap 1"; opt1_proof g true c x
  87          | v when H.is_proof c v && H.is_atomic v     ->
  88             let x = S.subst v t in
  89             HLog.warn "Optimizer: remove 5"; opt1_proof g true c x
  90          | v                                           ->
  91             g (C.LetIn (name, v, w, t))
  92       in
  93       if es then opt1_term g es c v else g v
  94    in
  95    if es then opt1_proof g es (entry :: c) t else g t
  96
  97 and opt1_lambda g es c name w t =
  98    let name = H.mk_fresh_name c name in
  99    let entry = Some (name, C.Decl w) in
 100    let g t = g (C.Lambda (name, w, t)) in
 101    if es then opt1_proof g es (entry :: c) t else g t
 102
 103 and opt1_appl g es c t vs =
 104    let g vs =
 105       let g = function
 106          | C.LetIn (mame, vv, tyty, tt) ->
 107             let vs = List.map (S.lift 1) vs in
 108             let x = C.LetIn (mame, vv, tyty, C.Appl (tt :: vs)) in
 109             HLog.warn "Optimizer: swap 2"; opt1_proof g true c x
 110          | C.Lambda (name, ww, tt) ->
 111             let v, vs = List.hd vs, List.tl vs in
 112             let w = get_type "opt1_appl 1" c v in
 113             let x = C.Appl (C.LetIn (name, v, w, tt) :: vs) in
 114             HLog.warn "Optimizer: remove 2"; opt1_proof g true c x
 115          | C.Appl vvs              ->
 116             let x = C.Appl (vvs @ vs) in
 117             HLog.warn "Optimizer: nested application"; opt1_proof g true c x
 118          | t                       ->
 119             let rec aux d rvs = function
 120                | [], _                   ->
 121                   let x = C.Appl (t :: List.rev rvs) in
 122                   if d then opt1_proof g true c x else g x
 123                | v :: vs, (cc, bb) :: cs ->
 124                   if H.is_not_atomic v && I.S.mem 0 cc && bb then begin
 125                      HLog.warn "Optimizer: anticipate 1";
 126                      aux true (define c v :: rvs) (vs, cs)
 127                   end else
 128                      aux d (v :: rvs) (vs, cs)
 129                | _, []                   -> assert false
 130             in
 131             let h () =
 132                let classes, conclusion = Cl.classify c (H.get_type c t) in
 133                let csno, vsno = List.length classes, List.length vs in
 134                if csno < vsno then
 135                   let vvs, vs = HEL.split_nth csno vs in
 136                   let x = C.Appl (define c (C.Appl (t :: vvs)) :: vs) in
 137                   HLog.warn "Optimizer: anticipate 2"; opt1_proof g true c x
 138                else match conclusion, List.rev vs with
 139                   | Some _, rv :: rvs when csno = vsno && H.is_not_atomic rv ->
 140                      let x = C.Appl (t :: List.rev rvs @ [define c rv]) in
 141                      HLog.warn "Optimizer: anticipate 3"; opt1_proof g true c x
 142                   | _ (* Some _, _ *)                                             ->
 143                      g (C.Appl (t :: vs))
 144 (*                | None, _                                                ->
 145                      aux false [] (vs, classes)
 146 *)          in
 147             let rec aux h prev = function
 148                | C.LetIn (name, vv, tyty, tt) :: vs ->
 149                   let t = S.lift 1 t in
 150                   let prev = List.map (S.lift 1) prev in
 151                   let vs = List.map (S.lift 1) vs in
 152                   let y = C.Appl (t :: List.rev prev @ tt :: vs) in
 153                   let ww = get_type "opt1_appl 2" c vv in
 154                   let x = C.LetIn (name, vv, ww, y) in
 155                   HLog.warn "Optimizer: swap 3"; opt1_proof g true c x
 156                | v :: vs                      -> aux h (v :: prev) vs
 157                | []                           -> h ()
 158             in
 159             aux h [] vs
 160       in
 161       if es then opt1_proof g es c t else g t
 162    in
 163    if es then H.list_map_cps g (fun h -> opt1_term h es c) vs else g vs
 164
 165 and opt1_mutcase g es c uri tyno outty arg cases =
 166    let eliminator = H.get_default_eliminator c uri tyno outty in
 167    let lpsno, (_, _, _, constructors) = H.get_ind_type uri tyno in
 168    let ps, sort_disp = H.get_ind_parameters c arg in
 169    let lps, rps = HEL.split_nth lpsno ps in
 170    let rpsno = List.length rps in
 171    let predicate = clear_absts rpsno (1 - sort_disp) outty in
 172    let is_recursive t =
 173       I.S.mem tyno (I.get_mutinds_of_uri uri t)
 174    in
 175    let map2 case (_, cty) =
 176       let map (h, case, k) (_, premise) =
 177          if h > 0 then pred h, case, k else
 178          if is_recursive premise then
 179             0, add_abst k case, k + 2
 180          else
 181             0, case, succ k
 182       in
 183       let premises, _ = PEH.split_with_whd (c, cty) in
 184       let _, lifted_case, _ =
 185          List.fold_left map (lpsno, case, 1) (List.rev (List.tl premises))
 186       in
 187       lifted_case
 188    in
 189    let lifted_cases = List.map2 map2 cases constructors in
 190    let args = eliminator :: lps @ predicate :: lifted_cases @ rps @ [arg] in
 191    let x = H.refine c (C.Appl args) in
 192    HLog.warn "Optimizer: remove 3"; opt1_proof g es c x
 193
 194 and opt1_cast g es c t w =
 195    let g t = HLog.warn "Optimizer: remove 4"; g t in
 196    if es then  opt1_proof g es c t else g t
 197
 198 and opt1_other g es c t = g t
 199
 200 and opt1_proof g es c = function
 201    | C.LetIn (name, v, ty, t)   -> opt1_letin g es c name v ty t
 202    | C.Lambda (name, w, t)      -> opt1_lambda g es c name w t
 203    | C.Appl (t :: v :: vs)      -> opt1_appl g es c t (v :: vs)
 204    | C.Appl [t]                 -> opt1_proof g es c t
 205    | C.MutCase (u, n, t, v, ws) -> opt1_mutcase g es c u n t v ws
 206    | C.Cast (t, w)              -> opt1_cast g es c t w
 207    | t                          -> opt1_other g es c t
 208
 209 and opt1_term g es c t =
 210    if H.is_proof c t then opt1_proof g es c t else g t
 211
 212 (* term preprocessing: optomization 2 ***************************************)
 213
 214 let expanded_premise = "EXPANDED"
 215
 216 let eta_expand g tys t =
 217    assert (tys <> []);
 218    let name i = Printf.sprintf "%s%u" expanded_premise i in
 219    let lambda i ty t = C.Lambda (C.Name (name i), ty, t) in
 220    let arg i = C.Rel (succ i) in
 221    let rec aux i f a = function
 222       | []            -> f, a
 223       | (_, ty) :: tl -> aux (succ i) (H.compose f (lambda i ty)) (arg i :: a) tl
 224    in
 225    let n = List.length tys in
 226    let absts, args = aux 0 H.identity [] tys in
 227    let t = match S.lift n t with
 228       | C.Appl ts -> C.Appl (ts @ args)
 229       | t         -> C.Appl (t :: args)
 230    in
 231    g (absts t)
 232
 233 let rec opt2_letin g c name v w t =
 234    let entry = Some (name, C.Def (v, w)) in
 235    let g t =
 236       let g v = g (C.LetIn (name, v, w, t)) in
 237       opt2_term g c v
 238    in
 239    opt2_proof g (entry :: c) t
 240
 241 and opt2_lambda g c name w t =
 242    let entry = Some (name, C.Decl w) in
 243    let g t = g (C.Lambda (name, w, t)) in
 244    opt2_proof g (entry :: c) t
 245
 246 and opt2_appl g c t vs =
 247    let g vs =
 248       let x = C.Appl (t :: vs) in
 249       let vsno = List.length vs in
 250       let _, csno = PEH.split_with_whd (c, H.get_type c t) in
 251       if vsno < csno then
 252          let tys, _ = PEH.split_with_whd (c, H.get_type c x) in
 253          let tys = List.rev (List.tl tys) in
 254          let tys, _ = HEL.split_nth (csno - vsno) tys in
 255          HLog.warn "Optimizer: eta 1"; eta_expand g tys x
 256       else g x
 257    in
 258    H.list_map_cps g (fun h -> opt2_term h c) vs
 259
 260 and opt2_other g c t =
 261    let tys, csno = PEH.split_with_whd (c, H.get_type c t) in
 262    if csno > 0 then begin
 263       let tys = List.rev (List.tl tys) in
 264       HLog.warn "Optimizer: eta 2"; eta_expand g tys t
 265    end else g t
 266
 267 and opt2_proof g c = function
 268    | C.LetIn (name, v, w, t) -> opt2_letin g c name v w t
 269    | C.Lambda (name, w, t)   -> opt2_lambda g c name w t
 270    | C.Appl (t :: vs)        -> opt2_appl g c t vs
 271    | t                       -> opt2_other g c t
 272
 273 and opt2_term g c t =
 274    if H.is_proof c t then opt2_proof g c t else g t
 275
 276 (* object preprocessing *****************************************************)
 277
 278 let optimize_obj = function
 279    | C.Constant (name, Some bo, ty, pars, attrs) ->
 280       let bo, ty = H.cic_bc [] bo, H.cic_bc [] ty in
 281       let g bo =
 282          Printf.eprintf "Optimized : %s\nPost Nodes: %u\n"
 283             (Pp.ppterm bo) (I.count_nodes 0 bo);
 284          let _ = H.get_type [] (C.Cast (bo, ty)) in
 285          C.Constant (name, Some bo, ty, pars, attrs)
 286       in
 287       Printf.eprintf "BEGIN: %s\nPre Nodes : %u\n"
 288          name (I.count_nodes 0 bo);
 289       begin try opt1_term g (* (opt2_term g []) *) true [] bo
 290       with e -> failwith ("PPP: " ^ Printexc.to_string e) end
 291    | obj                                         -> obj