components/cic/cicParser.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 let debug = false
  29 let debug_print s = if debug then prerr_endline (Lazy.force s)
  30
  31 open Printf
  32
  33 (* ZACK TODO element from the DTD still to be handled:
  34    <!ELEMENT CurrentProof (Conjecture*,body)>
  35    <!ELEMENT Sequent %sequent;>
  36    <!ELEMENT Conjecture %sequent;>
  37    <!ELEMENT Decl %term;>
  38    <!ELEMENT Def %term;>
  39    <!ELEMENT Hidden EMPTY>
  40    <!ELEMENT Goal %term;>
  41 *)
  42
  43 exception Getter_failure of string * string
  44 exception Parser_failure of string
  45
  46 type stack_entry =
  47   | Arg of string * Cic.annterm (* relative uri, term *)
  48   (* constants' body and types resides in differne files, thus we can't simple
  49    * keep constants in Cic_obj stack entries *)
  50   | Cic_attributes of Cic.attribute list
  51   | Cic_constant_body of string * string * UriManager.uri list * Cic.annterm
  52       * Cic.attribute list
  53       (* id, for, params, body, object attributes *)
  54   | Cic_constant_type of string * string * UriManager.uri list * Cic.annterm
  55       * Cic.attribute list
  56       (* id, name, params, type, object attributes *)
  57   | Cic_term of Cic.annterm (* term *)
  58   | Cic_obj of Cic.annobj   (* object *)
  59   | Cofix_fun of Cic.id * string * Cic.annterm * Cic.annterm
  60       (* id, name, type, body *)
  61   | Constructor of string * Cic.annterm   (* name, type *)
  62   | Decl of Cic.id * Cic.name * Cic.annterm (* id, binder, source *)
  63   | Def of Cic.id * Cic.name * Cic.annterm * Cic.annterm  (* id, binder, source, type *)
  64   | Fix_fun of Cic.id * string * int * Cic.annterm * Cic.annterm
  65       (* id, name, ind. index, type, body *)
  66   | Inductive_type of string * string * bool * Cic.annterm *
  67       (string * Cic.annterm) list (* id, name, inductive, arity, constructors *)
  68   | Meta_subst of Cic.annterm option
  69   | Obj_class of Cic.object_class
  70   | Obj_flavour of Cic.object_flavour
  71   | Obj_field of string (* field name *)
  72   | Obj_generated
  73   | Tag of string * (string * string) list  (* tag name, attributes *)
  74       (* ZACK TODO add file position to tag stack entry so that when attribute
  75        * errors occur, the position of their _start_tag_ could be printed
  76        * instead of the current position (usually the end tag) *)
  77
  78 type ctxt = {
  79   mutable stack: stack_entry list;
  80   mutable xml_parser: XmlPushParser.xml_parser option;
  81   mutable filename: string;
  82   uri: UriManager.uri;
  83 }
  84
  85 let string_of_stack ctxt =
  86   "[" ^ (String.concat "; "
  87     (List.map
  88       (function
  89       | Arg (reluri, _) -> sprintf "Arg %s" reluri
  90       | Cic_attributes _ -> "Cic_attributes"
  91       | Cic_constant_body (id, name, _, _, _) ->
  92           sprintf "Cic_constant_body %s (id=%s)" name id
  93       | Cic_constant_type (id, name, _, _, _) ->
  94           sprintf "Cic_constant_type %s (id=%s)" name id
  95       | Cic_term _ -> "Cic_term"
  96       | Cic_obj _ -> "Cic_obj"
  97       | Constructor (name, _) -> "Constructor " ^ name
  98       | Cofix_fun (id, _, _, _) -> sprintf "Cofix_fun (id=%s)" id
  99       | Decl (id, _, _) -> sprintf "Decl (id=%s)" id
 100       | Def (id, _, _, _) -> sprintf "Def (id=%s)" id
 101       | Fix_fun (id, _, _, _, _) -> sprintf "Fix_fun (id=%s)" id
 102       | Inductive_type (id, name, _, _, _) ->
 103           sprintf "Inductive_type %s (id=%s)" name id
 104       | Meta_subst _ -> "Meta_subst"
 105       | Obj_class _ -> "Obj_class"
 106       | Obj_flavour _ -> "Obj_flavour"
 107       | Obj_field name -> "Obj_field " ^ name
 108       | Obj_generated -> "Obj_generated"
 109       | Tag (tag, _) -> "Tag " ^ tag)
 110       ctxt.stack)) ^ "]"
 111
 112 let compare_attrs (a1, v1) (a2, v2) = Pervasives.compare a1 a2
 113 let sort_attrs = List.sort compare_attrs
 114
 115 let new_parser_context uri = {
 116   stack = [];
 117   xml_parser = None;
 118   filename = "-";
 119   uri = uri;
 120 }
 121
 122 let get_parser ctxt =
 123   match ctxt.xml_parser with
 124   | Some p -> p
 125   | None -> assert false
 126
 127 (** {2 Error handling} *)
 128
 129 let parse_error ctxt msg =
 130   let (line, col) = XmlPushParser.get_position (get_parser ctxt) in
 131   raise (Parser_failure (sprintf "[%s: line %d, column %d] %s"
 132     ctxt.filename line col msg))
 133
 134 let attribute_error ctxt tag =
 135   parse_error ctxt ("wrong attribute set for " ^ tag)
 136
 137 (** {2 Parsing context management} *)
 138
 139 let pop ctxt =
 140 (*  debug_print (lazy "pop");*)
 141   match ctxt.stack with
 142   | hd :: tl -> (ctxt.stack <- tl)
 143   | _ -> assert false
 144
 145 let push ctxt v =
 146 (*  debug_print (lazy "push");*)
 147   ctxt.stack <- v :: ctxt.stack
 148
 149 let set_top ctxt v =
 150 (*  debug_print (lazy "set_top");*)
 151   match ctxt.stack with
 152   | _ :: tl -> (ctxt.stack <- v :: tl)
 153   | _ -> assert false
 154
 155   (** pop the last tag from the open tags stack returning a pair <tag_name,
 156    * attribute_list> *)
 157 let pop_tag ctxt =
 158   match ctxt.stack with
 159   | Tag (tag, attrs) :: tl ->
 160       ctxt.stack <- tl;
 161       (tag, attrs)
 162   | _ -> parse_error ctxt "unexpected extra content"
 163
 164   (** pop the last tag from the open tags stack returning its attributes.
 165    * Attributes are returned as a list of pair <name, value> _sorted_ by
 166    * attribute name *)
 167 let pop_tag_attrs ctxt = sort_attrs (snd (pop_tag ctxt))
 168
 169 let pop_cics ctxt =
 170   let rec aux acc stack =
 171     match stack with
 172     | Cic_term t :: tl -> aux (t :: acc) tl
 173     | tl -> acc, tl
 174   in
 175   let values, new_stack = aux [] ctxt.stack in
 176   ctxt.stack <- new_stack;
 177   values
 178
 179 let pop_class_modifiers ctxt =
 180   let rec aux acc stack =
 181     match stack with
 182     | (Cic_term (Cic.ASort _) as m) :: tl
 183     | (Obj_field _ as m) :: tl ->
 184         aux (m :: acc) tl
 185     | tl -> acc, tl
 186   in
 187   let values, new_stack = aux [] ctxt.stack in
 188   ctxt.stack <- new_stack;
 189   values
 190
 191 let pop_meta_substs ctxt =
 192   let rec aux acc stack =
 193     match stack with
 194     | Meta_subst t :: tl -> aux (t :: acc) tl
 195     | tl -> acc, tl
 196   in
 197   let values, new_stack = aux [] ctxt.stack in
 198   ctxt.stack <- new_stack;
 199   values
 200
 201 let pop_fix_funs ctxt =
 202   let rec aux acc stack =
 203     match stack with
 204     | Fix_fun (id, name, index, typ, body) :: tl ->
 205         aux ((id, name, index, typ, body) :: acc) tl
 206     | tl -> acc, tl
 207   in
 208   let values, new_stack = aux [] ctxt.stack in
 209   ctxt.stack <- new_stack;
 210   values
 211
 212 let pop_cofix_funs ctxt =
 213   let rec aux acc stack =
 214     match stack with
 215     | Cofix_fun (id, name, typ, body) :: tl ->
 216         aux ((id, name, typ, body) :: acc) tl
 217     | tl -> acc, tl
 218   in
 219   let values, new_stack = aux [] ctxt.stack in
 220   ctxt.stack <- new_stack;
 221   values
 222
 223 let pop_constructors ctxt =
 224   let rec aux acc stack =
 225     match stack with
 226     | Constructor (name, t) :: tl -> aux ((name, t) :: acc) tl
 227     | tl -> acc, tl
 228   in
 229   let values, new_stack = aux [] ctxt.stack in
 230   ctxt.stack <- new_stack;
 231   values
 232
 233 let pop_inductive_types ctxt =
 234   let rec aux acc stack =
 235     match stack with
 236     | Inductive_type (id, name, ind, arity, ctors) :: tl ->
 237         aux ((id, name, ind, arity, ctors) :: acc) tl
 238     | tl -> acc, tl
 239   in
 240   let values, new_stack = aux [] ctxt.stack in
 241   if values = [] then
 242     parse_error ctxt "no \"InductiveType\" element found";
 243   ctxt.stack <- new_stack;
 244   values
 245
 246   (** travels the stack (without popping) for the first term subject of explicit
 247    * named substitution and return its URI *)
 248 let find_base_uri ctxt =
 249   let rec aux = function
 250     | Cic_term (Cic.AConst (_, uri, _)) :: _
 251     | Cic_term (Cic.AMutInd (_, uri, _, _)) :: _
 252     | Cic_term (Cic.AMutConstruct (_, uri, _, _, _)) :: _
 253     | Cic_term (Cic.AVar (_, uri, _)) :: _ ->
 254         uri
 255     | Arg _ :: tl -> aux tl
 256     | _ -> parse_error ctxt "no \"arg\" element found"
 257   in
 258   UriManager.buri_of_uri (aux ctxt.stack)
 259
 260   (** backwardly eats the stack building an explicit named substitution from Arg
 261    * stack entries *)
 262 let pop_subst ctxt base_uri =
 263   let rec aux acc stack =
 264     match stack with
 265     | Arg (rel_uri, term) :: tl ->
 266         let uri = UriManager.uri_of_string (base_uri ^ "/" ^ rel_uri) in
 267         aux ((uri, term) :: acc) tl
 268     | tl -> acc, tl
 269   in
 270   let subst, new_stack = aux [] ctxt.stack in
 271   if subst = [] then
 272     parse_error ctxt "no \"arg\" element found";
 273   ctxt.stack <- new_stack;
 274   subst
 275
 276 let pop_cic ctxt =
 277   match ctxt.stack with
 278   | Cic_term t :: tl ->
 279       ctxt.stack <- tl;
 280       t
 281   | _ -> parse_error ctxt "no cic term found"
 282
 283 let pop_obj_attributes ctxt =
 284   match ctxt.stack with
 285   | Cic_attributes attributes :: tl ->
 286       ctxt.stack <- tl;
 287       attributes
 288   | _ -> []
 289
 290 (** {2 Auxiliary functions} *)
 291
 292 let uri_of_string = UriManager.uri_of_string
 293
 294 let uri_list_of_string =
 295   let space_RE = Str.regexp " " in
 296   fun s ->
 297     List.map uri_of_string (Str.split space_RE s)
 298
 299 let impredicative_set = ref true;;
 300
 301 let sort_of_string ctxt = function
 302   | "Prop" -> Cic.Prop
 303   | "CProp" -> Cic.CProp
 304   (* THIS CASE IS HERE ONLY TO ALLOW THE PARSING OF COQ LIBRARY
 305    * THIS SHOULD BE REMOVED AS SOON AS univ_maker OR COQ'S EXPORTATION
 306    * IS FIXED *)
 307   | "Type" ->  Cic.Type (CicUniv.fresh ~uri:ctxt.uri ())
 308   | "Set" when !impredicative_set -> Cic.Set
 309   | "Set" -> Cic.Type (CicUniv.fresh ~uri:ctxt.uri ())
 310   | s ->
 311       let len = String.length s in
 312       if not(len > 5) then parse_error ctxt "sort expected";
 313       if not(String.sub s 0 5 = "Type:") then parse_error ctxt "sort expected";
 314       try
 315         Cic.Type
 316           (CicUniv.fresh
 317             ~uri:ctxt.uri
 318             ~id:(int_of_string (String.sub s 5 (len - 5))) ())
 319       with
 320       | Failure "int_of_string"
 321       | Invalid_argument _ -> parse_error ctxt "sort expected"
 322
 323 let patch_subst ctxt subst = function
 324   | Cic.AConst (id, uri, _) -> Cic.AConst (id, uri, subst)
 325   | Cic.AMutInd (id, uri, typeno, _) ->
 326       Cic.AMutInd (id, uri, typeno, subst)
 327   | Cic.AMutConstruct (id, uri, typeno, consno, _) ->
 328       Cic.AMutConstruct (id, uri, typeno, consno, subst)
 329   | Cic.AVar (id, uri, _) -> Cic.AVar (id, uri, subst)
 330   | _ ->
 331       parse_error ctxt
 332         ("only \"CONST\", \"VAR\", \"MUTIND\", and \"MUTCONSTRUCT\" can be" ^
 333         " instantiated")
 334
 335   (** backwardly eats the stack seeking for the first open tag carrying
 336    * "helm:exception" attributes. If found return Some of a pair containing
 337    * exception name and argument. Return None otherwise *)
 338 let find_helm_exception ctxt =
 339   let rec aux = function
 340     | [] -> None
 341     | Tag (_, attrs) :: tl ->
 342         (try
 343           let exn = List.assoc "helm:exception" attrs in
 344           let arg =
 345             try List.assoc "helm:exception_arg" attrs with Not_found -> ""
 346           in
 347           Some (exn, arg)
 348         with Not_found -> aux tl)
 349     | _ :: tl -> aux tl
 350   in
 351   aux ctxt.stack
 352
 353 (** {2 Push parser callbacks}
 354  * each callback needs to be instantiated to a parsing context *)
 355
 356 let start_element ctxt tag attrs =
 357 (*  debug_print (lazy (sprintf "<%s%s>" tag (match attrs with | [] -> "" | _ -> " " ^ String.concat " " (List.map (fun (a,v) -> sprintf "%s=\"%s\"" a v) attrs))));*)
 358   push ctxt (Tag (tag, attrs))
 359
 360 let end_element ctxt tag =
 361 (*  debug_print (lazy (sprintf "</%s>" tag));*)
 362 (*  debug_print (lazy (string_of_stack ctxt));*)
 363   let attribute_error () = attribute_error ctxt tag in
 364   let parse_error = parse_error ctxt in
 365   let sort_of_string = sort_of_string ctxt in
 366   match tag with
 367   | "REL" ->
 368       push ctxt (Cic_term
 369         (match pop_tag_attrs ctxt with
 370         | ["binder", binder; "id", id; "idref", idref; "value", value]
 371         | ["binder", binder; "id", id; "idref", idref; "sort", _;
 372            "value", value] ->
 373             Cic.ARel (id, idref, int_of_string value, binder)
 374         | _ -> attribute_error ()))
 375   | "VAR" ->
 376       push ctxt (Cic_term
 377         (match pop_tag_attrs ctxt with
 378         | ["id", id; "uri", uri]
 379         | ["id", id; "sort", _; "uri", uri] ->
 380             Cic.AVar (id, uri_of_string uri, [])
 381         | _ -> attribute_error ()))
 382   | "CONST" ->
 383       push ctxt (Cic_term
 384         (match pop_tag_attrs ctxt with
 385         | ["id", id; "uri", uri]
 386         | ["id", id; "sort", _; "uri", uri] ->
 387             Cic.AConst (id, uri_of_string uri, [])
 388         | _ -> attribute_error ()))
 389   | "SORT" ->
 390       push ctxt (Cic_term
 391         (match pop_tag_attrs ctxt with
 392         | ["id", id; "value", sort] -> Cic.ASort (id, sort_of_string sort)
 393         | _ -> attribute_error ()))
 394   | "APPLY" ->
 395       let args = pop_cics ctxt in
 396       push ctxt (Cic_term
 397         (match pop_tag_attrs ctxt with
 398         | ["id", id ]
 399         | ["id", id; "sort", _] -> Cic.AAppl (id, args)
 400         | _ -> attribute_error ()))
 401   | "decl" ->
 402       let source = pop_cic ctxt in
 403       push ctxt
 404         (match pop_tag_attrs ctxt with
 405         | ["binder", binder; "id", id ]
 406         | ["binder", binder; "id", id; "type", _] ->
 407             Decl (id, Cic.Name binder, source)
 408         | ["id", id]
 409         | ["id", id; "type", _] -> Decl (id, Cic.Anonymous, source)
 410         | _ -> attribute_error ())
 411   | "def" ->  (* same as "decl" above *)
 412       let ty,source =
 413        (*CSC: hack to parse Coq files where the LetIn is not typed *)
 414        let ty = pop_cic ctxt in
 415        try
 416         let source = pop_cic ctxt in
 417          ty,source
 418        with
 419         Parser_failure _ -> Cic.AImplicit ("MISSING_def_TYPE",None),ty
 420       in
 421       push ctxt
 422         (match pop_tag_attrs ctxt with
 423         | ["binder", binder; "id", id]
 424         | ["binder", binder; "id", id; "sort", _] ->
 425             Def (id, Cic.Name binder, source, ty)
 426         | ["id", id]
 427         | ["id", id; "sort", _] -> Def (id, Cic.Anonymous, source, ty)
 428         | _ -> attribute_error ())
 429   | "arity"           (* transparent elements (i.e. which contain a CIC) *)
 430   | "body"
 431   | "inductiveTerm"
 432   | "pattern"
 433   | "patternsType"
 434   | "target"
 435   | "term"
 436   | "type" ->
 437       let term = pop_cic ctxt in
 438       pop ctxt; (* pops start tag matching current end tag (e.g. <arity>) *)
 439       push ctxt (Cic_term term)
 440   | "substitution" ->   (* optional transparent elements (i.e. which _may_
 441                          * contain a CIC) *)
 442       set_top ctxt  (* replace <substitution> *)
 443         (match ctxt.stack with
 444         | Cic_term term :: tl ->
 445             ctxt.stack <- tl;
 446             (Meta_subst (Some term))
 447         | _ ->  Meta_subst None)
 448   | "PROD" ->
 449       let target = pop_cic ctxt in
 450       let rec add_decl target = function
 451         | Decl (id, binder, source) :: tl ->
 452             add_decl (Cic.AProd (id, binder, source, target)) tl
 453         | tl ->
 454             ctxt.stack <- tl;
 455             target
 456       in
 457       let term = add_decl target ctxt.stack in
 458       (match pop_tag_attrs ctxt with
 459         []
 460       | ["type", _] -> ()
 461       | _ -> attribute_error ());
 462       push ctxt (Cic_term term)
 463   | "LAMBDA" ->
 464       let target = pop_cic ctxt in
 465       let rec add_decl target = function
 466         | Decl (id, binder, source) :: tl ->
 467             add_decl (Cic.ALambda (id, binder, source, target)) tl
 468         | tl ->
 469             ctxt.stack <- tl;
 470             target
 471       in
 472       let term = add_decl target ctxt.stack in
 473       (match pop_tag_attrs ctxt with
 474         []
 475       | ["sort", _] -> ()
 476       | _ -> attribute_error ());
 477       push ctxt (Cic_term term)
 478   | "LETIN" ->
 479       let target = pop_cic ctxt in
 480       let rec add_def target = function
 481         | Def (id, binder, source, ty) :: tl ->
 482             add_def (Cic.ALetIn (id, binder, source, ty, target)) tl
 483         | tl ->
 484             ctxt.stack <- tl;
 485             target
 486       in
 487       let term = add_def target ctxt.stack in
 488       (match pop_tag_attrs ctxt with
 489         []
 490       | ["sort", _] -> ()
 491       | _ -> attribute_error ());
 492       push ctxt (Cic_term term)
 493   | "CAST" ->
 494       let typ = pop_cic ctxt in
 495       let term = pop_cic ctxt in
 496       push ctxt (Cic_term
 497         (match pop_tag_attrs ctxt with
 498           ["id", id]
 499         | ["id", id; "sort", _] -> Cic.ACast (id, term, typ)
 500         | _ -> attribute_error ()));
 501   | "IMPLICIT" ->
 502       push ctxt (Cic_term
 503         (match pop_tag_attrs ctxt with
 504         | ["id", id] -> Cic.AImplicit (id, None)
 505         | ["annotation", annotation; "id", id] ->
 506             let implicit_annotation =
 507               match annotation with
 508               | "closed" -> `Closed
 509               | "hole" -> `Hole
 510               | "type" -> `Type
 511               | _ -> parse_error "invalid value for \"annotation\" attribute"
 512             in
 513             Cic.AImplicit (id, Some implicit_annotation)
 514         | _ -> attribute_error ()))
 515   | "META" ->
 516       let meta_substs = pop_meta_substs ctxt in
 517       push ctxt (Cic_term
 518         (match pop_tag_attrs ctxt with
 519         | ["id", id; "no", no]
 520         | ["id", id; "no", no; "sort", _] ->
 521             Cic.AMeta (id, int_of_string no, meta_substs)
 522         | _ -> attribute_error ()));
 523   | "MUTIND" ->
 524       push ctxt (Cic_term
 525         (match pop_tag_attrs ctxt with
 526         | ["id", id; "noType", noType; "uri", uri] ->
 527             Cic.AMutInd (id, uri_of_string uri, int_of_string noType, [])
 528         | _ -> attribute_error ()));
 529   | "MUTCONSTRUCT" ->
 530       push ctxt (Cic_term
 531         (match pop_tag_attrs ctxt with
 532         | ["id", id; "noConstr", noConstr; "noType", noType; "uri", uri]
 533         | ["id", id; "noConstr", noConstr; "noType", noType; "sort", _;
 534            "uri", uri] ->
 535             Cic.AMutConstruct (id, uri_of_string uri, int_of_string noType,
 536               int_of_string noConstr, [])
 537         | _ -> attribute_error ()));
 538   | "FixFunction" ->
 539       let body = pop_cic ctxt in
 540       let typ = pop_cic ctxt in
 541       push ctxt
 542         (match pop_tag_attrs ctxt with
 543         | ["id", id; "name", name; "recIndex", recIndex] ->
 544             Fix_fun (id, name, int_of_string recIndex, typ, body)
 545         | _ -> attribute_error ())
 546   | "CofixFunction" ->
 547       let body = pop_cic ctxt in
 548       let typ = pop_cic ctxt in
 549       push ctxt
 550         (match pop_tag_attrs ctxt with
 551         | ["id", id; "name", name] ->
 552             Cofix_fun (id, name, typ, body)
 553         | _ -> attribute_error ())
 554   | "FIX" ->
 555       let fix_funs = pop_fix_funs ctxt in
 556       push ctxt (Cic_term
 557         (match pop_tag_attrs ctxt with
 558         | ["id", id; "noFun", noFun]
 559         | ["id", id; "noFun", noFun; "sort", _] ->
 560             Cic.AFix (id, int_of_string noFun, fix_funs)
 561         | _ -> attribute_error ()))
 562   | "COFIX" ->
 563       let cofix_funs = pop_cofix_funs ctxt in
 564       push ctxt (Cic_term
 565         (match pop_tag_attrs ctxt with
 566         | ["id", id; "noFun", noFun]
 567         | ["id", id; "noFun", noFun; "sort", _] ->
 568             Cic.ACoFix (id, int_of_string noFun, cofix_funs)
 569         | _ -> attribute_error ()))
 570   | "MUTCASE" ->
 571       (match pop_cics ctxt with
 572       | patternsType :: inductiveTerm :: patterns ->
 573           push ctxt (Cic_term
 574             (match pop_tag_attrs ctxt with
 575             | ["id", id; "noType", noType; "uriType", uriType]
 576             | ["id", id; "noType", noType; "sort", _; "uriType", uriType] ->
 577                 Cic.AMutCase (id, uri_of_string uriType, int_of_string noType,
 578                   patternsType, inductiveTerm, patterns)
 579             | _ -> attribute_error ()))
 580       | _ -> parse_error "invalid \"MUTCASE\" content")
 581   | "Constructor" ->
 582       let typ = pop_cic ctxt in
 583       push ctxt
 584         (match pop_tag_attrs ctxt with
 585         | ["name", name] -> Constructor (name, typ)
 586         | _ -> attribute_error ())
 587   | "InductiveType" ->
 588       let constructors = pop_constructors ctxt in
 589       let arity = pop_cic ctxt in
 590       push ctxt
 591         (match pop_tag_attrs ctxt with
 592         | ["id", id; "inductive", inductive; "name", name] ->
 593             Inductive_type (id, name, bool_of_string inductive, arity,
 594               constructors)
 595         | _ -> attribute_error ())
 596   | "InductiveDefinition" ->
 597       let inductive_types = pop_inductive_types ctxt in
 598       let obj_attributes = pop_obj_attributes ctxt in
 599       push ctxt (Cic_obj
 600         (match pop_tag_attrs ctxt with
 601         | ["id", id; "noParams", noParams; "params", params] ->
 602             Cic.AInductiveDefinition (id, inductive_types,
 603               uri_list_of_string params, int_of_string noParams, obj_attributes)
 604         | _ -> attribute_error ()))
 605   | "ConstantType" ->
 606       let typ = pop_cic ctxt in
 607       let obj_attributes = pop_obj_attributes ctxt in
 608       push ctxt
 609         (match pop_tag_attrs ctxt with
 610         | ["id", id; "name", name; "params", params] ->
 611             Cic_constant_type (id, name, uri_list_of_string params, typ,
 612               obj_attributes)
 613         | _ -> attribute_error ())
 614   | "ConstantBody" ->
 615       let body = pop_cic ctxt in
 616       let obj_attributes = pop_obj_attributes ctxt in
 617       push ctxt
 618         (match pop_tag_attrs ctxt with
 619         | ["for", for_; "id", id; "params", params] ->
 620             Cic_constant_body (id, for_, uri_list_of_string params, body,
 621               obj_attributes)
 622         | _ -> attribute_error ())
 623   | "Variable" ->
 624       let typ = pop_cic ctxt in
 625       let body =
 626         match pop_cics ctxt with
 627         | [] -> None
 628         | [t] -> Some t
 629         | _ -> parse_error "wrong content for \"Variable\""
 630       in
 631       let obj_attributes = pop_obj_attributes ctxt in
 632       push ctxt (Cic_obj
 633         (match pop_tag_attrs ctxt with
 634         | ["id", id; "name", name; "params", params] ->
 635             Cic.AVariable (id, name, body, typ, uri_list_of_string params,
 636               obj_attributes)
 637         | _ -> attribute_error ()))
 638   | "arg" ->
 639       let term = pop_cic ctxt in
 640       push ctxt
 641         (match pop_tag_attrs ctxt with
 642         | ["relUri", relUri] -> Arg (relUri, term)
 643         | _ -> attribute_error ())
 644   | "instantiate" ->
 645         (* explicit named substitution handling: when the end tag of an element
 646          * subject of exlicit named subst (MUTIND, MUTCONSTRUCT, CONST, VAR) it
 647          * is stored on the stack with no substitutions (i.e. []). When the end
 648          * tag of an "instantiate" element is found we patch the term currently
 649          * on the stack with the substitution built from "instantiate" children
 650          *)
 651         (* XXX inefficiency here: first travels the <arg> elements in order to
 652          * find the baseUri, then in order to build the explicit named subst *)
 653       let base_uri = find_base_uri ctxt in
 654       let subst = pop_subst ctxt base_uri in
 655       let term = pop_cic ctxt in
 656         (* comment from CicParser3.ml:
 657          * CSC: the "id" optional attribute should be parsed and reflected in
 658          *      Cic.annterm and id = string_of_xml_attr (n#attribute "id") *)
 659         (* replace <instantiate> *)
 660       set_top ctxt (Cic_term (patch_subst ctxt subst term))
 661   | "attributes" ->
 662       let rec aux acc = function  (* retrieve object attributes *)
 663         | Obj_class c :: tl -> aux (`Class c :: acc) tl
 664         | Obj_flavour f :: tl -> aux (`Flavour f :: acc) tl
 665         | Obj_generated :: tl -> aux (`Generated :: acc) tl
 666         | tl -> acc, tl
 667       in
 668       let obj_attrs, new_stack = aux [] ctxt.stack in
 669       ctxt.stack <- new_stack;
 670       set_top ctxt (Cic_attributes obj_attrs)
 671   | "generated" -> set_top ctxt Obj_generated
 672   | "field" ->
 673       push ctxt
 674         (match pop_tag_attrs ctxt with
 675         | ["name", name] -> Obj_field name
 676         | _ -> attribute_error ())
 677   | "flavour" ->
 678       push ctxt
 679         (match pop_tag_attrs ctxt with
 680         | [ "value", "definition"] -> Obj_flavour `Definition
 681         | [ "value", "mutual_definition"] -> Obj_flavour `MutualDefinition
 682         | [ "value", "fact"] -> Obj_flavour `Fact
 683         | [ "value", "lemma"] -> Obj_flavour `Lemma
 684         | [ "value", "remark"] -> Obj_flavour `Remark
 685         | [ "value", "theorem"] -> Obj_flavour `Theorem
 686         | [ "value", "variant"] -> Obj_flavour `Variant
 687         | [ "value", "axiom"] -> Obj_flavour `Axiom
 688         | _ -> attribute_error ())
 689   | "class" ->
 690       let class_modifiers = pop_class_modifiers ctxt in
 691       push ctxt
 692         (match pop_tag_attrs ctxt with
 693         | ["value", "coercion"] -> Obj_class (`Coercion 0)
 694         | ("value", "coercion")::["arity",n]
 695         | ("arity",n)::["value", "coercion"] ->
 696             let arity = try int_of_string n with Failure _ ->
 697               parse_error "\"arity\" must be an integer"
 698             in
 699             Obj_class (`Coercion arity)
 700         | ["value", "elim"] ->
 701             (match class_modifiers with
 702             | [Cic_term (Cic.ASort (_, sort))] -> Obj_class (`Elim sort)
 703             | _ ->
 704                 parse_error
 705                   "unexpected extra content for \"elim\" object class")
 706         | ["value", "record"] ->
 707             let fields =
 708               List.map
 709                 (function
 710                   | Obj_field name ->
 711                       (match Str.split (Str.regexp " ") name with
 712                       | [name] -> name, false, 0
 713                       | [name;"coercion"] -> name,true,0
 714                       | [name;"coercion"; n] ->
 715                           let n =
 716                             try int_of_string n
 717                             with Failure _ ->
 718                               parse_error "int expected after \"coercion\""
 719                           in
 720                           name,true,n
 721                       | _ ->
 722                           parse_error
 723                             "wrong \"field\"'s name attribute")
 724                   | _ ->
 725                       parse_error
 726                         "unexpected extra content for \"record\" object class")
 727                 class_modifiers
 728             in
 729             Obj_class (`Record fields)
 730         | ["value", "projection"] -> Obj_class `Projection
 731         | ["value", "inversion"] -> Obj_class `InversionPrinciple
 732         | _ -> attribute_error ())
 733   | tag ->
 734       match find_helm_exception ctxt with
 735       | Some (exn, arg) -> raise (Getter_failure (exn, arg))
 736       | None -> parse_error (sprintf "unknown element \"%s\"" tag)
 737
 738 (** {2 Parser internals} *)
 739
 740 let has_gz_suffix fname =
 741   try
 742     let idx = String.rindex fname '.' in
 743     let suffix = String.sub fname idx (String.length fname - idx) in
 744     suffix = ".gz"
 745   with Not_found -> false
 746
 747 let parse uri filename =
 748   let ctxt = new_parser_context uri in
 749   ctxt.filename <- filename;
 750   let module P = XmlPushParser in
 751   let callbacks = {
 752     P.default_callbacks with
 753       P.start_element = Some (start_element ctxt);
 754       P.end_element = Some (end_element ctxt);
 755   } in
 756   let xml_parser = P.create_parser callbacks in
 757   ctxt.xml_parser <- Some xml_parser;
 758   try
 759     (try
 760       let xml_source =
 761         if has_gz_suffix filename then `Gzip_file filename
 762         else `File filename
 763       in
 764       P.parse xml_parser xml_source
 765     with exn ->
 766       ctxt.xml_parser <- None;
 767       (* ZACK: the above "<- None" is vital for garbage collection. Without it
 768        * we keep in memory a circular structure parser -> callbacks -> ctxt ->
 769        * parser. I don't know if the ocaml garbage collector is supposed to
 770        * collect such structures, but for sure the expat bindings will (orribly)
 771        * leak when used in conjunction with such structures *)
 772       raise exn);
 773     ctxt.xml_parser <- None; (* ZACK: same comment as above *)
 774 (*    debug_print (lazy (string_of_stack stack));*)
 775     (* assert (List.length ctxt.stack = 1) *)
 776     List.hd ctxt.stack
 777   with
 778   | Failure "int_of_string" -> parse_error ctxt "integer number expected"
 779   | Invalid_argument "bool_of_string" -> parse_error ctxt "boolean expected"
 780   | P.Parse_error msg -> parse_error ctxt ("parse error: " ^ msg)
 781   | Sys.Break
 782   | Parser_failure _
 783   | Getter_failure _ as exn ->
 784       raise exn
 785   | exn ->
 786       raise (Parser_failure ("CicParser: uncaught exception: " ^ Printexc.to_string exn))
 787
 788 (** {2 API implementation} *)
 789
 790 let annobj_of_xml uri filename filenamebody =
 791   match filenamebody with
 792   | None ->
 793       (match parse uri filename with
 794       | Cic_constant_type (id, name, params, typ, obj_attributes) ->
 795           Cic.AConstant (id, None, name, None, typ, params, obj_attributes)
 796       | Cic_obj obj -> obj
 797       | _ -> raise (Parser_failure ("no object found in " ^ filename)))
 798   | Some filenamebody ->
 799       (match parse uri filename, parse uri filenamebody with
 800       | Cic_constant_type (type_id, name, params, typ, obj_attributes),
 801         Cic_constant_body (body_id, _, _, body, _) ->
 802           Cic.AConstant (type_id, Some body_id, name, Some body, typ, params,obj_attributes)
 803       | _ ->
 804           raise (Parser_failure (sprintf "no constant found in %s, %s"
 805             filename filenamebody)))
 806
 807 let obj_of_xml uri filename filenamebody =
 808  Deannotate.deannotate_obj (annobj_of_xml uri filename filenamebody)