components/extlib/hExtlib.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* $Id$ *)
  27
  28 (** PROFILING *)
  29
  30 let profiling_enabled = ref false ;; (* ComponentsConf.profiling *)
  31
  32 let something_profiled = ref false
  33
  34 let _ =
  35   if !something_profiled then
  36     at_exit
  37       (fun _ ->
  38         prerr_endline
  39          (Printf.sprintf "!! %39s ---------- --------- --------- ---------"
  40            (String.make 39 '-'));
  41         prerr_endline
  42          (Printf.sprintf "!! %-39s %10s %9s %9s %9s"
  43            "function" "#calls" "total" "max" "average"))
  44
  45 let profiling_printings = ref (fun _ -> true)
  46 let set_profiling_printings f = profiling_printings := f
  47
  48 type profiler = { profile : 'a 'b. ('a -> 'b) -> 'a -> 'b }
  49 let profile ?(enable = true) s =
  50  if !profiling_enabled && enable then
  51    let total = ref 0.0 in
  52    let calls = ref 0 in
  53    let max = ref 0.0 in
  54    let profile f x =
  55     if not !profiling_enabled then f x else
  56     let before = Unix.gettimeofday () in
  57     try
  58      incr calls;
  59      let res = f x in
  60      let after = Unix.gettimeofday () in
  61      let delta = after -. before in
  62       total := !total +. delta;
  63       if delta > !max then max := delta;
  64       res
  65     with
  66      exc ->
  67       let after = Unix.gettimeofday () in
  68       let delta = after -. before in
  69        total := !total +. delta;
  70        if delta > !max then max := delta;
  71        raise exc
  72    in
  73    at_exit
  74     (fun () ->
  75       if !profiling_printings s && !calls <> 0 then
  76        begin
  77         something_profiled := true;
  78         prerr_endline
  79          (Printf.sprintf "!! %-39s %10d %9.4f %9.4f %9.4f"
  80          s !calls !total !max (!total /. (float_of_int !calls)))
  81        end);
  82    { profile = profile }
  83  else
  84    { profile = fun f x -> f x }
  85
  86 (** {2 Optional values} *)
  87
  88 let map_option f = function None -> None | Some v -> Some (f v)
  89 let iter_option f = function None -> () | Some v -> f v
  90 let unopt = function None -> failwith "unopt: None" | Some v -> v
  91
  92 (** {2 String processing} *)
  93
  94 let split ?(sep = ' ') s =
  95   let pieces = ref [] in
  96   let rec aux idx =
  97     match (try Some (String.index_from s idx sep) with Not_found -> None) with
  98     | Some pos ->
  99         pieces := String.sub s idx (pos - idx) :: !pieces;
 100         aux (pos + 1)
 101     | None -> pieces := String.sub s idx (String.length s - idx) :: !pieces
 102   in
 103   aux 0;
 104   List.rev !pieces
 105
 106 let trim_blanks s =
 107   let rec find_left idx =
 108     match s.[idx] with
 109     | ' ' | '\t' | '\r' | '\n' -> find_left (idx + 1)
 110     | _ -> idx
 111   in
 112   let rec find_right idx =
 113     match s.[idx] with
 114     | ' ' | '\t' | '\r' | '\n' -> find_right (idx - 1)
 115     | _ -> idx
 116   in
 117   let s_len = String.length s in
 118   let left, right = find_left 0, find_right (s_len - 1) in
 119   String.sub s left (right - left + 1)
 120
 121 (** {2 Char processing} *)
 122
 123 let is_alpha c =
 124   let code = Char.code c in
 125   (code >= 65 && code <= 90) || (code >= 97 && code <= 122)
 126
 127 let is_digit c =
 128   let code = Char.code c in
 129   code >= 48 && code <= 57
 130
 131 let is_blank c =
 132   let code = Char.code c in
 133   code = 9 || code = 10 || code = 13 || code = 32
 134
 135 let is_alphanum c = is_alpha c || is_digit c
 136
 137 (** {2 List processing} *)
 138
 139 let flatten_map f l =
 140   List.flatten (List.map f l)
 141 ;;
 142
 143 let list_mapi f l =
 144   let rec aux k = function
 145     | [] -> []
 146     | h::tl -> f h k :: aux (k+1) tl
 147   in
 148      aux 0 l
 149 ;;
 150
 151 let rec list_uniq ?(eq=(=)) = function
 152   | [] -> []
 153   | h::[] -> [h]
 154   | h1::h2::tl when eq h1 h2 -> list_uniq ~eq (h2 :: tl)
 155   | h1::tl (* when h1 <> h2 *) -> h1 :: list_uniq ~eq tl
 156
 157 let rec filter_map f =
 158   function
 159   | [] -> []
 160   | hd :: tl ->
 161       (match f hd with
 162       | None -> filter_map f tl
 163       | Some v -> v :: filter_map f tl)
 164
 165 let list_rev_map_filter f l =
 166    let rec aux a = function
 167       | []       -> a
 168       | hd :: tl ->
 169          begin match f hd with
 170             | None   -> aux a tl
 171             | Some b -> aux (b :: a) tl
 172          end
 173    in
 174    aux [] l
 175
 176 let list_rev_map_filter_fold f v l =
 177    let rec aux v a = function
 178       | []       -> v, a
 179       | hd :: tl ->
 180          begin match f v hd with
 181             | v, None   -> aux v a tl
 182             | v, Some b -> aux v (b :: a) tl
 183          end
 184    in
 185    aux v [] l
 186
 187 let list_concat ?(sep = []) =
 188   let rec aux acc =
 189     function
 190     | [] -> []
 191     | [ last ] -> List.flatten (List.rev (last :: acc))
 192     | hd :: tl -> aux ([sep; hd] @ acc) tl
 193   in
 194   aux []
 195
 196 let rec list_findopt f l =
 197   let rec aux = function
 198     | [] -> None
 199     | x::tl ->
 200         (match f x with
 201         | None -> aux tl
 202         | Some _ as rc -> rc)
 203   in
 204   aux l
 205
 206 let split_nth n l =
 207   let rec aux acc n l =
 208     match n, l with
 209     | 0, _ -> List.rev acc, l
 210     | n, [] -> raise (Failure "HExtlib.split_nth")
 211     | n, hd :: tl -> aux (hd :: acc) (n - 1) tl in
 212   aux [] n l
 213
 214 let list_last l =
 215   let l = List.rev l in
 216   try List.hd l with exn -> raise (Failure "HExtlib.list_last")
 217 ;;
 218
 219 (** {2 File predicates} *)
 220
 221 let is_dir fname =
 222   try
 223     (Unix.stat fname).Unix.st_kind = Unix.S_DIR
 224   with Unix.Unix_error _ -> false
 225
 226 let writable_dir path =
 227   try
 228     let file = path ^ "/prova_matita" in
 229     let oc = open_out file in
 230     close_out oc;
 231     Sys.remove file;
 232     true
 233   with Sys_error _ -> false
 234
 235
 236 let is_regular fname =
 237   try
 238     (Unix.stat fname).Unix.st_kind = Unix.S_REG
 239   with Unix.Unix_error _ -> false
 240
 241 let is_executable fname =
 242   try
 243     let stat = (Unix.stat fname) in
 244     stat.Unix.st_kind = Unix.S_REG &&
 245     (stat.Unix.st_perm land 0o001 > 0)
 246   with Unix.Unix_error _ -> false
 247
 248 let chmod mode filename =
 249    Unix.chmod filename mode
 250
 251 let mkdir path =
 252   let components = split ~sep:'/' path in
 253   let rec aux where = function
 254     | [] -> ()
 255     | piece::tl ->
 256         let path =
 257           if where = "" then piece else where ^ "/" ^ piece in
 258         (try
 259           Unix.mkdir path 0o755; chmod 0o2775 path
 260         with
 261         | Unix.Unix_error (Unix.EEXIST,_,_) -> ()
 262         | Unix.Unix_error (e,_,_) ->
 263             raise
 264               (Failure
 265                 ("Unix.mkdir " ^ path ^ " 0o2775 :" ^ (Unix.error_message e))));
 266         aux path tl
 267   in
 268   let where = if path.[0] = '/' then "/" else "" in
 269   aux where components
 270
 271 (** {2 Filesystem} *)
 272
 273 let input_file fname =
 274   let size = (Unix.stat fname).Unix.st_size in
 275   let buf = Buffer.create size in
 276   let ic = open_in fname in
 277   Buffer.add_channel buf ic size;
 278   close_in ic;
 279   Buffer.contents buf
 280
 281 let input_all ic =
 282   let size = 10240 in
 283   let buf = Buffer.create size in
 284   let s = String.create size in
 285   (try
 286     while true do
 287       let bytes = input ic s 0 size in
 288       if bytes = 0 then raise End_of_file
 289       else Buffer.add_substring buf s 0 bytes
 290     done
 291   with End_of_file -> ());
 292   Buffer.contents buf
 293
 294 let output_file ~filename ~text =
 295   let oc = open_out filename in
 296   output_string oc text;
 297   close_out oc;
 298   chmod 0o664 filename
 299
 300 let blank_split s =
 301   let len = String.length s in
 302   let buf = Buffer.create 0 in
 303   let rec aux acc i =
 304     if i >= len
 305     then begin
 306       if Buffer.length buf > 0
 307       then List.rev (Buffer.contents buf :: acc)
 308       else List.rev acc
 309     end else begin
 310       if is_blank s.[i] then
 311         if Buffer.length buf > 0 then begin
 312           let s = Buffer.contents buf in
 313           Buffer.clear buf;
 314           aux (s :: acc) (i + 1)
 315         end else
 316           aux acc (i + 1)
 317       else begin
 318         Buffer.add_char buf s.[i];
 319         aux acc (i + 1)
 320       end
 321     end
 322   in
 323   aux [] 0
 324
 325   (* Rules: * "~name" -> home dir of "name"
 326    * "~" -> value of $HOME if defined, home dir of the current user otherwise *)
 327 let tilde_expand s =
 328   let get_home login = (Unix.getpwnam login).Unix.pw_dir in
 329   let expand_one s =
 330     let len = String.length s in
 331     if len > 0 && s.[0] = '~' then begin
 332       let login_len = ref 1 in
 333       while !login_len < len && is_alphanum (s.[!login_len]) do
 334         incr login_len
 335       done;
 336       let login = String.sub s 1 (!login_len - 1) in
 337       try
 338         let home =
 339           if login = "" then
 340             try Sys.getenv "HOME" with Not_found -> get_home (Unix.getlogin ())
 341           else
 342             get_home login
 343         in
 344         home ^ String.sub s !login_len (len - !login_len)
 345       with Not_found | Invalid_argument _ -> s
 346     end else
 347       s
 348   in
 349   String.concat " " (List.map expand_one (blank_split s))
 350
 351 let find ?(test = fun _ -> true) path =
 352   let rec aux acc todo =
 353     match todo with
 354     | [] -> acc
 355     | path :: tl ->
 356         try
 357           let handle = Unix.opendir path in
 358           let dirs = ref [] in
 359           let matching_files = ref [] in
 360           (try
 361             while true do
 362               match Unix.readdir handle with
 363               | "." | ".." -> ()
 364               | entry ->
 365                   let qentry = path ^ "/" ^ entry in
 366                   (try
 367                     if is_dir qentry then
 368                       dirs := qentry :: !dirs
 369                     else if test qentry then
 370                       matching_files := qentry :: !matching_files;
 371                   with Unix.Unix_error _ -> ())
 372             done
 373           with End_of_file -> Unix.closedir handle);
 374           aux (!matching_files @ acc) (!dirs @ tl)
 375         with Unix.Unix_error _ -> aux acc tl
 376   in
 377   aux [] [path]
 378
 379 let safe_remove fname = if Sys.file_exists fname then Sys.remove fname
 380
 381 let is_dir_empty d =
 382  try
 383   let od = Unix.opendir d in
 384   let rec aux () =
 385    let name = Unix.readdir od in
 386    if name <> "." && name <> ".." then false else aux () in
 387   let res = try aux () with End_of_file -> true in
 388    Unix.closedir od;
 389    res
 390  with
 391   Unix.Unix_error _ -> true (* raised by Unix.opendir, we hope :-) *)
 392
 393 let safe_rmdir d = try Unix.rmdir d with Unix.Unix_error _ -> ()
 394
 395 let rec rmdir_descend d =
 396   if is_dir_empty d then
 397     begin
 398       safe_rmdir d;
 399       rmdir_descend (Filename.dirname d)
 400     end
 401
 402
 403 (** {2 Exception handling} *)
 404
 405 let finally at_end f arg =
 406   let res =
 407     try f arg
 408     with exn -> at_end (); raise exn
 409   in
 410   at_end ();
 411   res
 412
 413 (** {2 Localized exceptions } *)
 414
 415 exception Localized of Stdpp.location * exn
 416
 417 let loc_of_floc floc = Stdpp.first_pos floc, Stdpp.last_pos floc;;
 418
 419 let floc_of_loc (loc_begin, loc_end) =
 420  Stdpp.make_loc (loc_begin, loc_end)
 421
 422 let dummy_floc = floc_of_loc (-1, -1)
 423
 424 let raise_localized_exception ~offset floc exn =
 425  let x, y = loc_of_floc floc in
 426  let x = offset + x in
 427  let y = offset + y in
 428  let floc = floc_of_loc (x,y) in
 429   raise (Localized (floc, exn))
 430
 431 let estimate_size x =
 432   4 * (String.length (Marshal.to_string x [])) / 1024
 433
 434 let normalize_path s =
 435   let s = Str.global_replace (Str.regexp "//") "/" s in
 436   let l = Str.split (Str.regexp "/") s in
 437   let rec aux acc = function
 438     | [] -> acc
 439     | he::"."::tl -> aux acc (he::tl)
 440     | he::".."::tl when he <> ".." -> aux [] (acc @ tl)
 441     | he::tl -> aux (acc@[he]) tl
 442   in
 443   (if Str.string_match (Str.regexp "^/") s 0 then "/" else "") ^
 444   String.concat "/" (aux [] l)
 445   ^ (if Str.string_match (Str.regexp "/$") s 0 then "/" else "")
 446 ;;
 447
 448 let find_in paths path =
 449    let rec aux = function
 450    | [] -> raise (Failure "find_in")
 451    | p :: tl ->
 452       let path = normalize_path (p ^ "/" ^ path) in
 453        try
 454          if (Unix.stat path).Unix.st_kind = Unix.S_REG then path
 455          else aux tl
 456        with Unix.Unix_error _ ->
 457                aux tl
 458    in
 459    try
 460      aux paths
 461    with Unix.Unix_error _ | Failure _ ->
 462      raise
 463        (Failure "find_in")
 464 ;;
 465
 466 let is_prefix_of_aux d1 d2 =
 467   let len1 = String.length d1 in
 468   let len2 = String.length d2 in
 469   if len2 < len1 then
 470     false, len1, len2
 471   else
 472     let pref = String.sub d2 0 len1 in
 473     pref = d1 && (len1 = len2 || d1.[len1-1] = '/' || d2.[len1] = '/'), len1, len2
 474
 475 let is_prefix_of d1 d2 =
 476   let b,_,_ = is_prefix_of_aux d1 d2 in b
 477 ;;
 478
 479 let chop_prefix prefix s =
 480   let b,lp,ls = is_prefix_of_aux prefix s in
 481   if b then
 482     String.sub s lp (ls - lp)
 483   else
 484     s
 485 ;;
 486
 487 let touch s =
 488   try close_out(open_out s) with Sys_error _ -> ()
 489 ;;