components/content_pres/termContentPres.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Env = CicNotationEnv
  32
  33 let debug = false
  34 let debug_print s = if debug then prerr_endline (Lazy.force s) else ()
  35
  36 type pattern_id = int
  37 type pretty_printer_id = pattern_id
  38
  39 let resolve_binder = function
  40   | `Lambda -> "\\lambda"
  41   | `Pi -> "\\Pi"
  42   | `Forall -> "\\forall"
  43   | `Exists -> "\\exists"
  44
  45 let add_level_info prec assoc t = Ast.AttributedTerm (`Level (prec, assoc), t)
  46 let add_pos_info pos t = Ast.AttributedTerm (`ChildPos pos, t)
  47 let left_pos = add_pos_info `Left
  48 let right_pos = add_pos_info `Right
  49 let inner_pos = add_pos_info `Inner
  50
  51 let rec top_pos t = add_level_info ~-1 Gramext.NonA (inner_pos t)
  52 (*   function
  53   | Ast.AttributedTerm (`Level _, t) ->
  54       add_level_info ~-1 Gramext.NonA (inner_pos t)
  55   | Ast.AttributedTerm (attr, t) -> Ast.AttributedTerm (attr, top_pos t)
  56   | t -> add_level_info ~-1 Gramext.NonA (inner_pos t) *)
  57
  58 let rec remove_level_info =
  59   function
  60   | Ast.AttributedTerm (`Level _, t) -> remove_level_info t
  61   | Ast.AttributedTerm (a, t) -> Ast.AttributedTerm (a, remove_level_info t)
  62   | t -> t
  63
  64 let add_xml_attrs attrs t =
  65   if attrs = [] then t else Ast.AttributedTerm (`XmlAttrs attrs, t)
  66
  67 let add_keyword_attrs =
  68   add_xml_attrs (RenderingAttrs.keyword_attributes `MathML)
  69
  70 let box kind spacing indent content =
  71   Ast.Layout (Ast.Box ((kind, spacing, indent), content))
  72
  73 let hbox = box Ast.H
  74 let vbox = box Ast.V
  75 let hvbox = box Ast.HV
  76 let hovbox = box Ast.HOV
  77 let break = Ast.Layout Ast.Break
  78 let space = Ast.Literal (`Symbol " ")
  79 let builtin_symbol s = Ast.Literal (`Symbol s)
  80 let keyword k = add_keyword_attrs (Ast.Literal (`Keyword k))
  81
  82 let number s =
  83   add_xml_attrs (RenderingAttrs.number_attributes `MathML)
  84     (Ast.Literal (`Number s))
  85
  86 let ident i =
  87   add_xml_attrs (RenderingAttrs.ident_attributes `MathML) (Ast.Ident (i, None))
  88
  89 let ident_w_href href i =
  90   match href with
  91   | None -> ident i
  92   | Some href ->
  93       let href = UriManager.string_of_uri href in
  94       add_xml_attrs [Some "xlink", "href", href] (ident i)
  95
  96 let binder_symbol s =
  97   add_xml_attrs (RenderingAttrs.builtin_symbol_attributes `MathML)
  98     (builtin_symbol s)
  99
 100 let string_of_sort_kind = function
 101   | `Prop -> "Prop"
 102   | `Set -> "Set"
 103   | `CProp -> "CProp"
 104   | `Type _ -> "Type"
 105
 106 let pp_ast0 t k =
 107   let rec aux =
 108     function
 109     | Ast.Appl ts ->
 110         let rec aux_args pos =
 111           function
 112           | [] -> []
 113           | [ last ] ->
 114               let last = k last in
 115               if pos = `Left then [ left_pos last ] else [ right_pos last ]
 116           | hd :: tl ->
 117               (add_pos_info pos (k hd)) :: aux_args `Inner tl
 118         in
 119         add_level_info Ast.apply_prec Ast.apply_assoc
 120           (hovbox true true (CicNotationUtil.dress break (aux_args `Left ts)))
 121     | Ast.Binder (binder_kind, (id, ty), body) ->
 122         add_level_info Ast.binder_prec Ast.binder_assoc
 123           (hvbox false true
 124             [ binder_symbol (resolve_binder binder_kind);
 125               k id; builtin_symbol ":"; aux_ty ty; break;
 126               builtin_symbol "."; right_pos (k body) ])
 127     | Ast.Case (what, indty_opt, outty_opt, patterns) ->
 128         let outty_box =
 129           match outty_opt with
 130           | None -> []
 131           | Some outty ->
 132               [ space; keyword "return"; space; break; remove_level_info (k outty)]
 133         in
 134         let indty_box =
 135           match indty_opt with
 136           | None -> []
 137           | Some (indty, href) -> [ space; keyword "in"; space; break; ident_w_href href indty ]
 138         in
 139         let match_box =
 140           hvbox false false [
 141            hvbox false true [
 142             hvbox false true [keyword "match"; space; break; top_pos (k what)];
 143             break;
 144             hvbox false true indty_box;
 145             break;
 146             hvbox false true outty_box
 147            ];
 148            break;
 149            space;
 150            keyword "with";
 151            space
 152          ]
 153         in
 154         let mk_case_pattern =
 155          function
 156             Ast.Pattern (head, href, vars) ->
 157              hbox true false (ident_w_href href head :: List.map aux_var vars)
 158           | Ast.Wildcard -> builtin_symbol "_"
 159         in
 160         let patterns' =
 161           List.map
 162             (fun (lhs, rhs) ->
 163               remove_level_info
 164                 (hvbox false true [
 165                   hbox false true [
 166                     mk_case_pattern lhs; builtin_symbol "\\Rightarrow" ];
 167                   break; top_pos (k rhs) ]))
 168             patterns
 169         in
 170         let patterns'' =
 171           let rec aux_patterns = function
 172             | [] -> assert false
 173             | [ last ] ->
 174                 [ break;
 175                   hbox false false [
 176                     builtin_symbol "|";
 177                     last; builtin_symbol "]" ] ]
 178             | hd :: tl ->
 179                 [ break; hbox false false [ builtin_symbol "|"; hd ] ]
 180                 @ aux_patterns tl
 181           in
 182           match patterns' with
 183           | [] ->
 184               [ hbox false false [ builtin_symbol "["; builtin_symbol "]" ] ]
 185           | [ one ] ->
 186               [ hbox false false [
 187                 builtin_symbol "["; one; builtin_symbol "]" ] ]
 188           | hd :: tl ->
 189               hbox false false [ builtin_symbol "["; hd ]
 190               :: aux_patterns tl
 191         in
 192         add_level_info Ast.simple_prec Ast.simple_assoc
 193           (hvbox false false [
 194             hvbox false false ([match_box]); break;
 195             hbox false false [ hvbox false false patterns'' ] ])
 196     | Ast.Cast (bo, ty) ->
 197         add_level_info Ast.simple_prec Ast.simple_assoc
 198           (hvbox false true [
 199             builtin_symbol "("; top_pos (k bo); break; builtin_symbol ":";
 200             top_pos (k ty); builtin_symbol ")"])
 201     | Ast.LetIn (var, s, t) ->
 202         add_level_info Ast.let_in_prec Ast.let_in_assoc
 203           (hvbox false true [
 204             hvbox false true [
 205               keyword "let"; space;
 206               hvbox false true [
 207                 aux_var var; space; builtin_symbol "\\def"; break; top_pos (k s) ];
 208               break; space; keyword "in" ];
 209             break;
 210             k t ])
 211     | Ast.LetRec (rec_kind, funs, where) ->
 212         let rec_op =
 213           match rec_kind with `Inductive -> "rec" | `CoInductive -> "corec"
 214         in
 215         let mk_fun (args, (name,ty), body, rec_param) =
 216          List.map aux_var args ,k name, HExtlib.map_option k ty, k body,
 217            fst (List.nth args rec_param)
 218         in
 219         let mk_funs = List.map mk_fun in
 220         let fst_fun, tl_funs =
 221           match mk_funs funs with hd :: tl -> hd, tl | [] -> assert false
 222         in
 223         let fst_row =
 224           let (params, name, ty, body, rec_param) = fst_fun in
 225           hvbox false true ([
 226             keyword "let";
 227             space;
 228             keyword rec_op;
 229             space;
 230             name] @
 231             params @
 232             [space; keyword "on" ; space ; rec_param ;space ] @
 233             (match ty with None -> [] | Some ty -> [builtin_symbol ":"; ty]) @
 234             [ builtin_symbol "\\def";
 235             break;
 236             top_pos body ])
 237         in
 238         let tl_rows =
 239           List.map
 240             (fun (params, name, ty, body, rec_param) ->
 241               [ break;
 242                 hvbox false true ([
 243                   keyword "and";
 244                   name] @
 245                   params @
 246                   [space; keyword "on" ; space; rec_param ;space ] @
 247                   (match ty with
 248                       None -> []
 249                     | Some ty -> [builtin_symbol ":"; ty]) @
 250                   [ builtin_symbol "\\def"; break; body ])])
 251             tl_funs
 252         in
 253         add_level_info Ast.let_in_prec Ast.let_in_assoc
 254           ((hvbox false false
 255             (fst_row :: List.flatten tl_rows
 256              @ [ break; keyword "in"; break; k where ])))
 257     | Ast.Implicit -> builtin_symbol "?"
 258     | Ast.Meta (n, l) ->
 259         let local_context l =
 260             List.map (function None -> None | Some t -> Some (k t)) l
 261         in
 262         Ast.Meta(n, local_context l)
 263     | Ast.Sort sort -> aux_sort sort
 264     | Ast.Num _
 265     | Ast.Symbol _
 266     | Ast.Ident (_, None) | Ast.Ident (_, Some [])
 267     | Ast.Uri (_, None) | Ast.Uri (_, Some [])
 268     | Ast.Literal _
 269     | Ast.UserInput as leaf -> leaf
 270     | t -> CicNotationUtil.visit_ast ~special_k k t
 271   and aux_sort sort_kind =
 272     add_xml_attrs (RenderingAttrs.keyword_attributes `MathML)
 273       (Ast.Ident (string_of_sort_kind sort_kind, None))
 274   and aux_ty = function
 275     | None -> builtin_symbol "?"
 276     | Some ty -> k ty
 277   and aux_var = function
 278     | name, Some ty ->
 279         hvbox false true [
 280           builtin_symbol "("; name; builtin_symbol ":"; break; k ty;
 281           builtin_symbol ")" ]
 282     | name, None -> name
 283   and special_k = function
 284     | Ast.AttributedTerm (attrs, t) -> Ast.AttributedTerm (attrs, k t)
 285     | t ->
 286         prerr_endline ("unexpected special: " ^ CicNotationPp.pp_term t);
 287         assert false
 288   in
 289   aux t
 290
 291   (* persistent state *)
 292
 293 let level1_patterns21 = Hashtbl.create 211
 294
 295 let compiled21 = ref None
 296
 297 let pattern21_matrix = ref []
 298
 299 let get_compiled21 () =
 300   match !compiled21 with
 301   | None -> assert false
 302   | Some f -> Lazy.force f
 303
 304 let set_compiled21 f = compiled21 := Some f
 305
 306 let add_idrefs =
 307   List.fold_right (fun idref t -> Ast.AttributedTerm (`IdRef idref, t))
 308
 309 let instantiate21 idrefs env l1 =
 310   let rec subst_singleton pos env =
 311     function
 312       Ast.AttributedTerm (attr, t) ->
 313         Ast.AttributedTerm (attr, subst_singleton pos env t)
 314     | t -> CicNotationUtil.group (subst pos env t)
 315   and subst pos env = function
 316     | Ast.AttributedTerm (attr, t) ->
 317 (*         prerr_endline ("loosing attribute " ^ CicNotationPp.pp_attribute attr); *)
 318         subst pos env t
 319     | Ast.Variable var ->
 320         let name, expected_ty = CicNotationEnv.declaration_of_var var in
 321         let ty, value =
 322           try
 323             List.assoc name env
 324           with Not_found ->
 325             prerr_endline ("name " ^ name ^ " not found in environment");
 326             assert false
 327         in
 328         assert (CicNotationEnv.well_typed ty value); (* INVARIANT *)
 329         (* following assertion should be a conditional that makes this
 330          * instantiation fail *)
 331         assert (CicNotationEnv.well_typed expected_ty value);
 332         [ add_pos_info pos (CicNotationEnv.term_of_value value) ]
 333     | Ast.Magic m -> subst_magic pos env m
 334     | Ast.Literal l as t ->
 335         let t = add_idrefs idrefs t in
 336         (match l with
 337         | `Keyword k -> [ add_keyword_attrs t ]
 338         | _ -> [ t ])
 339     | Ast.Layout l -> [ Ast.Layout (subst_layout pos env l) ]
 340     | t -> [ CicNotationUtil.visit_ast (subst_singleton pos env) t ]
 341   and subst_magic pos env = function
 342     | Ast.List0 (p, sep_opt)
 343     | Ast.List1 (p, sep_opt) ->
 344         let rec_decls = CicNotationEnv.declarations_of_term p in
 345         let rec_values =
 346           List.map (fun (n, _) -> CicNotationEnv.lookup_list env n) rec_decls
 347         in
 348         let values = CicNotationUtil.ncombine rec_values in
 349         let sep =
 350           match sep_opt with
 351             | None -> []
 352             | Some l -> [ Ast.Literal l ]
 353         in
 354         let rec instantiate_list acc = function
 355           | [] -> List.rev acc
 356           | value_set :: [] ->
 357               let env = CicNotationEnv.combine rec_decls value_set in
 358               instantiate_list (CicNotationUtil.group (subst pos env p) :: acc)
 359                 []
 360           | value_set :: tl ->
 361               let env = CicNotationEnv.combine rec_decls value_set in
 362               let terms = subst pos env p in
 363               instantiate_list (CicNotationUtil.group (terms @ sep) :: acc) tl
 364         in
 365         instantiate_list [] values
 366     | Ast.Opt p ->
 367         let opt_decls = CicNotationEnv.declarations_of_term p in
 368         let env =
 369           let rec build_env = function
 370             | [] -> []
 371             | (name, ty) :: tl ->
 372                   (* assumption: if one of the value is None then all are *)
 373                 (match CicNotationEnv.lookup_opt env name with
 374                 | None -> raise Exit
 375                 | Some v -> (name, (ty, v)) :: build_env tl)
 376           in
 377           try build_env opt_decls with Exit -> []
 378         in
 379           begin
 380             match env with
 381               | [] -> []
 382               | _ -> subst pos env p
 383           end
 384     | _ -> assert false (* impossible *)
 385   and subst_layout pos env = function
 386     | Ast.Box (kind, tl) ->
 387         let tl' = subst_children pos env tl in
 388         Ast.Box (kind, List.concat tl')
 389     | l -> CicNotationUtil.visit_layout (subst_singleton pos env) l
 390   and subst_children pos env =
 391     function
 392     | [] -> []
 393     | [ child ] ->
 394         let pos' =
 395           match pos with
 396           | `Inner -> `Right
 397           | `Left -> `Left
 398 (*           | `None -> assert false *)
 399           | `Right -> `Right
 400         in
 401         [ subst pos' env child ]
 402     | hd :: tl ->
 403         let pos' =
 404           match pos with
 405           | `Inner -> `Inner
 406           | `Left -> `Inner
 407 (*           | `None -> assert false *)
 408           | `Right -> `Right
 409         in
 410         (subst pos env hd) :: subst_children pos' env tl
 411   in
 412     subst_singleton `Left env l1
 413
 414 let rec pp_ast1 term =
 415   let rec pp_value = function
 416     | CicNotationEnv.NumValue _ as v -> v
 417     | CicNotationEnv.StringValue _ as v -> v
 418 (*     | CicNotationEnv.TermValue t when t == term -> CicNotationEnv.TermValue (pp_ast0 t pp_ast1) *)
 419     | CicNotationEnv.TermValue t -> CicNotationEnv.TermValue (pp_ast1 t)
 420     | CicNotationEnv.OptValue None as v -> v
 421     | CicNotationEnv.OptValue (Some v) ->
 422         CicNotationEnv.OptValue (Some (pp_value v))
 423     | CicNotationEnv.ListValue vl ->
 424         CicNotationEnv.ListValue (List.map pp_value vl)
 425   in
 426   let ast_env_of_env env =
 427     List.map (fun (var, (ty, value)) -> (var, (ty, pp_value value))) env
 428   in
 429 (* prerr_endline ("pattern matching from 2 to 1 on term " ^ CicNotationPp.pp_term term); *)
 430   match term with
 431   | Ast.AttributedTerm (attrs, term') ->
 432       Ast.AttributedTerm (attrs, pp_ast1 term')
 433   | _ ->
 434       (match (get_compiled21 ()) term with
 435       | None -> pp_ast0 term pp_ast1
 436       | Some (env, ctors, pid) ->
 437           let idrefs =
 438             List.flatten (List.map CicNotationUtil.get_idrefs ctors)
 439           in
 440           let l1 =
 441             try
 442               Hashtbl.find level1_patterns21 pid
 443             with Not_found -> assert false
 444           in
 445           instantiate21 idrefs (ast_env_of_env env) l1)
 446
 447 let load_patterns21 t =
 448   set_compiled21 (lazy (Content2presMatcher.Matcher21.compiler t))
 449
 450 let pp_ast ast =
 451   debug_print (lazy "pp_ast <-");
 452   let ast' = pp_ast1 ast in
 453   debug_print (lazy ("pp_ast -> " ^ CicNotationPp.pp_term ast'));
 454   ast'
 455
 456 exception Pretty_printer_not_found
 457
 458 let fill_pos_info l1_pattern = l1_pattern
 459 (*   let rec aux toplevel pos =
 460     function
 461     | Ast.Layout l ->
 462         (match l
 463
 464     | Ast.Magic m ->
 465         Ast.Box (
 466     | Ast.Variable _ as t -> add_pos_info pos t
 467     | t -> t
 468   in
 469   aux true l1_pattern *)
 470
 471 let fresh_id =
 472   let counter = ref ~-1 in
 473   fun () ->
 474     incr counter;
 475     !counter
 476
 477 let add_pretty_printer ~precedence ~associativity l2 l1 =
 478   let id = fresh_id () in
 479   let l1' = add_level_info precedence associativity (fill_pos_info l1) in
 480   let l2' = CicNotationUtil.strip_attributes l2 in
 481   Hashtbl.add level1_patterns21 id l1';
 482   pattern21_matrix := (l2', id) :: !pattern21_matrix;
 483   load_patterns21 !pattern21_matrix;
 484   id
 485
 486 let remove_pretty_printer id =
 487   (try
 488     Hashtbl.remove level1_patterns21 id;
 489   with Not_found -> raise Pretty_printer_not_found);
 490   pattern21_matrix := List.filter (fun (_, id') -> id <> id') !pattern21_matrix;
 491   load_patterns21 !pattern21_matrix
 492
 493   (* presentation -> content *)
 494
 495 let unopt_names names env =
 496   let rec aux acc = function
 497     | (name, (ty, v)) :: tl when List.mem name names ->
 498         (match ty, v with
 499         | Env.OptType ty, Env.OptValue (Some v) ->
 500             aux ((name, (ty, v)) :: acc) tl
 501         | _ -> assert false)
 502     | hd :: tl -> aux (hd :: acc) tl
 503     | [] -> acc
 504   in
 505   aux [] env
 506
 507 let head_names names env =
 508   let rec aux acc = function
 509     | (name, (ty, v)) :: tl when List.mem name names ->
 510         (match ty, v with
 511         | Env.ListType ty, Env.ListValue (v :: _) ->
 512             aux ((name, (ty, v)) :: acc) tl
 513         | _ -> assert false)
 514     | _ :: tl -> aux acc tl
 515       (* base pattern may contain only meta names, thus we trash all others *)
 516     | [] -> acc
 517   in
 518   aux [] env
 519
 520 let tail_names names env =
 521   let rec aux acc = function
 522     | (name, (ty, v)) :: tl when List.mem name names ->
 523         (match ty, v with
 524         | Env.ListType ty, Env.ListValue (_ :: vtl) ->
 525             aux ((name, (Env.ListType ty, Env.ListValue vtl)) :: acc) tl
 526         | _ -> assert false)
 527     | binding :: tl -> aux (binding :: acc) tl
 528     | [] -> acc
 529   in
 530   aux [] env
 531
 532 let instantiate_level2 env term =
 533   let fresh_env = ref [] in
 534   let lookup_fresh_name n =
 535     try
 536       List.assoc n !fresh_env
 537     with Not_found ->
 538       let new_name = CicNotationUtil.fresh_name () in
 539       fresh_env := (n, new_name) :: !fresh_env;
 540       new_name
 541   in
 542   let rec aux env term =
 543 (*     prerr_endline ("ENV " ^ CicNotationPp.pp_env env); *)
 544     match term with
 545     | Ast.AttributedTerm (_, term) -> aux env term
 546     | Ast.Appl terms -> Ast.Appl (List.map (aux env) terms)
 547     | Ast.Binder (binder, var, body) ->
 548         Ast.Binder (binder, aux_capture_var env var, aux env body)
 549     | Ast.Case (term, indty, outty_opt, patterns) ->
 550         Ast.Case (aux env term, indty, aux_opt env outty_opt,
 551           List.map (aux_branch env) patterns)
 552     | Ast.LetIn (var, t1, t2) ->
 553         Ast.LetIn (aux_capture_var env var, aux env t1, aux env t2)
 554     | Ast.LetRec (kind, definitions, body) ->
 555         Ast.LetRec (kind, List.map (aux_definition env) definitions,
 556           aux env body)
 557     | Ast.Uri (name, None) -> Ast.Uri (name, None)
 558     | Ast.Uri (name, Some substs) ->
 559         Ast.Uri (name, Some (aux_substs env substs))
 560     | Ast.Ident (name, Some substs) ->
 561         Ast.Ident (name, Some (aux_substs env substs))
 562     | Ast.Meta (index, substs) -> Ast.Meta (index, aux_meta_substs env substs)
 563
 564     | Ast.Implicit
 565     | Ast.Ident _
 566     | Ast.Num _
 567     | Ast.Sort _
 568     | Ast.Symbol _
 569     | Ast.UserInput -> term
 570
 571     | Ast.Magic magic -> aux_magic env magic
 572     | Ast.Variable var -> aux_variable env var
 573
 574     | _ -> assert false
 575   and aux_opt env = function
 576     | Some term -> Some (aux env term)
 577     | None -> None
 578   and aux_capture_var env (name, ty_opt) = (aux env name, aux_opt env ty_opt)
 579   and aux_branch env (pattern, term) =
 580     (aux_pattern env pattern, aux env term)
 581   and aux_pattern env =
 582    function
 583       Ast.Pattern (head, hrefs, vars) ->
 584        Ast.Pattern (head, hrefs, List.map (aux_capture_var env) vars)
 585     | Ast.Wildcard -> Ast.Wildcard
 586   and aux_definition env (params, var, term, i) =
 587     (List.map (aux_capture_var env) params, aux_capture_var env var, aux env term, i)
 588   and aux_substs env substs =
 589     List.map (fun (name, term) -> (name, aux env term)) substs
 590   and aux_meta_substs env meta_substs = List.map (aux_opt env) meta_substs
 591   and aux_variable env = function
 592     | Ast.NumVar name -> Ast.Num (Env.lookup_num env name, 0)
 593     | Ast.IdentVar name -> Ast.Ident (Env.lookup_string env name, None)
 594     | Ast.TermVar name -> Env.lookup_term env name
 595     | Ast.FreshVar name -> Ast.Ident (lookup_fresh_name name, None)
 596     | Ast.Ascription (term, name) -> assert false
 597   and aux_magic env = function
 598     | Ast.Default (some_pattern, none_pattern) ->
 599         let some_pattern_names = CicNotationUtil.names_of_term some_pattern in
 600         let none_pattern_names = CicNotationUtil.names_of_term none_pattern in
 601         let opt_names =
 602           List.filter
 603             (fun name -> not (List.mem name none_pattern_names))
 604             some_pattern_names
 605         in
 606         (match opt_names with
 607         | [] -> assert false (* some pattern must contain at least 1 name *)
 608         | (name :: _) as names ->
 609             (match Env.lookup_value env name with
 610             | Env.OptValue (Some _) ->
 611                 (* assumption: if "name" above is bound to Some _, then all
 612                  * names returned by "meta_names_of" are bound to Some _ as well
 613                  *)
 614                 aux (unopt_names names env) some_pattern
 615             | Env.OptValue None -> aux env none_pattern
 616             | _ ->
 617                 prerr_endline (sprintf
 618                   "lookup of %s in env %s did not return an optional value"
 619                   name (CicNotationPp.pp_env env));
 620                 assert false))
 621     | Ast.Fold (`Left, base_pattern, names, rec_pattern) ->
 622         let acc_name = List.hd names in (* names can't be empty, cfr. parser *)
 623         let meta_names =
 624           List.filter ((<>) acc_name)
 625             (CicNotationUtil.names_of_term rec_pattern)
 626         in
 627         (match meta_names with
 628         | [] -> assert false (* as above *)
 629         | (name :: _) as names ->
 630             let rec instantiate_fold_left acc env' =
 631               match Env.lookup_value env' name with
 632               | Env.ListValue (_ :: _) ->
 633                   instantiate_fold_left
 634                     (let acc_binding =
 635                       acc_name, (Env.TermType, Env.TermValue acc)
 636                      in
 637                      aux (acc_binding :: head_names names env') rec_pattern)
 638                     (tail_names names env')
 639               | Env.ListValue [] -> acc
 640               | _ -> assert false
 641             in
 642             instantiate_fold_left (aux env base_pattern) env)
 643     | Ast.Fold (`Right, base_pattern, names, rec_pattern) ->
 644         let acc_name = List.hd names in (* names can't be empty, cfr. parser *)
 645         let meta_names =
 646           List.filter ((<>) acc_name)
 647             (CicNotationUtil.names_of_term rec_pattern)
 648         in
 649         (match meta_names with
 650         | [] -> assert false (* as above *)
 651         | (name :: _) as names ->
 652             let rec instantiate_fold_right env' =
 653               match Env.lookup_value env' name with
 654               | Env.ListValue (_ :: _) ->
 655                   let acc = instantiate_fold_right (tail_names names env') in
 656                   let acc_binding =
 657                     acc_name, (Env.TermType, Env.TermValue acc)
 658                   in
 659                   aux (acc_binding :: head_names names env') rec_pattern
 660               | Env.ListValue [] -> aux env base_pattern
 661               | _ -> assert false
 662             in
 663             instantiate_fold_right env)
 664     | Ast.If (_, p_true, p_false) as t ->
 665         aux env (CicNotationUtil.find_branch (Ast.Magic t))
 666     | Ast.Fail -> assert false
 667     | _ -> assert false
 668   in
 669   aux env term
 670
 671   (* initialization *)
 672
 673 let _ = load_patterns21 []
 674
 675
 676