components/cic/unshare.ml

   1 (* Copyright (C) 2000, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* $Id$ *)
  27
  28 let unshare ?(fresh_univs=false) t =
  29  let module C = Cic in
  30  let rec unshare =
  31   function
  32      C.Rel m -> C.Rel m
  33    | C.Var (uri,exp_named_subst) ->
  34       let exp_named_subst' =
  35        List.map (function (uri,t) -> (uri,unshare t)) exp_named_subst
  36       in
  37        C.Var (uri,exp_named_subst')
  38    | C.Meta (i,l) ->
  39       let l' =
  40        List.map
  41         (function
  42             None -> None
  43           | Some t -> Some (unshare t)
  44         ) l
  45       in
  46        C.Meta(i,l')
  47    | C.Sort s when not fresh_univs -> C.Sort s
  48    | C.Sort (C.Type _) -> C.Sort (C.Type (CicUniv.fresh ()))
  49    | C.Sort s -> C.Sort s
  50    | C.Implicit info -> C.Implicit info
  51    | C.Cast (te,ty) -> C.Cast (unshare te, unshare ty)
  52    | C.Prod (n,s,t) -> C.Prod (n, unshare s, unshare t)
  53    | C.Lambda (n,s,t) -> C.Lambda (n, unshare s, unshare t)
  54    | C.LetIn (n,s,ty,t) ->
  55       C.LetIn (n, unshare s, unshare ty, unshare t)
  56    | C.Appl l -> C.Appl (List.map unshare l)
  57    | C.Const (uri,exp_named_subst) ->
  58       let exp_named_subst' =
  59        List.map (function (uri,t) -> (uri,unshare t)) exp_named_subst
  60       in
  61        C.Const (uri,exp_named_subst')
  62    | C.MutInd (uri,tyno,exp_named_subst) ->
  63       let exp_named_subst' =
  64        List.map (function (uri,t) -> (uri,unshare t)) exp_named_subst
  65       in
  66        C.MutInd (uri,tyno,exp_named_subst')
  67    | C.MutConstruct (uri,tyno,consno,exp_named_subst) ->
  68       let exp_named_subst' =
  69        List.map (function (uri,t) -> (uri,unshare t)) exp_named_subst
  70       in
  71        C.MutConstruct (uri,tyno,consno,exp_named_subst')
  72    | C.MutCase (sp,i,outty,t,pl) ->
  73       C.MutCase (sp, i, unshare outty, unshare t,
  74        List.map unshare pl)
  75    | C.Fix (i, fl) ->
  76       let liftedfl =
  77        List.map
  78         (fun (name, i, ty, bo) -> (name, i, unshare ty, unshare bo))
  79          fl
  80       in
  81        C.Fix (i, liftedfl)
  82    | C.CoFix (i, fl) ->
  83       let liftedfl =
  84        List.map
  85         (fun (name, ty, bo) -> (name, unshare ty, unshare bo))
  86          fl
  87       in
  88        C.CoFix (i, liftedfl)
  89  in
  90   unshare t
  91 ;;
  92
  93 let sharing_map f l =
  94   let unchanged = ref true in
  95   let rec aux b = function
  96     | [] as t -> unchanged := b; t
  97     | he::tl ->
  98         let he1 = f he in
  99         he1 :: aux (b && he1 == he) tl
 100   in
 101   let l1 = aux true l in
 102   if !unchanged then l else l1
 103 ;;
 104
 105 let fresh_univs t =
 106  let module C = Cic in
 107  let rec unshare =
 108   function
 109    | C.Sort (C.Type u) when not (CicUniv.is_anon u) -> C.Sort (C.Type (CicUniv.fresh ()))
 110    | C.Sort _ | C.Implicit _ | C.Var _ | C.Rel _ as t -> t
 111    | C.Meta (i,l) as orig ->
 112       let l' = sharing_map
 113         (function None -> None | Some t -> Some (unshare t)) l
 114       in
 115       if l == l' then orig else C.Meta(i,l')
 116    | C.Cast (te,ty) as orig ->
 117       let te' = unshare te in
 118       let ty' = unshare ty in
 119       if te' == te && ty' == ty then orig else C.Cast(te', ty')
 120    | C.Prod (n,s,t) as orig ->
 121       let s' = unshare s in
 122       let t' = unshare t in
 123       if s' == s && t' == t then orig else C.Prod(n,s',t')
 124    | C.Lambda (n,s,t) as orig ->
 125       let s' = unshare s in
 126       let t' = unshare t in
 127       if s' == s && t' == t then orig else C.Lambda(n,s',t')
 128    | C.LetIn (n,s,ty,t) as orig ->
 129       let s' = unshare s in
 130       let t' = unshare t in
 131       let ty' = unshare ty in
 132       if t' == t && ty' == ty && s' == s then orig else C.LetIn (n, s', ty', t')
 133    | C.Appl l as orig ->
 134       let l' = sharing_map unshare l in
 135       if l == l' then orig else C.Appl l'
 136    | C.Const (uri,exp_named_subst) as orig ->
 137       let exp_named_subst' =
 138         sharing_map
 139           (fun (uri,t as orig) ->
 140             let t' = unshare t in
 141             if t == t' then orig else (uri,t'))
 142           exp_named_subst
 143       in
 144       if exp_named_subst' == exp_named_subst then orig
 145       else C.Const (uri,exp_named_subst')
 146    | C.MutInd (uri,tyno,exp_named_subst) as orig ->
 147       let exp_named_subst' =
 148         sharing_map
 149           (fun (uri,t as orig) ->
 150             let t' = unshare t in
 151             if t == t' then orig else (uri,t'))
 152           exp_named_subst
 153       in
 154       if exp_named_subst' == exp_named_subst then orig
 155       else C.MutInd (uri,tyno,exp_named_subst')
 156    | C.MutConstruct (uri,tyno,consno,exp_named_subst) as orig ->
 157       let exp_named_subst' =
 158         sharing_map
 159           (fun (uri,t as orig) ->
 160             let t' = unshare t in
 161             if t == t' then orig else (uri,t'))
 162           exp_named_subst
 163       in
 164       if exp_named_subst' == exp_named_subst then orig
 165       else C.MutConstruct (uri,tyno,consno,exp_named_subst')
 166    | C.MutCase (sp,i,outty,t,pl) as orig ->
 167       let t' = unshare t in
 168       let pl' = sharing_map unshare pl in
 169       let outty' = unshare outty in
 170       if t' == t && pl' == pl && outty' == outty then orig
 171       else C.MutCase (sp, i, outty', t', pl')
 172    | C.Fix (i, fl) as orig ->
 173       let fl' =
 174        sharing_map
 175         (fun (name, i, ty, bo as orig) ->
 176            let ty' = unshare ty in
 177            let bo' = unshare bo in
 178            if ty' == ty && bo' == bo then orig else name,i,ty',bo')
 179          fl
 180       in
 181       if fl' == fl then orig else C.Fix (i, fl')
 182    | C.CoFix (i, fl) as orig ->
 183       let fl' =
 184        sharing_map
 185         (fun (name, ty, bo as orig) ->
 186            let ty' = unshare ty in
 187            let bo' = unshare bo in
 188            if ty' == ty && bo' == bo then orig else name,ty',bo')
 189          fl
 190       in
 191       if fl' == fl then orig else C.CoFix (i, fl')
 192  in
 193   unshare t
 194 ;;
 195
 196 let fresh_types =
 197   let module C = Cic in
 198   let unshare = fresh_univs in
 199   function
 200    | C.Constant (name,te,ty,exp,att) ->
 201         C.Constant (name,HExtlib.map_option unshare te,
 202           unshare ty,exp,att)
 203    | C.CurrentProof _ -> assert false
 204    | C.Variable _ -> assert false
 205    | C.InductiveDefinition (itl,u,i,att) ->
 206         C.InductiveDefinition
 207           (List.map
 208             (fun (name,b,t,cl) ->
 209                name,b,unshare t,
 210                List.map
 211                  (fun (name,t) -> name, unshare t)
 212                  cl)
 213             itl,u,i,att)
 214 ;;