helm/DEVEL/ocaml-http/http_daemon.ml

   1
   2 (*
   3   OCaml HTTP - do it yourself (fully OCaml) HTTP daemon
   4
   5   Copyright (C) <2002> Stefano Zacchiroli <zack@cs.unibo.it>
   6
   7   This program is free software; you can redistribute it and/or modify
   8   it under the terms of the GNU General Public License as published by
   9   the Free Software Foundation; either version 2 of the License, or
  10   (at your option) any later version.
  11
  12   This program is distributed in the hope that it will be useful,
  13   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15   GNU General Public License for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with this program; if not, write to the Free Software
  19   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  20 *)
  21
  22 open Printf;;
  23
  24 open Http_common;;
  25 open Http_types;;
  26 open Http_constants;;
  27 open Http_parser;;
  28
  29 let debug = true
  30 let debug_print str =
  31   if debug then begin
  32     prerr_endline ("DEBUG: " ^ str);
  33     flush stderr
  34   end
  35
  36 let default_addr = "0.0.0.0"
  37 let default_port = 80
  38 let default_timeout = 300
  39 let default_mode = `Fork
  40
  41   (** send raw data on outchan, flushing it afterwards *)
  42 let send_raw ~data outchan =
  43   output_string outchan data;
  44   flush outchan
  45
  46 let send_CRLF = send_raw ~data:crlf
  47
  48 let send_header ~header ~value =
  49   Http_parser.heal_header (header, value);
  50   send_raw ~data:(header ^ ": " ^ value ^ crlf)
  51
  52 let send_headers ~headers outchan =
  53   List.iter (fun (header, value) -> send_header ~header ~value outchan) headers
  54
  55   (** internal: parse a code argument from a function which have two optional
  56   arguments "code" and "status" *)
  57 let get_code_argument func_name =
  58   fun ~code ~status ->
  59     (match code, status with
  60     | Some c, None -> c
  61     | None, Some s -> code_of_status s
  62     | Some _, Some _ ->
  63         failwith (func_name ^ " you must give 'code' or 'status', not both")
  64     | None, None ->
  65         failwith (func_name ^ " you must give 'code' or 'status', not none"))
  66
  67   (** internal: low level for send_status_line *)
  68 let send_status_line' ~version ~code =
  69   let status_line =
  70     String.concat
  71       " "
  72       [ string_of_version version;
  73       string_of_int code;
  74       Http_misc.reason_phrase_of_code code ]
  75   in
  76   send_raw ~data:(status_line ^ crlf)
  77
  78 let send_status_line ?(version = http_version) ?code ?status outchan =
  79   send_status_line'
  80     ~version
  81     ~code:(get_code_argument "Daemon.send_status_line" ~code ~status)
  82     outchan
  83
  84   (* FIXME duplication of code between this and response#addBasicHeaders *)
  85 let send_basic_headers ?(version = http_version) ?code ?status outchan =
  86   send_status_line'
  87     ~version ~code:(get_code_argument "Daemon.send_basic_headers" ~code ~status)
  88     outchan;
  89   send_headers
  90     ~headers:["Date", Http_misc.date_822 (); "Server", server_string]
  91     outchan
  92
  93   (** internal: given a status code and an additional body return a string
  94   representing an HTML document that explains the meaning of given status code.
  95   Additional data can be added to the body via 'body' argument *)
  96 let foo_body code body =
  97   let reason_phrase = Http_misc.reason_phrase_of_code code in
  98   sprintf
  99 "<!DOCTYPE HTML PUBLIC \"-//IETF//DTD HTML 2.0//EN\">
 100 <HTML><HEAD>
 101 <TITLE>%d %s</TITLE>
 102 </HEAD><BODY>
 103 <H1>%d - %s</H1>%s
 104 </BODY></HTML>"
 105     code reason_phrase code reason_phrase body
 106
 107   (** internal: send a fooish body explaining in HTML form the 'reason phrase'
 108   of an HTTP response; body, if given, will be appended to the body *)
 109 let send_foo_body code body = send_raw ~data:(foo_body code body)
 110
 111   (* TODO add the computation of Content-Length header *)
 112 let respond
 113   (* Warning: keep default values in sync with Http_response.response class *)
 114   ?(body = "") ?(headers = [])
 115   ?(version = http_version) ?(code = 200) ?status outchan
 116   =
 117   let code =
 118     match status with
 119     | None -> code
 120     | Some s -> code_of_status s
 121   in
 122   send_basic_headers ~version ~code outchan;
 123   send_headers ~headers outchan;
 124   send_CRLF outchan;
 125   send_raw ~data:body outchan
 126
 127   (** internal: low level for respond_redirect, respond_error, ...
 128   This function send a status line corresponding to a given code, some basic
 129   headers, the additional headers (if given) and an HTML page containing the
 130   reason phrase; if body is given it will be included in the body of the HTML
 131   page *)
 132 let send_empty_response
 133   func_name ?(is_valid_status = fun _ -> true) ?(headers = []) ~body () =
 134     fun ?(version = http_version) ?code ?status outchan ->
 135       let code = get_code_argument func_name ~code ~status in
 136       if not (is_valid_status code) then
 137         failwith
 138           (sprintf "'%d' isn't a valid status code for %s" code func_name)
 139       else begin  (* status code suitable for answering *)
 140         let headers =
 141           [
 142             "Connection", "close";
 143             "Content-Type", "text/html; charset=iso-8859-1"
 144           ] @ headers
 145         in
 146         let body = (foo_body code body) ^ body in
 147         respond ~version ~code ~headers ~body outchan
 148 (*
 149         (* OLD VERSION, now use 'respond' function *)
 150         send_basic_headers ~version ~code outchan;
 151         send_header ~header:"Connection" ~value:"close" outchan;
 152         send_header
 153           ~header:"Content-Type"
 154           ~value:"text/html; charset=iso-8859-1"
 155           outchan;
 156         send_headers ~headers outchan;
 157         send_CRLF outchan;
 158         send_foo_body ~code ~body outchan
 159 *)
 160       end
 161
 162 let respond_redirect
 163   ~location ?(body = "") ?(version = http_version) ?(code = 301) ?status outchan
 164   =
 165   let code =
 166     match status with
 167     | None -> code
 168     | Some (s: Http_types.redirection_status) -> code_of_status s
 169   in
 170   send_empty_response
 171     "Daemon.respond_redirect" ~is_valid_status:is_redirection
 172     ~headers:["Location", location] ~body ()
 173     ~version ~code outchan
 174
 175 let respond_error
 176   ?(body = "") ?(version = http_version) ?(code = 400) ?status outchan =
 177     let code =
 178       match status with
 179       | None -> code
 180       | Some s -> code_of_status s
 181     in
 182     send_empty_response
 183       "Daemon.respond_error" ~is_valid_status:is_error ~body ()
 184       ~version ~code outchan
 185
 186 let respond_not_found ~url ?(version = http_version) outchan =
 187   send_empty_response
 188     "Daemon.respond_not_found" ~body:"" () ~version ~code:404 outchan
 189
 190 let respond_forbidden ~url ?(version = http_version) outchan =
 191   send_empty_response
 192     "Daemon.respond_permission_denied" ~body:"" () ~version ~code:403 outchan
 193
 194 let send_file ?name ?file outchan =
 195   let buflen = 1024 in
 196   let buf = String.make buflen ' ' in
 197   let (file, cleanup) =
 198     (match (name, file) with
 199     | Some n, None -> (* if we open the file, we close it before returning *)
 200         let f = open_in n in
 201         f, (fun () -> close_in f)
 202     | None, Some f -> (f, (fun () -> ()))
 203     | _ -> failwith "Daemon.send_file: either name or file must be given")
 204   in
 205   try
 206     while true do
 207       let bytes = input file buf 0 buflen in
 208       if bytes = 0 then
 209         raise End_of_file
 210       else
 211         output outchan buf 0 bytes
 212     done;
 213     assert false
 214   with End_of_file ->
 215     begin
 216       flush outchan;
 217       cleanup ()
 218     end
 219
 220   (* TODO interface is too ugly to advertise this function in .mli *)
 221   (** create a minimal HTML directory listing of a given directory and send it
 222   over an out_channel, directory is passed as a dir_handle; name is the
 223   directory name, used for pretty printing purposes; path is the opened dir
 224   path, used to test its contents with stat *)
 225 let send_dir_listing ~dir ~name ~path outchan =
 226   fprintf outchan "<html>\n<head><title>%s</title></head>\n<body>\n" name;
 227   let (dirs, files) =
 228     List.partition (fun e -> Http_misc.is_directory (path ^ e)) (Http_misc.ls dir)
 229   in
 230   List.iter
 231     (fun d -> fprintf outchan "<a href=\"%s/\">%s/</a><br />\n" d d)
 232     (List.sort compare dirs);
 233   List.iter
 234     (fun f -> fprintf outchan "<a href=\"%s\">%s</a><br />\n" f f)
 235     (List.sort compare files);
 236   fprintf outchan "</body>\n</html>";
 237   flush outchan
 238
 239 let respond_file ~fname ?(version = http_version) outchan =
 240   (** ASSUMPTION: 'fname' doesn't begin with a "/"; it's relative to the current
 241   document root (usually the daemon's cwd) *)
 242   let droot = Sys.getcwd () in  (* document root *)
 243   let path = droot ^ "/" ^ fname in (* full path to the desired file *)
 244   if not (Sys.file_exists path) then (* file not found *)
 245     respond_not_found ~url:fname outchan
 246   else begin
 247     try
 248       if Http_misc.is_directory path then begin (* file found, is a dir *)
 249         let dir = Unix.opendir path in
 250         send_basic_headers ~version ~code:200 outchan;
 251         send_header "Content-Type" "text/html" outchan;
 252         send_CRLF outchan;
 253         send_dir_listing ~dir ~name:fname ~path outchan;
 254         Unix.closedir dir
 255       end else begin  (* file found, is something else *)
 256         let file = open_in fname in
 257         send_basic_headers ~version ~code:200 outchan;
 258         send_header
 259           ~header:"Content-Length"
 260           ~value:(string_of_int (Http_misc.filesize fname))
 261           outchan;
 262         send_CRLF outchan;
 263         send_file ~file outchan;
 264         close_in file
 265       end
 266     with
 267     | Unix.Unix_error (Unix.EACCES, s, _) when (s = fname) ->
 268         respond_forbidden ~url:fname ~version outchan
 269     | Sys_error s when
 270         (Pcre.pmatch ~rex:(Pcre.regexp (fname ^ ": Permission denied")) s) ->
 271           respond_forbidden ~url:fname ~version outchan
 272   end
 273
 274 let respond_with (res: Http_types.response) outchan =
 275   res#serialize outchan;
 276   flush outchan
 277
 278 exception Again;;
 279
 280   (* given a Http_parser.parse_request like function, wrap it in a function that
 281   do the same and additionally catch parsing exception sending HTTP error
 282   messages back to client as needed. Returned function raises Again when it
 283   encounter a parse error (name 'Again' is intended for future versions that
 284   will support http keep alive signaling that a new request has to be parsed
 285   from client) *)
 286 let rec wrap_parse_request_w_safety parse_function inchan outchan =
 287 (*   try *)
 288   (try
 289     parse_function inchan
 290   with
 291   | End_of_file ->
 292       respond_error ~code:400 ~body:"Unexpected End Of File" outchan;
 293       raise Again
 294   | Malformed_request req ->
 295       respond_error
 296         ~code:400
 297         ~body:(
 298           "request 1st line format should be: '<method> <url> <version>'" ^
 299           "<br />\nwhile received request 1st line was:<br />\n" ^ req)
 300         outchan;
 301       raise Again
 302   | Unsupported_method meth ->
 303       respond_error
 304         ~code:501
 305         ~body:("Method '" ^ meth ^ "' isn't supported (yet)")
 306         outchan;
 307       raise Again
 308   | Malformed_request_URI uri ->
 309       respond_error ~code:400 ~body:("Malformed URL: '" ^ uri ^ "'") outchan;
 310       raise Again
 311   | Unsupported_HTTP_version version ->
 312       respond_error
 313         ~code:505
 314         ~body:("HTTP version '" ^ version ^ "' isn't supported (yet)")
 315         outchan;
 316       raise Again
 317   | Malformed_query query ->
 318       respond_error
 319         ~code:400 ~body:(sprintf "Malformed query string '%s'" query) outchan;
 320       raise Again
 321   | Malformed_query_part (binding, query) ->
 322       respond_error
 323         ~code:400
 324         ~body:(
 325           sprintf "Malformed query part '%s' in query '%s'" binding query)
 326         outchan;
 327       raise Again)
 328 (*  (* preliminary support for HTTP keep alive connections ... *)
 329   with Again ->
 330     wrap_parse_request_w_safety parse_function inchan outchan
 331 *)
 332
 333   (* wrapper around Http_parser.parse_request which catch parsing exceptions and
 334   return error messages to client as needed
 335   @param inchan in_channel from which read incoming requests
 336   @param outchan out_channl on which respond with error messages if needed
 337   *)
 338 let safe_parse_request = wrap_parse_request_w_safety parse_request
 339
 340   (* as above but for OO version (Http_parser.parse_request') *)
 341 let safe_parse_request' = wrap_parse_request_w_safety parse_request'
 342
 343   (* TODO support also chroot to 'root', not only chdir *)
 344   (* curried request *)
 345 let start
 346   ?(addr = default_addr) ?(port = default_port)
 347   ?(timeout = Some default_timeout) ?(mode = default_mode) ?root callback
 348   =
 349   (match root with  (* chdir to document root *)
 350   | Some dir -> Sys.chdir dir
 351   | None -> ());
 352   let sockaddr = Http_misc.build_sockaddr ~addr ~port in
 353   let daemon_callback inchan outchan =
 354     try
 355       let (path, parameters) = safe_parse_request inchan outchan in
 356       callback path parameters outchan;
 357       flush outchan
 358     with Again -> ()
 359   in
 360   match mode with
 361   | `Single -> Http_tcp_server.simple ~sockaddr ~timeout daemon_callback
 362   | `Fork   -> Http_tcp_server.ocaml_builtin ~sockaddr ~timeout daemon_callback
 363   | `Thread -> Http_tcp_server.thread ~sockaddr ~timeout daemon_callback
 364
 365   (* OO request *)
 366 let start'
 367   ?(addr = default_addr) ?(port = default_port)
 368   ?(timeout = Some default_timeout) ?(mode = default_mode) ?root callback
 369   =
 370   let wrapper path params outchan =
 371     let req = new Http_request.request ~path ~params in
 372     callback req outchan
 373   in
 374   match root with
 375   | None      -> start ~addr ~port ~timeout ~mode wrapper
 376   | Some root -> start ~addr ~port ~timeout ~mode ~root wrapper
 377
 378 module Trivial =
 379   struct
 380     let callback path _ outchan =
 381       if not (Pcre.pmatch ~rex:(Pcre.regexp "^/") path) then
 382         respond_error ~code:400 outchan
 383       else
 384         respond_file ~fname:(Http_misc.strip_heading_slash path) outchan
 385     let start ?(addr = default_addr) ?(port = default_port) () =
 386       start ~addr ~port callback
 387   end
 388
 389   (* @param inchan input channel connected to client
 390      @param outchan output channel connected to client
 391      @param sockaddr client socket address *)
 392 class connection inchan outchan sockaddr =
 393   (* ASSUMPTION: inchan and outchan are channels built on top of the same
 394   Unix.file_descr thus closing one of them will close also the other *)
 395   let close' o = o#close in
 396   object (self)
 397
 398     initializer Gc.finalise close' self
 399
 400     val mutable closed = false
 401
 402     method private assertNotClosed =
 403       if closed then
 404         failwith "Http_daemon.connection: connection is closed"
 405
 406     method getRequest =
 407       self#assertNotClosed;
 408       try
 409         Some (safe_parse_request' inchan outchan)
 410       with Again -> None
 411
 412     method respond_with res =
 413       self#assertNotClosed;
 414       respond_with res outchan
 415
 416     method close =
 417       self#assertNotClosed;
 418       close_in inchan;  (* this close also outchan *)
 419       closed <- true
 420
 421   end
 422
 423 class daemon ?(addr = "0.0.0.0") ?(port = 80) () =
 424   object (self)
 425
 426     val suck =
 427       Http_tcp_server.init_socket (Http_misc.build_sockaddr ~addr ~port)
 428
 429     method accept =
 430       let (cli_suck, cli_sockaddr) = Unix.accept suck in  (* may block *)
 431       let (inchan, outchan) =
 432         (Unix.in_channel_of_descr cli_suck, Unix.out_channel_of_descr cli_suck)
 433       in
 434       new connection inchan outchan cli_sockaddr
 435
 436     method getRequest =
 437       let conn = self#accept in
 438       match conn#getRequest with
 439       | None ->
 440           conn#close;
 441           self#getRequest
 442       | Some req -> (req, conn)
 443
 444   end
 445