helm/DEVEL/ocaml-http/http_daemon.ml

   1
   2 (*
   3   OCaml HTTP - do it yourself (fully OCaml) HTTP daemon
   4
   5   Copyright (C) <2002> Stefano Zacchiroli <zack@cs.unibo.it>
   6
   7   This program is free software; you can redistribute it and/or modify
   8   it under the terms of the GNU General Public License as published by
   9   the Free Software Foundation; either version 2 of the License, or
  10   (at your option) any later version.
  11
  12   This program is distributed in the hope that it will be useful,
  13   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15   GNU General Public License for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with this program; if not, write to the Free Software
  19   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  20 *)
  21
  22 open Printf;;
  23
  24 open Http_common;;
  25 open Http_types;;
  26 open Http_constants;;
  27 open Http_parser;;
  28
  29 let default_addr = "0.0.0.0"
  30 let default_port = 80
  31 let default_timeout = 300
  32 let default_mode = `Fork
  33
  34   (** send raw data on outchan, flushing it afterwards *)
  35 let send_raw ~data outchan =
  36   output_string outchan data;
  37   flush outchan
  38
  39 let send_CRLF = send_raw ~data:crlf
  40
  41 let send_header ~header ~value =
  42   Http_parser_sanity.heal_header (header, value);
  43   send_raw ~data:(header ^ ": " ^ value ^ crlf)
  44
  45 let send_headers ~headers outchan =
  46   List.iter (fun (header, value) -> send_header ~header ~value outchan) headers
  47
  48   (** internal: parse a code argument from a function which have two optional
  49   arguments "code" and "status" *)
  50 let get_code_argument func_name =
  51   fun ~code ~status ->
  52     (match code, status with
  53     | Some c, None -> c
  54     | None, Some s -> code_of_status s
  55     | Some _, Some _ -> (* TODO use some static type checking *)
  56         failwith (func_name ^ " you must give 'code' or 'status', not both")
  57     | None, None -> (* TODO use some static type checking *)
  58         failwith (func_name ^ " you must give 'code' or 'status', not none"))
  59
  60   (** internal: low level for send_status_line *)
  61 let send_status_line' ~version ~code =
  62   let status_line =
  63     String.concat
  64       " "
  65       [ string_of_version version;
  66       string_of_int code;
  67       Http_misc.reason_phrase_of_code code ]
  68   in
  69   send_raw ~data:(status_line ^ crlf)
  70
  71 let send_status_line ?(version = http_version) ?code ?status outchan =
  72   send_status_line'
  73     ~version
  74     ~code:(get_code_argument "Daemon.send_status_line" ~code ~status)
  75     outchan
  76
  77   (* FIXME duplication of code between this and response#addBasicHeaders *)
  78 let send_basic_headers ?(version = http_version) ?code ?status outchan =
  79   send_status_line'
  80     ~version ~code:(get_code_argument "Daemon.send_basic_headers" ~code ~status)
  81     outchan;
  82   send_headers
  83     ~headers:["Date", Http_misc.date_822 (); "Server", server_string]
  84     outchan
  85
  86   (** internal: given a status code and an additional body return a string
  87   representing an HTML document that explains the meaning of given status code.
  88   Additional data can be added to the body via 'body' argument *)
  89 let foo_body code body =
  90   let reason_phrase = Http_misc.reason_phrase_of_code code in
  91   sprintf
  92 "<!DOCTYPE HTML PUBLIC \"-//IETF//DTD HTML 2.0//EN\">
  93 <HTML><HEAD>
  94 <TITLE>%d %s</TITLE>
  95 </HEAD><BODY>
  96 <H1>%d - %s</H1>%s
  97 </BODY></HTML>"
  98     code reason_phrase code reason_phrase body
  99
 100   (** internal: send a fooish body explaining in HTML form the 'reason phrase'
 101   of an HTTP response; body, if given, will be appended to the body *)
 102 let send_foo_body code body = send_raw ~data:(foo_body code body)
 103
 104 let respond
 105   (* Warning: keep default values in sync with Http_response.response class *)
 106   ?(body = "") ?(headers = [])
 107   ?(version = http_version) ?(code = 200) ?status outchan
 108   =
 109   let code =
 110     match status with
 111     | None -> code
 112     | Some s -> code_of_status s
 113   in
 114   send_basic_headers ~version ~code outchan;
 115   send_headers ~headers outchan;
 116   send_header "Content-Length" (string_of_int (String.length body)) outchan;
 117   send_CRLF outchan;
 118   send_raw ~data:body outchan
 119
 120   (** internal: low level for respond_redirect, respond_error, ...
 121   This function send a status line corresponding to a given code, some basic
 122   headers, the additional headers (if given) and an HTML page containing the
 123   reason phrase; if body is given it will be included in the body of the HTML
 124   page *)
 125 let send_empty_response
 126   func_name ?(is_valid_status = fun _ -> true) ?(headers = []) ~body () =
 127     fun ?(version = http_version) ?code ?status outchan ->
 128       let code = get_code_argument func_name ~code ~status in
 129       if not (is_valid_status code) then
 130         failwith
 131           (sprintf "'%d' isn't a valid status code for %s" code func_name)
 132       else begin  (* status code suitable for answering *)
 133         let headers =
 134           [
 135             "Connection", "close";
 136             "Content-Type", "text/html; charset=iso-8859-1"
 137           ] @ headers
 138         in
 139         let body = (foo_body code body) ^ body in
 140         respond ~version ~code ~headers ~body outchan
 141 (*
 142         (* OLD VERSION, now use 'respond' function *)
 143         send_basic_headers ~version ~code outchan;
 144         send_header ~header:"Connection" ~value:"close" outchan;
 145         send_header
 146           ~header:"Content-Type"
 147           ~value:"text/html; charset=iso-8859-1"
 148           outchan;
 149         send_headers ~headers outchan;
 150         send_CRLF outchan;
 151         send_foo_body ~code ~body outchan
 152 *)
 153       end
 154
 155 let respond_redirect
 156   ~location ?(body = "") ?(version = http_version) ?(code = 301) ?status outchan
 157   =
 158   let code =
 159     match status with
 160     | None -> code
 161     | Some (s: Http_types.redirection_status) -> code_of_status s
 162   in
 163   send_empty_response
 164     "Daemon.respond_redirect" ~is_valid_status:is_redirection
 165     ~headers:["Location", location] ~body ()
 166     ~version ~code outchan
 167
 168 let respond_error
 169   ?(body = "") ?(version = http_version) ?(code = 400) ?status outchan =
 170     let code =
 171       match status with
 172       | None -> code
 173       | Some s -> code_of_status s
 174     in
 175     send_empty_response
 176       "Daemon.respond_error" ~is_valid_status:is_error ~body ()
 177       ~version ~code outchan
 178
 179 let respond_not_found ~url ?(version = http_version) outchan =
 180   send_empty_response
 181     "Daemon.respond_not_found" ~body:"" () ~version ~code:404 outchan
 182
 183 let respond_forbidden ~url ?(version = http_version) outchan =
 184   send_empty_response
 185     "Daemon.respond_permission_denied" ~body:"" () ~version ~code:403 outchan
 186
 187 let send_file ?name ?file outchan =
 188   let buflen = 1024 in
 189   let buf = String.make buflen ' ' in
 190   let (file, cleanup) =
 191     (match (name, file) with
 192     | Some n, None -> (* if we open the file, we close it before returning *)
 193         let f = open_in n in
 194         f, (fun () -> close_in f)
 195     | None, Some f -> (f, (fun () -> ()))
 196     | _ ->  (* TODO use some static type checking *)
 197         failwith "Daemon.send_file: either name or file must be given")
 198   in
 199   try
 200     while true do
 201       let bytes = input file buf 0 buflen in
 202       if bytes = 0 then
 203         raise End_of_file
 204       else
 205         output outchan buf 0 bytes
 206     done;
 207     assert false
 208   with End_of_file ->
 209     begin
 210       flush outchan;
 211       cleanup ()
 212     end
 213
 214   (* TODO interface is too ugly to advertise this function in .mli *)
 215   (** create a minimal HTML directory listing of a given directory and send it
 216   over an out_channel, directory is passed as a dir_handle; name is the
 217   directory name, used for pretty printing purposes; path is the opened dir
 218   path, used to test its contents with stat *)
 219 let send_dir_listing ~dir ~name ~path outchan =
 220   fprintf outchan "<html>\n<head><title>%s</title></head>\n<body>\n" name;
 221   let (dirs, files) =
 222     List.partition (fun e -> Http_misc.is_directory (path ^ e)) (Http_misc.ls dir)
 223   in
 224   List.iter
 225     (fun d -> fprintf outchan "<a href=\"%s/\">%s/</a><br />\n" d d)
 226     (List.sort compare dirs);
 227   List.iter
 228     (fun f -> fprintf outchan "<a href=\"%s\">%s</a><br />\n" f f)
 229     (List.sort compare files);
 230   fprintf outchan "</body>\n</html>";
 231   flush outchan
 232
 233 let respond_file ~fname ?(version = http_version) outchan =
 234   (** ASSUMPTION: 'fname' doesn't begin with a "/"; it's relative to the current
 235   document root (usually the daemon's cwd) *)
 236   let droot = Sys.getcwd () in  (* document root *)
 237   let path = droot ^ "/" ^ fname in (* full path to the desired file *)
 238   if not (Sys.file_exists path) then (* file not found *)
 239     respond_not_found ~url:fname outchan
 240   else begin
 241     try
 242       if Http_misc.is_directory path then begin (* file found, is a dir *)
 243         let dir = Unix.opendir path in
 244         send_basic_headers ~version ~code:200 outchan;
 245         send_header "Content-Type" "text/html" outchan;
 246         send_CRLF outchan;
 247         send_dir_listing ~dir ~name:fname ~path outchan;
 248         Unix.closedir dir
 249       end else begin  (* file found, is something else *)
 250         let file = open_in fname in
 251         send_basic_headers ~version ~code:200 outchan;
 252         send_header
 253           ~header:"Content-Length"
 254           ~value:(string_of_int (Http_misc.filesize fname))
 255           outchan;
 256         send_CRLF outchan;
 257         send_file ~file outchan;
 258         close_in file
 259       end
 260     with
 261     | Unix.Unix_error (Unix.EACCES, s, _) when (s = fname) ->
 262         respond_forbidden ~url:fname ~version outchan
 263     | Sys_error s when
 264         (Pcre.pmatch ~rex:(Pcre.regexp (fname ^ ": Permission denied")) s) ->
 265           respond_forbidden ~url:fname ~version outchan
 266   end
 267
 268 let respond_with (res: Http_types.response) outchan =
 269   res#serialize outchan;
 270   flush outchan
 271
 272   (** internal: this exception is raised after a malformed request has been read
 273   by a serving process to signal main server (or itself if mode = `Single) to
 274   skip to next request *)
 275 exception Again;;
 276
 277 let pp_parse_exc e =
 278   sprintf "HTTP request parse error: %s" (Printexc.to_string e)
 279
 280   (* given a Http_parser.parse_request like function, wrap it in a function that
 281   do the same and additionally catch parsing exception sending HTTP error
 282   messages back to client as needed. Returned function raises Again when it
 283   encounter a parse error (name 'Again' is intended for future versions that
 284   will support http keep alive signaling that a new request has to be parsed
 285   from client) *)
 286 let rec wrap_parse_request_w_safety parse_function inchan outchan =
 287 (*   try *)
 288   (try
 289     parse_function inchan
 290   with
 291   | (End_of_file) as e ->
 292       debug_print (pp_parse_exc e);
 293       respond_error ~code:400 ~body:"Unexpected End Of File" outchan;
 294       raise Again
 295   | (Malformed_request req) as e ->
 296       debug_print (pp_parse_exc e);
 297       respond_error
 298         ~code:400
 299         ~body:(
 300           "request 1st line format should be: '<method> <url> <version>'" ^
 301           "<br />\nwhile received request 1st line was:<br />\n" ^ req)
 302         outchan;
 303       raise Again
 304   | (Unsupported_method meth) as e ->
 305       debug_print (pp_parse_exc e);
 306       respond_error
 307         ~code:501
 308         ~body:("Method '" ^ meth ^ "' isn't supported (yet)")
 309         outchan;
 310       raise Again
 311   | (Malformed_request_URI uri) as e ->
 312       debug_print (pp_parse_exc e);
 313       respond_error ~code:400 ~body:("Malformed URL: '" ^ uri ^ "'") outchan;
 314       raise Again
 315   | (Unsupported_HTTP_version version) as e ->
 316       debug_print (pp_parse_exc e);
 317       respond_error
 318         ~code:505
 319         ~body:("HTTP version '" ^ version ^ "' isn't supported (yet)")
 320         outchan;
 321       raise Again
 322   | (Malformed_query query) as e ->
 323       debug_print (pp_parse_exc e);
 324       respond_error
 325         ~code:400 ~body:(sprintf "Malformed query string '%s'" query) outchan;
 326       raise Again
 327   | (Malformed_query_part (binding, query)) as e ->
 328       debug_print (pp_parse_exc e);
 329       respond_error
 330         ~code:400
 331         ~body:(
 332           sprintf "Malformed query part '%s' in query '%s'" binding query)
 333         outchan;
 334       raise Again)
 335 (*  (* preliminary support for HTTP keep alive connections ... *)
 336   with Again ->
 337     wrap_parse_request_w_safety parse_function inchan outchan
 338 *)
 339
 340   (* wrapper around Http_parser.parse_request which catch parsing exceptions and
 341   return error messages to client as needed
 342   @param inchan in_channel from which read incoming requests
 343   @param outchan out_channl on which respond with error messages if needed
 344   *)
 345 let safe_parse_request = wrap_parse_request_w_safety parse_request
 346
 347   (* as above but for OO version (Http_parser.parse_request') *)
 348 let safe_parse_request' = wrap_parse_request_w_safety (new Http_request.request)
 349
 350 let chdir_to_document_root = function (* chdir to document root *)
 351   | Some dir -> Sys.chdir dir
 352   | None -> ()
 353
 354 let server_of_mode = function
 355   | `Single -> Http_tcp_server.simple
 356   | `Fork   -> Http_tcp_server.fork
 357   | `Thread -> Http_tcp_server.thread
 358
 359   (* TODO support also chroot to 'root', not only chdir *)
 360   (* curried request *)
 361 let start
 362   ?(addr = default_addr) ?(port = default_port)
 363   ?(timeout = Some default_timeout) ?(mode = default_mode) ?root callback
 364   =
 365   chdir_to_document_root root;
 366   let sockaddr = Http_misc.build_sockaddr (addr, port) in
 367   let daemon_callback inchan outchan =
 368     try
 369       let (path, parameters) = safe_parse_request inchan outchan in
 370       callback path parameters outchan;
 371       flush outchan
 372     with Again -> ()
 373   in
 374   try
 375     (server_of_mode mode) ~sockaddr ~timeout daemon_callback
 376   with Quit -> ()
 377
 378   (* OO request *)
 379 let start'
 380   ?(addr = default_addr) ?(port = default_port)
 381   ?(timeout = Some default_timeout) ?(mode = default_mode) ?root callback
 382   =
 383   chdir_to_document_root root;
 384   let sockaddr = Http_misc.build_sockaddr (addr, port) in
 385   let daemon_callback inchan outchan =
 386     try
 387       let req = safe_parse_request' inchan outchan in
 388       callback req outchan;
 389       flush outchan
 390     with Again -> ()
 391   in
 392   try
 393     (server_of_mode mode) ~sockaddr ~timeout daemon_callback
 394   with Quit -> ()
 395
 396 module Trivial =
 397   struct
 398     let callback path _ outchan =
 399       if not (Pcre.pmatch ~rex:(Pcre.regexp "^/") path) then
 400         respond_error ~code:400 outchan
 401       else
 402         respond_file ~fname:(Http_misc.strip_heading_slash path) outchan
 403     let start ?(addr = default_addr) ?(port = default_port) () =
 404       start ~addr ~port callback
 405   end
 406
 407   (* @param inchan input channel connected to client
 408      @param outchan output channel connected to client
 409      @param sockaddr client socket address *)
 410 class connection inchan outchan sockaddr =
 411   (* ASSUMPTION: inchan and outchan are channels built on top of the same
 412   Unix.file_descr thus closing one of them will close also the other *)
 413   let close' o = o#close in
 414   object (self)
 415
 416     initializer Gc.finalise close' self
 417
 418     val mutable closed = false
 419
 420     method private assertNotClosed =
 421       if closed then
 422         failwith "Http_daemon.connection: connection is closed"
 423
 424     method getRequest =
 425       self#assertNotClosed;
 426       try
 427         Some (safe_parse_request' inchan outchan)
 428       with Again -> None
 429
 430     method respond_with res =
 431       self#assertNotClosed;
 432       respond_with res outchan
 433
 434     method close =
 435       self#assertNotClosed;
 436       close_in inchan;  (* this close also outchan *)
 437       closed <- true
 438
 439   end
 440
 441 class daemon ?(addr = "0.0.0.0") ?(port = 80) () =
 442   object (self)
 443
 444     val suck =
 445       Http_tcp_server.init_socket (Http_misc.build_sockaddr (addr, port))
 446
 447     method accept =
 448       let (cli_suck, cli_sockaddr) = Unix.accept suck in  (* may block *)
 449       let (inchan, outchan) =
 450         (Unix.in_channel_of_descr cli_suck, Unix.out_channel_of_descr cli_suck)
 451       in
 452       new connection inchan outchan cli_sockaddr
 453
 454     method getRequest =
 455       let conn = self#accept in
 456       match conn#getRequest with
 457       | None ->
 458           conn#close;
 459           self#getRequest
 460       | Some req -> (req, conn)
 461
 462   end
 463