components/grafite_engine/grafiteTypes.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 exception Option_error of string * string
  29 exception Statement_error of string
  30 exception Command_error of string
  31
  32 let command_error msg = raise (Command_error msg)
  33
  34 type incomplete_proof = {
  35   proof: ProofEngineTypes.proof;
  36   stack: Continuationals.Stack.t;
  37 }
  38
  39 type proof_status =
  40   | No_proof
  41   | Incomplete_proof of incomplete_proof
  42   | Proof of ProofEngineTypes.proof
  43   | Intermediate of Cic.metasenv
  44       (* Status in which the proof could be while it is being processed by the
  45       * engine. No status entering/exiting the engine could be in it. *)
  46
  47 module StringMap = Map.Make (String)
  48 type option_value =
  49   | String of string
  50   | Int of int
  51 type options = option_value StringMap.t
  52 let no_options = StringMap.empty
  53
  54 type status = {
  55   moo_content_rev: GrafiteMarshal.moo;
  56   proof_status: proof_status;
  57   options: options;
  58   objects: UriManager.uri list;
  59   coercions: UriManager.uri list;
  60   universe:Universe.universe;
  61   baseuri: string;
  62 }
  63
  64 let get_current_proof status =
  65   match status.proof_status with
  66   | Incomplete_proof { proof = p } -> p
  67   | Proof p -> p
  68   | _ -> raise (Statement_error "no ongoing proof")
  69
  70 let get_proof_metasenv status =
  71   match status.proof_status with
  72   | No_proof -> []
  73   | Proof (_, metasenv, _, _, _, _)
  74   | Incomplete_proof { proof = (_, metasenv, _, _, _, _) }
  75   | Intermediate metasenv ->
  76       metasenv
  77
  78 let get_stack status =
  79   match status.proof_status with
  80   | Incomplete_proof p -> p.stack
  81   | Proof _ -> Continuationals.Stack.empty
  82   | _ -> assert false
  83
  84 let set_stack stack status =
  85   match status.proof_status with
  86   | Incomplete_proof p ->
  87       { status with proof_status = Incomplete_proof { p with stack = stack } }
  88   | Proof _ ->
  89       assert (Continuationals.Stack.is_empty stack);
  90       status
  91   | _ -> assert false
  92
  93 let set_metasenv metasenv status =
  94   let proof_status =
  95     match status.proof_status with
  96     | No_proof -> Intermediate metasenv
  97     | Incomplete_proof ({ proof = (uri, _, subst, proof, ty, attrs) } as incomplete_proof) ->
  98         Incomplete_proof
  99           { incomplete_proof with proof = (uri, metasenv, subst, proof, ty, attrs) }
 100     | Intermediate _ -> Intermediate metasenv
 101     | Proof (_, metasenv', _, _, _, _) ->
 102        assert (metasenv = metasenv');
 103        status.proof_status
 104   in
 105   { status with proof_status = proof_status }
 106
 107 let get_proof_context status goal =
 108   match status.proof_status with
 109   | Incomplete_proof { proof = (_, metasenv, _, _, _, _) } ->
 110       let (_, context, _) = CicUtil.lookup_meta goal metasenv in
 111       context
 112   | _ -> []
 113
 114 let get_proof_conclusion status goal =
 115   match status.proof_status with
 116   | Incomplete_proof { proof = (_, metasenv, _, _, _, _) } ->
 117       let (_, _, conclusion) = CicUtil.lookup_meta goal metasenv in
 118       conclusion
 119   | _ -> raise (Statement_error "no ongoing proof")
 120
 121 let add_moo_content cmds status =
 122   let content = status.moo_content_rev in
 123   let content' =
 124     List.fold_right
 125       (fun cmd acc ->
 126 (*         prerr_endline ("adding to moo command: " ^ GrafiteAstPp.pp_command cmd); *)
 127         match cmd with
 128         | GrafiteAst.Default _
 129         | GrafiteAst.Index _
 130         | GrafiteAst.Coercion _ ->
 131             if List.mem cmd content then acc
 132             else cmd :: acc
 133         | _ -> cmd :: acc)
 134       cmds content
 135   in
 136 (*   prerr_endline ("new moo content: " ^ String.concat " " (List.map
 137     GrafiteAstPp.pp_command content')); *)
 138   { status with moo_content_rev = content' }
 139
 140 let get_option status name =
 141   try
 142     StringMap.find name status.options
 143   with Not_found -> raise (Option_error (name, "not found"))
 144
 145 let get_baseuri status = status.baseuri;;
 146
 147 let set_option status name value =
 148   let types = [ (* no set options defined! *) ] in
 149   let ty_and_mangler =
 150     try List.assoc name types
 151     with Not_found ->
 152      command_error (Printf.sprintf "Unknown option \"%s\"" name)
 153   in
 154   let value =
 155     match ty_and_mangler with
 156     | `String, f -> String (f value)
 157     | `Int, f ->
 158         (try
 159           Int (int_of_string (f value))
 160         with Failure _ ->
 161           command_error (Printf.sprintf "Not an integer value \"%s\"" value))
 162   in
 163     { status with options = StringMap.add name value status.options }
 164
 165
 166 let get_string_option status name =
 167   match get_option status name with
 168   | String s -> s
 169   | _ -> raise (Option_error (name, "not a string value"))
 170
 171 let dump_status status =
 172   HLog.message "status.aliases:\n";
 173   HLog.message "status.proof_status:";
 174   HLog.message
 175     (match status.proof_status with
 176     | No_proof -> "no proof\n"
 177     | Incomplete_proof _ -> "incomplete proof\n"
 178     | Proof _ -> "proof\n"
 179     | Intermediate _ -> "Intermediate\n");
 180   HLog.message "status.options\n";
 181   StringMap.iter (fun k v ->
 182     let v =
 183       match v with
 184       | String s -> s
 185       | Int i -> string_of_int i
 186     in
 187     HLog.message (k ^ "::=" ^ v)) status.options;
 188   HLog.message "status.coercions\n";
 189   HLog.message "status.objects:\n";
 190   List.iter
 191     (fun u -> HLog.message (UriManager.string_of_uri u)) status.objects
 192