helm/DEVEL/ocaml-http/http_daemon.ml

   1
   2 (*
   3   OCaml HTTP - do it yourself (fully OCaml) HTTP daemon
   4
   5   Copyright (C) <2002-2004> Stefano Zacchiroli <zack@cs.unibo.it>
   6
   7   This program is free software; you can redistribute it and/or modify
   8   it under the terms of the GNU General Public License as published by
   9   the Free Software Foundation; either version 2 of the License, or
  10   (at your option) any later version.
  11
  12   This program is distributed in the hope that it will be useful,
  13   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15   GNU General Public License for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with this program; if not, write to the Free Software
  19   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  20 *)
  21
  22 open Printf
  23
  24 open Http_common
  25 open Http_types
  26 open Http_constants
  27 open Http_parser
  28
  29   (** send raw data on outchan, flushing it afterwards *)
  30 let send_raw ~data outchan =
  31   output_string outchan data;
  32   flush outchan
  33
  34 let send_CRLF = send_raw ~data:crlf
  35
  36 let send_header ~header ~value =
  37   Http_parser_sanity.heal_header (header, value);
  38   send_raw ~data:(header ^ ": " ^ value ^ crlf)
  39
  40 let send_headers ~headers outchan =
  41   List.iter (fun (header, value) -> send_header ~header ~value outchan) headers
  42
  43   (** internal: low level for send_status_line *)
  44 let send_status_line' ~version code =
  45   let status_line =
  46     String.concat
  47       " "
  48       [ string_of_version version;
  49       string_of_int code;
  50       Http_misc.reason_phrase_of_code code ]
  51   in
  52   send_raw ~data:(status_line ^ crlf)
  53
  54 let int_of_code = function
  55   | `Code code -> code
  56   | `Status status -> code_of_status status
  57
  58 let send_status_line ?(version = http_version) ~(code: status_code) outchan =
  59   send_status_line' ~version (int_of_code code) outchan
  60
  61   (* FIXME duplication of code between this and response#addBasicHeaders *)
  62 let send_basic_headers ?(version = http_version) ~(code: status_code) outchan =
  63   send_status_line' ~version (int_of_code code) outchan;
  64   send_headers
  65     ~headers:["Date", Http_misc.date_822 (); "Server", server_string]
  66     outchan
  67
  68   (** internal: given a status code and an additional body return a string
  69   representing an HTML document that explains the meaning of given status code.
  70   Additional data can be added to the body via 'body' argument *)
  71 let foo_body code body =
  72   let reason_phrase = Http_misc.reason_phrase_of_code code in
  73   sprintf
  74 "<!DOCTYPE HTML PUBLIC \"-//IETF//DTD HTML 2.0//EN\">
  75 <HTML><HEAD>
  76 <TITLE>%d %s</TITLE>
  77 </HEAD><BODY>
  78 <H1>%d - %s</H1>%s
  79 </BODY></HTML>"
  80     code reason_phrase code reason_phrase body
  81
  82   (** internal: send a fooish body explaining in HTML form the 'reason phrase'
  83   of an HTTP response; body, if given, will be appended to the body *)
  84 let send_foo_body code body = send_raw ~data:(foo_body code body)
  85
  86   (* Warning: keep default values in sync with Http_response.response class *)
  87 let respond ?(body = "") ?(headers = []) ?version ?(code = `Code 200) outchan =
  88   send_basic_headers ?version ~code outchan;
  89   send_headers ~headers outchan;
  90   send_header "Content-Length" (string_of_int (String.length body)) outchan;
  91   send_CRLF outchan;
  92   send_raw ~data:body outchan
  93
  94   (** internal: low level for respond_redirect, respond_error, ...
  95   This function send a status line corresponding to a given code, some basic
  96   headers, the additional headers (if given) and an HTML page containing the
  97   reason phrase; if body is given it will be included in the body of the HTML
  98   page *)
  99 let send_empty_response
 100   func_name ?(is_valid_status = fun _ -> true) ?(headers=[]) ?(body="") () =
 101     fun ?version code outchan ->
 102       if not (is_valid_status (int_of_code code)) then
 103         failwith
 104           (sprintf "'%d' isn't a valid status code for %s"
 105             (int_of_code code) func_name)
 106       else begin  (* status code suitable for answering *)
 107         let headers =
 108           [ "Connection", "close";
 109             "Content-Type", "text/html; charset=iso-8859-1" ] @ headers
 110         in
 111         let body = (foo_body (int_of_code code) body) ^ body in
 112         respond ?version ~code ~headers ~body outchan
 113       end
 114
 115 let respond_redirect
 116   ~location ?body ?version ?(code = `Code 301) outchan
 117   =
 118   send_empty_response "Daemon.respond_redirect" ~is_valid_status:is_redirection
 119     ~headers:["Location", location] ?body () ?version code outchan
 120
 121 let respond_error ?body ?version ?(code = `Code 400) outchan =
 122   send_empty_response "Daemon.respond_error" ~is_valid_status:is_error
 123     ?body () ?version code outchan
 124
 125 let respond_not_found ~url ?version outchan =
 126   send_empty_response "Daemon.respond_not_found" () ?version (`Code 404) outchan
 127
 128 let respond_forbidden ~url ?version outchan =
 129   send_empty_response "Daemon.respond_permission_denied" () ?version
 130   (`Code 403) outchan
 131
 132 let respond_unauthorized ?version ?(realm = server_string) outchan =
 133   let body =
 134     sprintf "401 - Unauthorized - Authentication failed for realm \"%s\"" realm
 135   in
 136   respond ~headers:["WWW-Authenticate", sprintf "Basic realm=\"%s\"" realm]
 137     ~code:(`Code 401) ~body outchan
 138
 139 let send_file ~src outchan =
 140   let buflen = 1024 in
 141   let buf = String.make buflen ' ' in
 142
 143   let (file, cleanup) =
 144     match src with
 145     | FileSrc fname -> (* if we open the file, we close it before returning *)
 146         let f = open_in fname in
 147         f, (fun () -> close_in f)
 148     | InChanSrc inchan -> inchan, ignore
 149   in
 150   try
 151     while true do
 152       let bytes = input file buf 0 buflen in
 153       if bytes = 0 then
 154         raise End_of_file
 155       else
 156         output outchan buf 0 bytes
 157     done;
 158     assert false
 159   with End_of_file ->
 160     begin
 161       flush outchan;
 162       cleanup ()
 163     end
 164
 165   (* TODO interface is too ugly to advertise this function in .mli *)
 166   (** create a minimal HTML directory listing of a given directory and send it
 167   over an out_channel, directory is passed as a dir_handle; name is the
 168   directory name, used for pretty printing purposes; path is the opened dir
 169   path, used to test its contents with stat *)
 170 let send_dir_listing ~dir ~name ~path outchan =
 171   fprintf outchan "<html>\n<head><title>%s</title></head>\n<body>\n" name;
 172   let (dirs, files) =
 173     List.partition (fun e -> Http_misc.is_directory (path ^ e)) (Http_misc.ls dir)
 174   in
 175   List.iter
 176     (fun d -> fprintf outchan "<a href=\"%s/\">%s/</a><br />\n" d d)
 177     (List.sort compare dirs);
 178   List.iter
 179     (fun f -> fprintf outchan "<a href=\"%s\">%s</a><br />\n" f f)
 180     (List.sort compare files);
 181   fprintf outchan "</body>\n</html>";
 182   flush outchan
 183
 184 let respond_file ~fname ?(version = http_version) outchan =
 185   (** ASSUMPTION: 'fname' doesn't begin with a "/"; it's relative to the current
 186   document root (usually the daemon's cwd) *)
 187   let droot = Sys.getcwd () in  (* document root *)
 188   let path = droot ^ "/" ^ fname in (* full path to the desired file *)
 189   if not (Sys.file_exists path) then (* file not found *)
 190     respond_not_found ~url:fname outchan
 191   else begin
 192     try
 193       if Http_misc.is_directory path then begin (* file found, is a dir *)
 194         let dir = Unix.opendir path in
 195         send_basic_headers ~version ~code:(`Code 200) outchan;
 196         send_header "Content-Type" "text/html" outchan;
 197         send_CRLF outchan;
 198         send_dir_listing ~dir ~name:fname ~path outchan;
 199         Unix.closedir dir
 200       end else begin  (* file found, is something else *)
 201         let file = open_in fname in
 202         send_basic_headers ~version ~code:(`Code 200) outchan;
 203         send_header
 204           ~header:"Content-Length"
 205           ~value:(string_of_int (Http_misc.filesize fname))
 206           outchan;
 207         send_CRLF outchan;
 208         send_file ~src:(InChanSrc file) outchan;
 209         close_in file
 210       end
 211     with
 212     | Unix.Unix_error (Unix.EACCES, s, _) when (s = fname) ->
 213         respond_forbidden ~url:fname ~version outchan
 214     | Sys_error s when
 215         (Pcre.pmatch ~rex:(Pcre.regexp (fname ^ ": Permission denied")) s) ->
 216           respond_forbidden ~url:fname ~version outchan
 217   end
 218
 219 let respond_with (res: Http_types.response) outchan =
 220   res#serialize outchan;
 221   flush outchan
 222
 223   (** internal: this exception is raised after a malformed request has been read
 224   by a serving process to signal main server (or itself if mode = `Single) to
 225   skip to next request *)
 226 exception Again;;
 227
 228 let pp_parse_exc e =
 229   sprintf "HTTP request parse error: %s" (Printexc.to_string e)
 230
 231   (* given a Http_parser.parse_request like function, wrap it in a function that
 232   do the same and additionally catch parsing exception sending HTTP error
 233   messages back to client as needed. Returned function raises Again when it
 234   encounter a parse error (name 'Again' is intended for future versions that
 235   will support http keep alive signaling that a new request has to be parsed
 236   from client) *)
 237 let rec wrap_parse_request_w_safety parse_function inchan outchan =
 238 (*   try *)
 239   (try
 240     parse_function inchan
 241   with
 242   | (End_of_file) as e ->
 243       debug_print (pp_parse_exc e);
 244       respond_error ~code:(`Code 400) ~body:"Unexpected End Of File" outchan;
 245       raise Again
 246   | (Malformed_request req) as e ->
 247       debug_print (pp_parse_exc e);
 248       respond_error ~code:(`Code 400)
 249         ~body:("request 1st line format should be: '<method> <url> <version>'" ^
 250           "<br />\nwhile received request 1st line was:<br />\n" ^ req)
 251         outchan;
 252       raise Again
 253   | (Invalid_HTTP_method meth) as e ->
 254       debug_print (pp_parse_exc e);
 255       respond_error ~code:(`Code 501)
 256         ~body:("Method '" ^ meth ^ "' isn't supported (yet)")
 257         outchan;
 258       raise Again
 259   | (Malformed_request_URI uri) as e ->
 260       debug_print (pp_parse_exc e);
 261       respond_error ~code:(`Code 400) ~body:("Malformed URL: '" ^ uri ^ "'")
 262         outchan;
 263       raise Again
 264   | (Invalid_HTTP_version version) as e ->
 265       debug_print (pp_parse_exc e);
 266       respond_error ~code:(`Code 505)
 267         ~body:("HTTP version '" ^ version ^ "' isn't supported (yet)")
 268         outchan;
 269       raise Again
 270   | (Malformed_query query) as e ->
 271       debug_print (pp_parse_exc e);
 272       respond_error ~code:(`Code 400)
 273         ~body:(sprintf "Malformed query string '%s'" query) outchan;
 274       raise Again
 275   | (Malformed_query_part (binding, query)) as e ->
 276       debug_print (pp_parse_exc e);
 277       respond_error ~code:(`Code 400)
 278         ~body:(sprintf "Malformed query part '%s' in query '%s'" binding query)
 279         outchan;
 280       raise Again)
 281 (*  (* preliminary support for HTTP keep alive connections ... *)
 282   with Again ->
 283     wrap_parse_request_w_safety parse_function inchan outchan
 284 *)
 285
 286   (* wrapper around Http_parser.parse_request which catch parsing exceptions and
 287   return error messages to client as needed
 288   @param inchan in_channel from which read incoming requests
 289   @param outchan out_channl on which respond with error messages if needed
 290   *)
 291 let safe_parse_request = wrap_parse_request_w_safety parse_request
 292
 293   (* as above but for OO version (Http_parser.parse_request') *)
 294 let safe_parse_request' = wrap_parse_request_w_safety (new Http_request.request)
 295
 296 let chdir_to_document_root = function (* chdir to document root *)
 297   | Some dir -> Sys.chdir dir
 298   | None -> ()
 299
 300 let server_of_mode = function
 301   | `Single -> Http_tcp_server.simple
 302   | `Fork   -> Http_tcp_server.fork
 303   | `Thread -> Http_tcp_server.thread
 304
 305   (* TODO what happens when a Quit exception is raised by a callback? Do other
 306   callbacks keep on living until the end or are them all killed immediatly?
 307   The right semantics should obviously be the first one *)
 308
 309 let handle_manual_auth outchan f =
 310   try
 311     f ()
 312   with
 313   | Unauthorized realm -> respond_unauthorized ~realm outchan
 314   | Again -> ()
 315
 316 let handle_auth req spec outchan =
 317   try
 318     (match (spec.auth, req#authorization) with
 319     | None, _ -> spec.callback req outchan  (* no auth required *)
 320     | Some (realm, `Basic (spec_username, spec_password)),
 321       Some (`Basic (username, password))
 322       when (username = spec_username) && (password = spec_password) ->
 323         (* auth ok *)
 324         spec.callback req outchan
 325     | Some (realm, _), _ -> raise (Unauthorized realm)) (* auth failure *)
 326   with
 327   | Unauthorized realm -> respond_unauthorized ~realm outchan
 328   | Again -> ()
 329
 330   (* TODO support also chroot to 'root', not only chdir *)
 331   (* TODO deprecated: remove from future versions *)
 332   (* curried request *)
 333 let start
 334   ?(addr = default_addr) ?(port = default_port)
 335   ?(timeout = default_timeout) ?(mode = default_mode) ?root callback
 336   =
 337   Http_misc.warn
 338     "Http_daemon.start is deprecated in favour of Http_daemon.main and will be removed in future versions of the library";
 339   chdir_to_document_root root;
 340   let sockaddr = Http_misc.build_sockaddr (addr, port) in
 341   let daemon_callback inchan outchan =
 342     handle_manual_auth outchan (fun () ->
 343       let (path, parameters) = safe_parse_request inchan outchan in
 344       callback path parameters outchan;
 345       flush outchan);
 346   in
 347   try
 348     (server_of_mode mode) ~sockaddr ~timeout daemon_callback
 349   with Quit -> ()
 350
 351   (* OO request *)
 352   (* TODO deprecated: remove from future versions *)
 353 let start'
 354   ?(addr = default_addr) ?(port = default_port)
 355   ?(timeout = default_timeout) ?(mode = default_mode) ?root callback
 356 =
 357   Http_misc.warn
 358     "Http_daemon.start' is deprecated in favour of Http_daemon.main and will be removed in future versions of the library";
 359   chdir_to_document_root root;
 360   let sockaddr = Http_misc.build_sockaddr (addr, port) in
 361   let daemon_callback inchan outchan =
 362     handle_manual_auth outchan (fun () ->
 363       let req = safe_parse_request' inchan outchan in
 364       callback req outchan;
 365       flush outchan)
 366   in
 367   try
 368     (server_of_mode mode) ~sockaddr ~timeout daemon_callback
 369   with Quit -> ()
 370
 371 let main spec =
 372   chdir_to_document_root spec.root_dir;
 373   let sockaddr = Http_misc.build_sockaddr (spec.address, spec.port) in
 374   let daemon_callback inchan outchan =
 375     try
 376       let req = safe_parse_request' inchan outchan in
 377       handle_auth req spec outchan;
 378       flush outchan
 379     with exn ->
 380       (match spec.exn_handler with
 381       | Some f ->
 382           debug_print "uncaught exception: executing handler";
 383           f exn outchan
 384       | None ->
 385           debug_print "uncaught exception but no handler given: re-raising";
 386           raise exn)
 387   in
 388   try
 389     (server_of_mode spec.mode) ~sockaddr ~timeout:spec.timeout daemon_callback
 390   with Quit -> ()
 391
 392 module Trivial =
 393   struct
 394     let heading_slash_RE = Pcre.regexp "^/"
 395
 396     let trivial_callback req outchan =
 397       let path = req#path in
 398       if not (Pcre.pmatch ~rex:heading_slash_RE path) then
 399         respond_error ~code:(`Code 400) outchan
 400       else
 401         respond_file ~fname:(Http_misc.strip_heading_slash path) outchan
 402
 403     let callback = trivial_callback
 404
 405     let main spec = main { spec with callback = trivial_callback }
 406   end
 407
 408   (* @param inchan input channel connected to client
 409      @param outchan output channel connected to client
 410      @param sockaddr client socket address *)
 411 class connection inchan outchan sockaddr =
 412   (* ASSUMPTION: inchan and outchan are channels built on top of the same
 413   Unix.file_descr thus closing one of them will close also the other *)
 414   let close' o = o#close in
 415   object (self)
 416
 417     initializer Gc.finalise close' self
 418
 419     val mutable closed = false
 420
 421     method private assertNotClosed =
 422       if closed then
 423         failwith "Http_daemon.connection: connection is closed"
 424
 425     method getRequest =
 426       self#assertNotClosed;
 427       try
 428         Some (safe_parse_request' inchan outchan)
 429       with Again -> None
 430
 431     method respond_with res =
 432       self#assertNotClosed;
 433       respond_with res outchan
 434
 435     method close =
 436       self#assertNotClosed;
 437       close_in inchan;  (* this close also outchan *)
 438       closed <- true
 439
 440   end
 441
 442 class daemon ?(addr = "0.0.0.0") ?(port = 80) () =
 443   object (self)
 444
 445     val suck =
 446       Http_tcp_server.init_socket (Http_misc.build_sockaddr (addr, port))
 447
 448     method accept =
 449       let (cli_suck, cli_sockaddr) = Unix.accept suck in  (* may block *)
 450       let (inchan, outchan) =
 451         (Unix.in_channel_of_descr cli_suck, Unix.out_channel_of_descr cli_suck)
 452       in
 453       new connection inchan outchan cli_sockaddr
 454
 455     method getRequest =
 456       let conn = self#accept in
 457       match conn#getRequest with
 458       | None ->
 459           conn#close;
 460           self#getRequest
 461       | Some req -> (req, conn)
 462
 463   end
 464
 465 open Http_constants
 466
 467 let default_spec = {
 468   address = default_addr;
 469   auth = default_auth;
 470   callback = default_callback;
 471   mode = default_mode;
 472   port = default_port;
 473   root_dir = default_root_dir;
 474   exn_handler = default_exn_handler;
 475   timeout = default_timeout;
 476 }
 477
 478 let daemon_spec
 479   ?(address = default_addr) ?(auth = default_auth)
 480   ?(callback = default_callback) ?(mode = default_mode) ?(port = default_port)
 481   ?(root_dir = default_root_dir) ?(exn_handler = default_exn_handler)
 482   ?(timeout = default_timeout)
 483   ()
 484 =
 485   { default_spec with
 486       address = address;
 487       auth = auth;
 488       callback = callback;
 489       mode = mode;
 490       port = port;
 491       root_dir = root_dir;
 492       exn_handler = exn_handler;
 493       timeout = timeout;
 494   }
 495